[Windows]Batch per spostare directory

[marino51]

ciao, il grosso è fatto, ma la copia/sposta la inserisci tu, così devi guardare lo script e capirlo .... per evitare di perdere dati
se lo esegui cosi' com'e' ti fa solo la lista delle cartelle che hai indicato "sca" con "_files"
attento a non perdere per strada qualche carattere "strano" mentre maneggi il batch (tilde, ecc.....)

@echo off
rem http://forum.html.it/forum/showthrea...readid=2921648

rem nel percorso seguente si trovano le cartelle da spostare (non deve essere la root del disco es. c:\)
set WebSource=C:\Web_Sites

rem la cartella seguente ospiterà le cartelle spostate
set WebDest=C:\NEW_Web_Sites

rem ATTENZIONE AI NOMI DOPPI ....

FOR /R %WebSource% %%D IN (.) DO (call :DoIt "%%D")
pause
exit /b
 
:DoIt
  set MySource=%~f1
  if /I "%MySource:~-6%" NEQ "_files" exit /b
  call :StrLength %MySource%
  call set cart1=%%MySource:~0,%backslash%%%
  call set cart2=%%MySource:~%backslash%%%
  if /I "%cart2:~0,3%" NEQ "sca" exit /b
  echo %cart1%   -   %cart2%
  echo la stringa e' lunga %length% caratteri, la backslash si trova in posizione %backslash%
  exit /b
 
:StrLength
rem StrLength(string)
rem ritorna la lunghezza della stringa e la posizione della backslash più a destra
  set #=%1%
  set length=0
  set backslash=0
  :stringLengthLoop
  if defined # (
    set #=%#:~1%
    set /A length += 1
    set bks=%#:~0,1%
    if "%bks%"=="\" set backslash=%length%
    goto :stringLengthLoop
  )
rem echo %1%
rem echo la stringa e' lunga %length% caratteri, la backslash si trova in posizione %backslash%
exit /b

non è un fulmine di guerra in termini di velocita', pensa alla ferrari F14T(leggi FIAT) rispetto alla Mercedes