conoscere url corrente

[stex1984]

ciao
c'è un modo per sapere l'url corrente?

esempio:
se mi trovo in:
http://www.miodominio.it/contatti.asp

ho modo di ricavare all'interno della pagina lo stesso indirizzo?

[Santino83_02]

dim url

url=request.serverVariables("URL")
if request.serverVariables("QUERY_STRING")<>"" then url=url & "?" & request.serverVariables("QUERY_STRING")

oppure se vuoi solo sapere se ti trovi in una determinata pagina del tuo sito (comprensiva di path)

response.write request.serverVariables("PATH_INFO")

[stex1984]

grazie...
tecnicamente io voglio sapere l'url corrente perchè voglio fare il cambio di una variabile messa in get all'url

ad esempio:
se mi trovo su:
www.miodominio.it/pagina.asp?id=1&l=it
voglio sapere l'url per passare a:
www.miodominio.it/pagina.asp?id=1&l=en

[fabioRGV]

dal tuo ultimo post non si capisce bene cosa vuoi fare...
sulla load della pagina puoi risalire all'url con window.location.href, document.url, frame.src, e poi ci fai quello che vuoi...

[Santino83_02]

l'ho scritta al volo:

'pUrl= url in cui interessa cambiare il querystring
'toChange= elemento del querystring da cambiare (viene aggiunto se non presente)
'newValue= nuovo valore da assegnare

function changeQueryString(pUrl,toChange,newValue)

pUrl=pUrl & "?"

	if request.ServerVariables("QUERY_STRING")="" then
		pUrl=pUrl & toChange & "=" & newValue
	else
	
		if instr(1,request.ServerVariables("QUERY_STRING"),toChange & "=",1)=0 then
			if right(pUrl,1)<>"?" then pUrl=pUrl & "&"
			pUrl=pUrl & toChange & "=" & newValue
		end if
		
		for each el in request.QueryString
			if right(pUrl,1)<>"?" then pUrl=pUrl & "&"
			if lcase(el)=lcase(toChange) then
				pUrl=pUrl & el & "=" & newValue
			else
				pUrl=pUrl & el & "=" & request.QueryString(el)
			end if
		next
	end if
	
changeQueryString=pUrl
end function

EDIT:

uso:

url=request.serverVariables("URL")    'non ha il querystring

nUrl=changeQueryString(url,"id",12)

[stex1984]

grazie 1000!!!
sembra proprio funzionare!!!!
un'ultima cosa...
c'è un modo per non mettere la funzione in ogni pagina?
mi spiego...
posso mettere la funzione in un altro file e poi richiamarla dalle pagine che mi serve?

[Santino83_02]

Originariamente inviato da stex1984
grazie 1000!!!
sembra proprio funzionare!!!!
un'ultima cosa...
c'è un modo per non mettere la funzione in ogni pagina?
mi spiego...
posso mettere la funzione in un altro file e poi richiamarla dalle pagine che mi serve?

la metti nella pagina pippo.asp e poi la richiami con

[stex1984]

grazie 1000!!!!

[Santino83_02]

prego, 1000 euro

[Santino83_02]

Ho ritrovato una funzione che avevo salvato, la allego per i posteri essendo probabilmente piu performante della mia:

function ParametroQueryString(strurl,nomeParametro,valoreParametro)
	arrTemp=Split(strurl,"?")
	if UBound(arrTemp)=1 then
		set re=Server.CreateObject("VBScript.RegExp")
		re.Pattern="((^|&)" & nomeParametro & "=).*?(&|$)"
		re.Global=true
		re.IgnoreCase=true
		if re.Test(arrTemp(1)) then
			ParametroQueryString=arrTemp(0) & "?" & re.Replace(arrTemp(1),"$1" & valoreParametro & "$3")
		else
			ParametroQueryString=arrTemp(0) & "?" & arrTemp(1) & "&" & nomeParametro & "=" & valoreParametro
		end if		
	else
		ParametroQueryString=strurl & "?" & nomeParametro & "=" & valoreParametro
	end if
end function

url = "http://www.sito.it/?parametro1=valore&parametro2=valore2&parametro3=valore3"
Response.Write Server.HTMLEncode(url) & "


" 
Response.Write Server.HTMLEncode(ParametroQueryString(url,"parametro1","valore1cambiato")) & "


" 
Response.Write Server.HTMLEncode(ParametroQueryString(url,"parametro2","valore2cambiato")) & "


" 
Response.Write Server.HTMLEncode(ParametroQueryString(url,"parametro3","valore3cambiato")) & "


" 
Response.Write Server.HTMLEncode(ParametroQueryString(url,"parametroNuvo","valoreNuovo")) & "


<hr>"