[BASIC DB ACCESS] Percorso immagine

[osgb]

Qui sotto inserisco un codice sql di access perchè volevo visualizzare nella maschera un immagine da una cartella predefinita, diversa per ogni record ed identificata in base al valore di un altro campo. Nel caso in cui l'immagine non ci fosse ne visualizzerebbe una di default dal nome 0.jpg

Nelle righe evidenziate da "NON FUNZIONA" ci sarebbe la parte che mi interessa attivare perchè non mi serve un percorso testo, ma un collegamento ad un oggetto immagine.

Private Sub Form_Current()

Dim visua As Integer
Dim valore1 As Integer
Dim Percorso As String

Dim fs


valore1 = Nz([Forms]![Anagrafico]![IDGiocatore], 0)

Set fs = CreateObject("Scripting.FileSystemObject")

If fs.FileExists("C:\Database_COSOV\Foto\" & valore1 & ".jpg") Then
            visua = valore1
    Else
            visua = 0
    End If
    
Percorso = "C:\Database_COSOV\Foto\" & visua & ".jpg"

'---- FUNZIONA!!!! ---------
'---------------------------

[Forms]![Anagrafico]![PercImm] = Percorso
' Il campo PercImm è un testo con il percorso dell'immagine

'---------------------------
'---- NON FUNZIONA!!!! ----
'---------------------------

[Forms]![Anagrafico]![Foto].[Picture] = percorso
'Il campo Foto è un oggetto immagine non associato

'---------------------------

End Sub

Grazie mille.

[comas17]

Dal Regolamento...

1) In questo forum si parla di Database (relazionali e non) e di tutte le problematiche legate alla loro installazione, utilizzo, manutenzione. Vengono trattati problemi relativi alla scrittura di comandi SQL (query, funzioni, stored procedures) ed alla loro esecuzione
In questo forum NON si parla di alcune funzionalità peculiari di Microsoft Access (macro, maschere, report, etc) che continueranno ad essere trattate nel forum "Windows e software"

Sposto

[nman]

Quello che hai scritto è giusto tranne che su un dettaglio

___ [Forms]![Anagrafico]![Foto].[Picture] = percorso
[Picture] lo devi scrivere senza parentesi quadre

o meglio potresti scrivere
Me.Foto.Picture = percorso
( Me fa riferimento alla maschera in cui ti trovi )

__________________________________________________ ____________
__________________________________________________ ____________
__________________________________________________ ____________
__________________________________________________ ____________


Tuttavia io riscriverei tutto cosi:

Private Sub Form_Current()

On Error GoTo Foto0

Dim perc As String ' Il percorso della catrella delle foto
perc = "C:\Database_COSOV\Foto\"

Me.Foto.Picture = perc & Me.IdGiocatore & ".jpg"
Exit Sub

Foto0:
Me.Foto.Picture = perc & "0.jpg"

End Sub

Inserisci la gestione errori che se non trova la tua foto dove indicato
ti apre la foto di default


Facci sapere

[nman]

Pero cosi e ancor meglio

Private Sub Form_Current()

On Error GoTo Foto0

Dim perc As String ' Il percorso della catrella delle foto
perc = "C:\Database_COSOV\Foto\"

    Me.Foto.Picture = perc & Me.IdGiocatore & ".jpg"
    
Exxit:
Exit Sub

Foto0:
    If Err.Number = 2220 Then  ' errore 2220 = manca foto
        Me.Foto.Picture = perc & "0.jpg"
    Else
        MsgBox Err.Description & "    n° " & Err.Number
    End If
    Resume Exxit
End Sub

[osgb]

Grazie mille del consiglio.
Mi scuso se non ho risposto prima, comunque così come mi ha indicato funziona