Da mdb a txt

[luca.gigliofior]

Ciao a tutti, purtroppo sono costretto a postare, la funzione ricerca ancora non funzica
Problemino sicuramente trattato parecchie volte, da asp devo fare una select sul db (access) e fino qui niente di strano, ora devo far si che una volta eseguito il codice asp mi ritrovo un txt con i campi che ho stabiliti nella select, separati da pipe | , e alla fine di ogni record devo mettere <fineriga>, come faccio?
Qualche spunto?

[jesus]

Dovrebbe esserci un metodo del recordset che fa proprio questo, tipo GetString.

[luca.gigliofior]

Originariamente inviato da jesus
Dovrebbe esserci un metodo del recordset che fa proprio questo, tipo GetString.

Non riesco a trovare nulla in merito, ti ricordi un esempio?

[Corwin]

<%
Set Rs = Server.CreateObject("ADODB.Recordset")
Set conn = Server.CreateObject("ADODB.Connection")
conn.open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("db.mdb")
Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Set f = FSO.CreateTextFile(Server.MapPath("miofile.txt"),true)
sql = "SELECT * FROM TABELLA"
Rs.Open sql, conn
While not rs.Eof
s = ""
For x = 0 to rs.Fields.Count -1
If x = rs.fields.count -1 Then
s = s & rs(x) 
else
s = s & rs(x) & "|"
end if
Next
f.WriteLine s
rs.Movenext
Wend
f.close
%>

[kalosjo]

Il metodo getstring dell'oggetto adodb.recordset effettua questa operazione in una sola istruzione!!

stringa = rs.getstring(,,"|",vbcrlf)

restituisce una stringa che scritta in un file da colonne separate da pipe e righe successive

[luca.gigliofior]

Perfetto Corwin ha funzionato a primo colpo!!! , una sola cosa, come faccio a metterci <fineriga> alla fine di ogni riga?

[kalosjo]

Originariamente inviato da luca.gigliofior
Perfetto ha funzionato a primo colpo!!! , una sola cosa, come faccio a metterci <fineriga> alla fine di ogni riga?

Se è proprio la parola allora :

stringa = rs.getstring(,,"|","<fineriga>" & vbcrlf)

[luca.gigliofior]

Originariamente inviato da kalosjo
Il metodo getstring dell'oggetto adodb.recordset effettua questa operazione in una sola istruzione!!

stringa = rs.getstring(,,"|",vbcrlf)

restituisce una stringa che scritta in un file da colonne separate da pipe e righe successive

Non ti seguo .... come uso quel comando sopra? non vedo specificato da nessuna parte dove andare a scrivere ....

[kalosjo]

allora.

sSQL="select * from tabella where ......."
rs.open sSQL, conn
stringa=rs.getstring(,,"|","<fineriga>" & vbcrlf)
Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Set f = FSO.CreateTextFile(Server.MapPath("miofile.txt"),true)
f.WriteLine stringa
f.close
set f=nothing
set FSO=nothing

[luca.gigliofior]

Originariamente inviato da kalosjo
allora.

sSQL="select * from tabella where ......."
rs.open sSQL, conn
stringa=rs.getstring(,,"|","<fineriga>" & vbcrlf)
Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Set f = FSO.CreateTextFile(Server.MapPath("miofile.txt"),true)
f.WriteLine stringa
f.close
set f=nothing
set FSO=nothing

Perfetto, ora và a meraviglia, dunque se ora volessi inserire tra i campi che mi compaiono delimitati dal pipe, un campo semifisso (nel senso che sul database non ce l'ho, ma me lo posso ricavare poiche una parte sarà "pluto.asp?" fissa e ci aggiungo codice=x&codice1=y che mi ricavo dagli id degli articoli, dove devo intervenire? Mettiamo che questo campo lo volgio mettere alla sesta colonna, dove glielo indico?
Grazie ancora per la disponibilità e la pazienza