[PILLOLA] Preload di dati caricati dinamicamente dal server

[iaco74]

grande pillola falcao ci voleva un riassunto generale delle varie discussioni fatte su questo metodo.
mi sono appena stampato tutto adesso vado e vedere di capire per bene tutti i passaggi.


[OT]due pillole in due giorni faranno male ??? [\OT];

[andr3a]

Originariamente inviato da Falcao
a me da sempre 23sec sia con 12 che con 50 che con 80 che con 120... del resto mi sembra abbastanza logico se tu effettui uno spostamento ogni tot ms non può dipendere dal framerate! il framerate ti da la fluidità del moto e basta!

a me da 12 con 12 fps e 10 con 50 fps ... ma sono su Mozilla, magari sto giro influisce veramente ...


cmq sia, ho aggiunto n'altra caXXata per i piu' sfaticati ...

class LoadVars2 extends LoadVars {
	// andr3a [ www.3site.it ] [ 25/11/2003 ]
	// Thanks to: negatyve / Falcao / bubu77
	// from HTML.IT [ www.html.it ]
	public var percent:Number = new Number(0);
	private var myIntCheck:Number;
	function LoadVars2() {
		super();
	}
	public function load(url:String):Void {
		super.load(url);
		setMyInterval();
	}
	public function sendAndLoad(url:String, return_var:Object, method:String):Void {
		method = method != undefined ? method : "POST";
		super.sendAndLoad(url, return_var, method);
		setMyInterval();
	}
	public function stopLoading():Void {
		clearInterval(myIntCheck);
	}
	private function setMyInterval():Void {
		myIntCheck = setInterval(this, "checkCharge", 20);
	}
	private function checkCharge():Void {
		var loadedBytes:Number = getBytesLoaded() != undefined ? getBytesLoaded() : 0;
		var totalBytes:Number = getBytesTotal() != undefined ? getBytesTotal() : 0;
		percent = totalBytes > 0 ? Math.round((loadedBytes/totalBytes)*100) : 0;
		if( this.onLoadProgress != undefined ) {
			this.onLoadProgress(loadedBytes, totalBytes);
		}
		if( loadedBytes > 0 && loadedBytes >= totalBytes) {
			stopLoading();
		}
	}
}

ora e' sempre tutto come prima ma a prescindere che usate l' onLoadProgress avrete comunque la variabile auto aggiornata percent contenente l'avanzamento in percentuale del file che state caricando, sia questo .php che .txt

Esempio
poi basta ...

var serverbytes = new LoadVars2();
serverbytes.onLoad = function(success) {
	if(!success) {
		trace("Errore!");
		this.stopLoading();
	}
}
serverbytes.onLoadProgress = function(loadedBytes, totalBytes) {
	trace( this.percent + " %" );
}
serverbytes.load("http://miospazio/miofile.txt");

bona notte

[iaco74]

scusa Falcao ho un po' di domande perche' il tuo esempio a me non mi funziona perfettamente......

1 nella pillola hai messo result.load,mentre nel Fla da scaricare dentro c'e' result.sendAndLoad.
Il metodo giusto secondo me e' solo result.load in quanto non si deve mandare (send) niente a php.... mi confermi questa cosa ?

2 ho visto nel tuo fla d'esempio che hai usato onLoadProgress pubblicando pero' poi il filmato come player 6 e AS 1.0.
Chiedo ma onLoadProgress e solo per AS 2.0 o si puo' usare anche in AS 1.0 ?

Intanto queste due domande poi le altre te le faccio dopo

[iaco74]

un altra cosa che non mi torna ma magari e' un problema del mio hoster non so; il tuo Fla mi funziona ma non mi mostra l'avanzamento mi da una pagina bianca e quando ha finito di caricare i dati mi da direttamente tutti i dati corretti pero' con tutto gia' al 100% non mi mostra l'avanzamento.

Come mai ?
Hai qualche idea ?

[Falcao]

Originariamente inviato da iaco74
scusa Falcao ho un po' di domande perche' il tuo esempio a me non mi funziona perfettamente......

1 nella pillola hai messo result.load,mentre nel Fla da scaricare dentro c'e' result.sendAndLoad.
Il metodo giusto secondo me e' solo result.load in quanto non si deve mandare (send) niente a php.... mi confermi questa cosa ?

2 ho visto nel tuo fla d'esempio che hai usato onLoadProgress pubblicando pero' poi il filmato come player 6 e AS 1.0.
Chiedo ma onLoadProgress e solo per AS 2.0 o si puo' usare anche in AS 1.0 ?

Intanto queste due domande poi le altre te le faccio dopo

Funziona allo stesso modo sia col load che col sendAndLoad

