rollover pulsante in primo piano assoluto

[Sleter]

Ciao

Meglio se invece di usare i Pulsanti fai tutto con i MovieClip che sono più gestibili e più potenti.
Potresti mettere le finestre su un livello superiore, settarle su .visible = false e richiamarle al MouseOver (risettarle su visible = false al MouseOut).

Esempio per un puntino (MC) sul livello 1 e finestra sul livello 2:

finestra_1.visible = false;
pulsante_1.buttonMode = true;

pulsante_1.addEventListener(MouseEvent.MOUSE_OVER, apriFinestra);
pulsante_1.addEventListener(MouseEvent.MOUSE_OUT, chiudiFinestra);

function apriFinestra(evento:MouseEvent):void
{
    finestra_1.visible = true
}
function chiudiFinestra(evento:MouseEvent):void
{
    finestra_1.visible = false
} 

Se hai molti puntini e rispettive finestre, invece di scrivere tutto questo codice per ogni singolo elemento (puntino e rispettiva finestra) si può ottimizzare con gli Array e un ciclo for:

var pulsanti:Array = new Array(pulsante_1, pulsante_2)
var finestre:Array = new Array(finestra_1, finestra_2)

inizializza()
function inizializza():void
{
    for(var i:uint = 0; i < pulsanti.length; i ++)
    {
        finestre[i].visible = false
        pulsanti[i].buttonMode = true;
        pulsanti[i].addEventListener(MouseEvent.MOUSE_OVER, identificaOpen)
        pulsanti[i].addEventListener(MouseEvent.MOUSE_OUT, identificaClose)
    }
}
function identificaOpen(evento:MouseEvent):void
{
    apriFinestra(evento.target)
}
function identificaClose(evento:MouseEvent):void
{
    chiudiFinestra(evento.target)
}
function apriFinestra(bottone:*):void
{
    var id:int = pulsanti.indexOf(bottone);
    finestre[id].visible = true
}
function chiudiFinestra(bottone:*):void
{
    var id:int = pulsanti.indexOf(bottone);
    finestre[id].visible = false
} 

In questo secondo esempio ti basta aggiungere i nomi di puntini e finestre negli Array e nel campo <Nome Istanza> dei MC, tutti gli elementi si comporteranno allo stesso modo e le rispettive finestre saranno visibili sul livello superiore solo al mouseOver.

ciao