[PILLOLA] Introduzione ed utilizzo di MovieClipLoader [MX 2004]

[iaco74]

in piu' questo non mi torna tanto.....

movieListener.onLoadProgress=function(target_mc,loadedBytes,totalBytes){
		caricamento="Totale bytes caricati: "+loadedBytes;
		caricamento+="Totale bytes da caricare: "+totalBytes;
		accaduto(debug_txt,caricamento,myFormat);
		}

invece di loadedBytes che e' una variabile non ci dovrebbe essere bytesLoaded,e bytesTotal ?

Domando e' ? magari ho detto una bischerata.

[negatyve]

Visto che se ne parlava anche qui:

http://forum.html.it/forum/showthrea...hreadid=558107

[iaco74]

visto grazie...negatyve
Mi ci vorra' un po di tempo per apprendere tutto

[andr3a]

Originariamente inviato da iaco74
in piu' questo non mi torna tanto.....

movieListener.onLoadProgress=function(target_mc,loadedBytes,totalBytes){
		caricamento="Totale bytes caricati: "+loadedBytes;
		caricamento+="Totale bytes da caricare: "+totalBytes;
		accaduto(debug_txt,caricamento,myFormat);
		}

invece di loadedBytes che e' una variabile non ci dovrebbe essere bytesLoaded,e bytesTotal ?

Domando e' ? magari ho detto una bischerata.

movieListener. onLoadProgress = function(target_mc, loadedBytes, totalBytes) {
	caricamento="Totale bytes caricati: "+loadedBytes;
	caricamento+="Totale bytes da caricare: "+totalBytes;
	accaduto(debug_txt, caricamento, myFormat);
}

loadedBytes e totalBytes sono valori passati dal metodo stesso, non e' che "dovrebbero" essere getbytesLoaded etce tc .. possono essere pippo, pluto

movieListener. onLoadProgress = function(target_mc, pippo, pluto) {
	caricamento="Totale bytes caricati: "+pippo;
	caricamento+="Totale bytes da caricare: "+pluto;
	accaduto(debug_txt, caricamento, myFormat);
}

[iaco74]

ok chiaro grazie

Adesso devo scovare dove sta l'inghippo per il quale non mi fa vedere i valori prima del caricamento.....

Appena lo trovo te lo faccio sapere.....

[iaco74]

purtroppo l'inghippo non lo trovo a me i valori di caricamento non escono fuori.

[iaco74]

mi dai una mano andrea per favore ?????

funziona tutto ma non escono i valori di caricamento all'avvio.

Ma a te escono ? Lo hai testato ?

Fammi sapere se puoi
Grazie ciao

[andr3a]

Originariamente inviato da iaco74
mi dai una mano andrea per favore ?????

funziona tutto ma non escono i valori di caricamento all'avvio.

Ma a te escono ? Lo hai testato ?

Fammi sapere se puoi
Grazie ciao

io con l'altra storia del flusso dati da file php ho fatto l'enorme fagianata di non considerare che in locale o generavo un file da 1 GigaByte, oppure non potevo testare quanto stavo tentando di testare...

... spero che tu stia effettuando il test on-line con un file SWF di almeno 200Kb ...

se e' cosi' posta il codice caricante e linka il file, oppure dimmelo che ti faccio un .FLA di prova con un file grafico pesante e te lo faccio scaricare dopo averlo testato con successo, cosi' vedi se va oppure no

[iaco74]

ecco il link dove ho testato ....

http://www.videolink.tv.it/iaco/loader.html

l'immagine e' 280KB.

Ecco il codice