per quanto riguarda l'onLoadProgress() il metodo l'ho creato io e l'ho nominato così... ma potevo chiamarlo anche pippo()

Per il problema che non ti funziona il secondo esempio... prendi in considerazione il fla c'è un errore ho cambiato il nome di checkHeader in addlistener nella dichiarazione del prototype ma nell'esempio invece utilizzo ancora il checkHeader!

Non ho capitouna cosa... la barra di avanzamento la vedi? perchè se la vedi allora funziona, ma magari i dato sono talmente pochi che li carica immediatamente!

[iaco74]

per andr3a

sto provando a testare LoadVars2.

Siccome sono un profano di classi ecc......
mi domandavo come mai mi da questo errore quando vado a fare il controllo errore sullo script che sta sul prmo frame

**Error** D:\Web\Siti Internet\iacopinifabrizio\Online\LoadVars2.as: Line 1: Classes may only be defined in external ActionScript 2.0 class scripts.
class LoadVars2 extends LoadVars {

Total ActionScript Errors: 1 Reported Errors: 1

Premesso che sto usando mx2004 e as 2.0

Sul primo frame ho :

#include "LoadVars2.as"
var serverbytes = new LoadVars2(); // occhio a scrivere LoadVars2 e non LoadVars :-)

serverbytes.onLoad = function(success) {
	trace("____________________________________");
	trace("Caricati: " + this.getBytesLoaded());
	trace("Totali: " + this.getBytesTotal());
}

serverbytes.onLoadProgress = function(loadedBytes, totalBytes) {
	trace(loadedBytes + " - " + totalBytes);
}

serverbytes.sendAndLoad("http://miospazioweb/miofile.php", serverbytes);

[iaco74]

Originariamente inviato da Falcao
Non ho capitouna cosa... la barra di avanzamento la vedi? perchè se la vedi allora funziona, ma magari i dato sono talmente pochi che li carica immediatamente!

http://www.videolink.tv.it/iaco/loadvar_preload.html

Adesso aggiornero' lo script con la correzzione che mi hai detto comunque......

Grazie

[Falcao]

Originariamente inviato da iaco74
http://www.videolink.tv.it/iaco/loadvar_preload.html

Adesso aggiornero' lo script con la correzzione che mi hai detto comunque......

Grazie

lo sai che è strana sta cosa? ma hai utilizzato il mio fla senza modificarlo?

[iaco74]

si comunque non ho capito quale esempio devo usare Falcao se il fla o lo script che hai messo nel primo post o altro.

Quello che c'e' dentro il tuo fla e' questo:

LoadVars.prototype.checkHeader = function() {
	this.idHeader = setInterval(this, "getTotal", 10);
};
LoadVars.prototype.getTotal = function() {
	if (this.getBytesTotal() != undefined) {
		this.onStart();
		this.idLoading = setInterval(this, "getLoading", 10);
		clearInterval(this.idHeader);
	}
};
LoadVars.prototype.getLoading = function() {
	this.onLoadProgress();
	if (this.getBytesLoaded()>=this.getBytesTotal()) {
		clearInterval(this.idLoading);
	}
};
this.preload._visible = false;
result = new LoadVars();
result.sendAndLoad("prova.php", result, "POST");
result.checkHeader();
result.onLoadProgress = function() {
	_root.textField3.text = "caricati: "+this.getBytesLoaded();
	_root.textField4.text = "totali: "+this.getBytesTotal();
};
result.onStart = function() {
	this.startTime = getTimer();
	_root.textLabel1.text = "inizio flusso";
	_root.preload.loadVarsObject = this;
	_root.preload.totalBytes = this.getBytesTotal();
	_root.preload.onEnterFrame = function() {
		this.loadedBytes = this.loadVarsObject.getBytesLoaded();
		this.percent = this.loadedBytes/this.totalBytes*100;
		this.barra._xscale = this.percent;
		this._visible = true;
		this.text1.text = "Percentuale: "+Math.round(this.percent)+"%";
		this.text2.text = "Bytes caricati: "+this.loadedBytes;
		if (this.loadedBytes == this.totalBytes) {
			delete this.onEnterFrame;
		}
	};
};
result.onLoad = function() {
	_root.textLabel2.text = "fine flusso, bytes scaricati: "+this.getBytesLoaded()+" in "+(getTimer()-this.startTime)+"ms";
};

sostituendo checkHeader con addListener( mi immagino sia questa la correzzione che devo fare),non e' che devo cambiare anche questa riga ?

result.checkHeader();

help me please

[Falcao]

Prova a mettere un numero di dati minore nel file php... e dimmi cosa succede... mi fai vedere cmq il tuo file php? prova anche con un file di testo è la stessa cosa se ti funziona l'errore sta in php!

si se vuoi modificare addListener devi modificare pure la chiamata!