body della email da pagina web

[simones70]

salve,
vorrei sapere se è possibile inviare una pagina web in una email, tramite modulo cdonts.

[michele.santoro]

Prova con questo script:

    <%
    Sub ReplaceInBodyPart(bp)
    	Const strTokentoFind = "SIGNATURE"
    	Const strTokenToReplace = "Benny WONG Chee Khiun"
    	
    	Set objStream = bp.GetDecodedContentStream
    	strContent = objStream.ReadText
    	strContent = Replace(strContent, strTokentoFind, strTokenToReplace)
    	
    	objStream.Position = 0
    	objStream.SetEOS
    	objStream.WriteText strContent
    	objStream.Flush
    	Set objStream = nothing
    End Sub
    Sub modifyHtmlAndTextBodyParts(msg)
    	Set objBP = msg.HTMLBodyPart
    	ReplaceInBodyPart objBP
    	Set objBP = nothing
    	
    	Set objBP = msg.TextBodyPart
    	ReplaceInBodyPart objBP
    	Set objBP = nothing
    End Sub
    Set objMsg = Server.CreateObject ("CDO.Message")
    With objMsg
    	.To = """TUONOME"" <tuo_indirizzo@email.it>"
    	.From = """Nome_Mittente"" <aaaaaaaa@aaaaaaaaaaaa.it>"
    	.Subject = "This is the subject"
    	.CreateMHTMLBody "http://www.google.it"
    End With
    ModifyHtmlAndTextBodyParts objMsg
    objMsg.Send 
    Set objMsg = nothing
    %>

Se ti serve puoi renderla dinamica.


Ops, scusa questo script usa CDOSYS, comunque puoi modificarlo

[simones70]

ok, perfetto!!! funziona benissimo Grazie

[michele.santoro]

Prego