stop();
mydir=new String("http://www.videolink.tv.it/iaco/img/");
filename=new String("loader.jpg");
this.createTextField("debug_txt",1,0,0,1,1);
this["debug_txt"].autoSize=true;
this["debug_txt"].html=true;
myFormat=new TextFormat();
myFormat.font="Verdana";
myFormat.size=10;
myFormat.color=0x000000;
globalStatus= new String();
function accaduto(campo:TextField,testo:String,formattazione:TextFormat){
campo.htmlText=testo;
campo.setTextFormat(formattazione);
}
myLoadedMovie=new MovieClipLoader();
movieListener= new Object();
movieListener.onLoadStart=function(target_mc){
	globalStatus="Inizio caricamento di"+target_mc;
	}
	loadProgress=new Object(myLoadedMovie.getProgress(target_mc));
	globalStatus+="Bytes caricati all'avvio:"+loadProgress.bytesLoaded;
	globalStatus+="Bytes totali all'avvio:"+loadProgress.bytesTotal;
	movieListener.onLoadProgress=function(target_mc,loadedBytes,totalBytes){
		caricamento="Totale bytes caricati: "+loadedBytes;
		caricamento+="Totale bytes da caricare: "+totalBytes;
		accaduto(debug_txt,globalStatus,myFormat);
		}
	movieListener.onLoadComplete=function(target_mc){
		globalStatus+="il file"+target_mc+" è pronto";
		accaduto(debug_txt,globalStatus,myFormat);
		}
	movieListener=onLoadInit=function(target_mc){
		target_mc._alpha=50;
		globalStatus+="inizializzazione"+target_mc+" completata";
		accaduto(debug_txt,globalStatus,myFormat);
		}
     movieListener.onLoadError=function(target_mc,errorCode) {
		 globalStatus+="Impossibile caricare questo file "+target_mc;
		 globalStatus+="["+errorCode+"]";
		 accaduto(debug_txt,globalStatus,myFormat);
		 myLoadedMovie.unloadClip(target_mc);
		 }
		 myLoadedMovie.addListener(movieListener);
		 this.createEmptyMovieClip("myMove",10);
		 myLoadedMovie.loadClip(mydir+filename,this['myMove']);

Grazie per la tua disponibilita'

Ciao

[andr3a]

stop();

// FUNZIONE SCRITTURA
function accaduto(campo:TextField, testo:String, formattazione:TextFormat) {
	campo.htmlText = testo;
	campo.setTextFormat(formattazione); 
}

// CAMPO DI TESTO E FORMATTAZIONE
this.createTextField("debug_txt", 1, 5, 5, 240, 80); 
this["debug_txt"].html = true;
this["debug_txt"].background = true;
this["debug_txt"].backgroundColor = 0xEFEFEF;
this["debug_txt"].border = true;
this["debug_txt"].borderColor = 0xABABAB;
var myFormat:TextFormat = new TextFormat();
myFormat.font = "Verdana";
myFormat.size = 10;
myFormat.color = 0x002255;

/***************************************
* LISTNER E FUNZIONI DI GESTIONE EVENTI
***************************************/
var MovieListner:Object = new Object();

// onLoadStart
MovieListner.onLoadStart = function (target_mc)  {
	accaduto(debug_txt, ":: caricamento dati [ avviato ] ::", myFormat);
}

// onLoadProgress
MovieListner.onLoadProgress = function (target_mc, loadedBytes, totalBytes) {
	var caricamento:String = new String();
	caricamento = ":: caricamento dati [ in trasmissione ] ::\n";
	caricamento += ":: bytes caricati " + loadedBytes + " % ::\n";
	caricamento += ":: bytes totali " + totalBytes + " % ::\n";
	accaduto(debug_txt, caricamento, myFormat);
}

// onLoadComplete
MovieListner.onLoadComplete = function (target_mc) {
	accaduto(debug_txt, ":: caricamento dati [ effettuato ] ::", myFormat);
}

// onLoadInit
MovieListner.onLoadInit = function (target_mc) {
	debug_txt.removeTextField();
}

// onLoadError
MovieListner.onLoadError = function (target_mc, errorCode) {
	var caricamento:String = new String();
	caricamento = ":: ERRORE in apertura file ::\n";
	caricamento += "[ " + target_mc + " ]\n[ " + errorCode + " ]";
	accaduto(debug_txt, globalStatus, myFormat);
	myLoadedMovie.unloadClip(target_mc);
}
/************************************* *************************************/

// CREO MOVIECARICANTE
this.createEmptyMovieClip("myMove", 10);

// MOVIECLIPLOADER E ASSEGNAZIONI
var myLoadedMovie:MovieClipLoader = new MovieClipLoader();
myLoadedMovie.addListener(MovieListner);
myLoadedMovie.loadClip("http://www.videolink.tv.it/iaco/img/loader.jpg", this["myMove"]);