NEWSLETTER IN ASP:AIUTO!!!!!

[Roby_72]

Originariamente inviato da viki1967
Calma e sangue freddo, inizia dal tuo browser, in opzioni avanzate, TOGLI la spunta dalla voce Mostra messaggi di errore HTTP brevi.
Vedrai che ti apparirà l'errore ASP che vieen generato dallo script.

Non hai fatto quanto detto da viki

Roby

[giemme1976]

Errore... ecco qual'è l'errore che mi indica:
Microsoft JScript runtime error '800a01ad'

Automation server can't create object

/invia.asp, line 17

Che faccio?

[giemme1976]

L'errore di linea è proprio quello riguardante la "tua_mail" e "server.it".!!!

[Roby_72]

Se sei su server win 2003 non puoi usare cdonts ma cdosys.
Cerca nel forum, se ne è parlato.

Roby

[viki1967]

Verifica la presenza del componente che invia la posta sul server:

<%

	
	Dim comList(1)
	
	comList(0) = Array( "CDOSYS", "CDO.Message" )
	comList(1) = Array( "CDONTS","CDONTS.NewMail" )

Function IsAvailable( comIdentity )
		On Error Resume Next
		IsAvailable = False
		Err = 0
		Set xTestObj = Server.CreateObject( comIdentity )
		If Err = 0 Then IsAvailable = True
		Set xTestObj = Nothing
		Err = 0
	End Function

	Public Function CheckCOM()
		Avail = 0
		strTxt = "<table cellpadding=3 cellspacing=3 border=0 align=center width=300>" & vbNewLine
		For Idx = LBound( comList ) To UBound( comList )
			Provider = Idx
			strTxt = strTxt & vbTab & "<tr><td width=200><font class=norm>" & comList(Idx)(0) & "</font></td>"
			strTxt = strTxt & "<td align=right width=20><font class=norm>[</font></td>"
			If IsAvailable( comList(Idx)(1) ) Then
				strTxt = strTxt & "<td align=center><font face=tahoma size=2 color=blue>Available</font></td>"
				Avail = Avail + 1 
			Else
				strTxt = strTxt & "<td align=center><font class=norm>Unavailable</font></td>"
			End If
			strTxt = strTxt & "<td align=left width=20><font class=norm>]</font></td></tr>" & vbNewLine
		Next
		strTxt = strTxt & vbTab & "<tr><td colspan=4 height=30><font class=norm><font color=blue>" & Avail & "</font> of "
		strTxt = strTxt & UBound( comList ) + 1 & " supported components are available.</font></td></tr>" & vbNewLine
		CheckCOM = strTxt & "</table>" & vbNewLine
	End Function

	Response.Write( CheckCOM() )
%>

[giemme1976]

Grazie!!! proverò a verificare quanto suggeritomi! SIete stati gentilissimi!!!!! Vi faro sapere al più presto!!!!!!

[giemme1976]

Rieccomi!! Allora, ho provato quanto suggeritomi e, come ovvio, avevate ragione. Il server è wiondos 2003 e supporta solo cdosys.
Questo è il responso avuto:
CDOSYS [ Available ]
CDONTS [ Unavailable ]
1 of 2 supported components are available.
A questo punto, visto che sono un gran profano in materia, ke fare? Mi potete consigliare qualche tutorial (visto ke non sono un programmatore...!) o qualche indirizzo dove andare a trovare qualcosa di utile?
Come al solito... vi ringrazio per la vostra pazienza!!!!

[viki1967]

da weppos.com:

<%

' Controlla invio
if Request.QueryString("invia") = "true" AND Request.Form("submit") = "invia" then

Dim objMail, objConfig
' Crea l'oggetto email
Set objMail = CreateObject("CDO.Message")
' Dimensiona l'oggetto configurazione
Set objConfig = Server.CreateObject ("CDO.Configuration")
     
' Imposta le configurazioni
With objConfig
                        
' Server SMTP di uscita
' ATTENZIONE! Usare il proprio indirizzo di server email!
' E' FONDAMENTALE per l'invio della email
  .Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.miosito.com"

' Porta SMTP
  .Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25

' Porta CDO
  .Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

' Timeout
  .Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
  .Fields.Update
End With
     
' Assegna le configurazioni
Set objMail.Configuration = objConfig
     
' Assegna all'oggetto le proprietà necessarie
objMail.From = "mittente@dominio.xx" ' Mittente
objMail.To = Request.Form("email") ' Destinatario
objMail.Subject = Request.Form("oggetto") ' Oggetto
objMail.HTMLBody = Request.Form("messaggio") ' Messaggio
     
' Invia l'email
objMail.Send()

Set objMail = Nothing
     
Response.Write("Email inviata correttamente ")
Response.Write("all'indirizzo ")
Response.Write(Request.Form("email"))

else %>
<form name="formail" method="post" action="email.asp?invia=true">
<table align="center" cellpadding="3" cellspacing="1">
<tr>
<td>Email</td>
<td><input type="text" name="email" /></td>
</tr>
<tr>
<td>Oggetto</td>
<td><input type="text" name="oggetto" /></td>
</tr>
<tr>
<td>Messaggio</td>
<td><textarea name="messaggio"></textarea></td>
</tr>
<tr>
<td colspan="2"> <input type="submit" value="invia" name="submit" /> </td>
</tr>
</table>
</form>
<% end if %>

[giemme1976]

Ma riuscirò a mandare la newsletter a tutti gli iscritti?

[Roby_72]

In che senso?
Quello script invia una email. Mettilo nel loop mettendo il destinatario preso dal db ed invierai la newsletter a tutti.

Roby