vb6 e file .inf

[amodio]

salve a tutti
avendo un file inf come posso reperire informazioni su questo file?
del tipo un'intenstazione -->[data]
vorrei reperire i dettagli

ho provato a fare un ciclo for, ma mi sembra poco professionale

grazie

[xegallo]

gli inf si leggono come gli ini fai una ricerca ne abbiamo già parlato ampiamente

[amodio]

ah ini scusa

ma la ricerca è disabilitata
ho provato

[xegallo]

ups mi ero scordato

Public Declare Function WritePrivateProfileString Lib "kernel32" _
Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, _
ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
Public Declare Function GetPrivateProfileString Lib "kernel32" _
 Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, _ 
ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, _
ByVal nSize As Long, ByVal lpFileName As String) As Long

Public Function WriteStringIni(ByVal sSection As String, ByVal sKeyName As String, ByVal sString As String, ByVal sFileName As String) As Integer
' Scrive una stringa in un file *.INI
'    Input:  sSection      sezione
'            sKeyName      parola chiave
'            sString       stringa da scrivere
'            sFileName     file *.INI
'    Output: False: fallita;  True: Ok
Dim nResult As Integer
On Error GoTo WriteStringIniError
   
   nResult = WritePrivateProfileString(sSection, ByVal sKeyName, ByVal sString, sFileName)
   If nResult = 0 Then
      WriteStringIni = False
   Else
      WriteStringIni = True
   End If
   
Exit Function
WriteStringIniError:
    WriteStringIni = False
End Function

Public Function ReadStringIni(ByVal sSection As String, ByVal sKeyName As String, ByVal sFileName As String) As String
' Legge una stringa da un file *.INI
'    Input:  sSection      sezione
'            sKeyName      parola chiave
'            sFileName     file *.INI
'    Output: stringa letta oppure "-1" se fallita lettura
'
Dim nResult As Integer
Dim sDefault As String
Dim sReturnedString As String
Dim nSize As Integer
On Error GoTo ReadStringIniError
   
   sDefault = ""
   sReturnedString = Space$(255)
   nSize = 255
   nResult = GetPrivateProfileString(sSection, sKeyName, sDefault, sReturnedString, nSize, sFileName)
   If nResult <> 0 Then
      ReadStringIni = Left$(sReturnedString, nResult)
   Else
      'errore
      ReadStringIni = "-1"
   End If

Exit Function
ReadStringIniError:
   ReadStringIni = "-1"
End Function