Originariamente inviato da chico62

I CommandButton non posseggono la proprietà ForeColor, Brainjar ....

A quanto ne so , l'unico sistema è usare un controllo CheckBox con la proprietà Style impostata a Graphical. Il controllo CheckBox prevede la proprietà di cui sopra, e con Style impostato a Graphical ha lo stesso aspetto di un CommandButton.

Ciauz

Chico
Probabilmente ne sai poco.
Confermo la mancanza della proprietà ForeColor per il CommandButton. Mi sono confuso con
BackColor. Come ho avuto modo di specificare più volte, non ho sottomano una
installazione di VS 6.0 in ufficio (lavoro principalmente in Java e .NET (SharpDevelop 2.0).
Ad ogni modo non è l'unico sistema. Si può creare ad hoc un controllo del tutto simile al
command button con le proprietà richieste e bastano 74 righe di 'puro' VB.

PS: Usa un tono meno arrogante, meno da saputello, la prossima volta che rispondi.

I CommandButton non posseggono la proprietà ForeColor, Brainjar ....
Forse l'età e l'esperienza (quanta poi?) ti fanno sentire molto sicuro di te.
La soluzione da te proposta, però, la dice lunga sulla tua 'conoscenza' di VB 6.0.

Per i curiosi e per mykael100 :

1) Inserite in un file queste righe di codice :
codice:
VERSION 5.00
Begin VB.UserControl bjCommand 
   ClientHeight    =   375
   ClientLeft      =   0
   ClientTop       =   0
   ClientWidth     =   1560
   ScaleHeight     =   375
   ScaleWidth      =   1560
   Begin VB.TextBox Text 
      Alignment       =   2  'Center
      Appearance      =   0  'Flat
      BorderStyle     =   0  'None
      Height          =   225
      Left            =   90
      Locked          =   -1  'True
      MultiLine       =   -1  'True
      TabIndex        =   1
      Text            =   ""
      Top             =   60
      Width           =   1395
   End
   Begin VB.CommandButton Command 
      Height          =   375
      Left            =   0
      Style           =   1  'Graphical
      TabIndex        =   0
      Top             =   0
      Width           =   1575
   End
End
Attribute VB_Name = "bjCommand"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Public Event Click()
Private Sub Command_Click()
    RaiseEvent Click
End Sub
Private Sub UserControl_Initialize()
    Text.BackColor = Command.BackColor
End Sub
Public Property Get Caption() As String
    Caption = Text.Text
End Property
Public Property Let Caption(ByVal cap As String)
    Text.Text = cap
End Property
Public Property Get ForeColor() As OLE_COLOR
    ForeColor = Text.ForeColor
End Property
Public Property Let ForeColor(ByVal colore As OLE_COLOR)
    Text.ForeColor = colore
End Property
Public Property Get BackColor() As OLE_COLOR
    BackColor = Command.BackColor
End Property
Public Property Let BackColor(ByVal colore As OLE_COLOR)
    Text.BackColor = colore
    Command.BackColor = colore
End Property
Public Property Set Font(ByVal colore As Font)
    Set Text.Font = colore
End Property
Public Property Get Font() As Font
    Set Font = Text.Font
End Property
Private Sub UserControl_Resize()
    Command.Width = UserControl.Width
    Command.Height = UserControl.Height
    Text.Width = UserControl.Width - 60
    Text.Left = 30
    Text.Top = (UserControl.Height - Text.Height) / 2
End Sub
2) Salvate il file con il nome 'bjCommand.ctl'
3) Inseritelo come file nei votri progetti VB.

Avrete i Command Buttons con la proprietà ForeColor direttamente nella palette dei
componenti.
Al controllo in questione mancano alcune 'finezze' come la persistenza del settaggio delle
nuove proprietà a design-time. Ad ogni modo potrete personalizzarlo a piacere.