[vb6 - vba] creare un foglio di excel senza fogli predefiniti

[andreaciao_22]

ciao Luisa,

Prova questo codice da vba di excel

Sub ProvaCopia()
    Dim NewBook As Workbook, ActWkb As Workbook, CopySheet As Worksheet, shNewBook As Worksheet
    Dim intShNew As Integer, scUpdate As Boolean, dpAlert As Boolean
    With Application
        scUpdate = .ScreenUpdating
        dpAlert = .DisplayAlerts
        intShNew = .SheetsInNewWorkbook
        .ScreenUpdating = False
        .SheetsInNewWorkbook = 1
        .DisplayAlerts = False
        Set ActWkb = .ActiveWorkbook 'o il workbook da cui devi copiare
        Set CopySheet = ActWkb.Sheets(1)
        Set NewBook = .Workbooks.Add
        Set shNewBook = NewBook.Sheets(1)
        shNewBook.Name = "!!!|||!!!"
        CopySheet.Copy shNewBook
        shNewBook.Delete
        NewBook.Activate
        Set shNewBook = Nothing
        Set NewBook = Nothing
        Set CopySheet = Nothing
        Set ActWkb = Nothing
        .SheetsInNewWorkbook = intShNew
        .ScreenUpdating = scUpdate
        .DisplayAlerts = dpAlert
    End With
End Sub

dimmi cosa ti esce