errore: ADODB.Stream (0x800A0BBC)

[rinosan_76]

Ciao a tutti...
Ho creato un piccolo file con una classe scaricata:

<%@LANGUAGE="VBSCRIPT"%> 
<%
Class CString

 Private Buffer

 Private Sub Class_Initialize()
  Set Buffer = Server.CreateObject("ADODB.Stream")
  Buffer.Charset = "ISO-8859-1"
  Buffer.Type = 2
  Buffer.Open()
 End Sub

 Public Function ToArray()
  Dim Ar(),i
  Redim Ar(Buffer.Size) 
  Buffer.Position = 0
  For i=0 to Buffer.Size
   Ar(i)=Buffer.ReadText(1)
  Next
  ToArray = Ar
 End Function

 Public Function Clear()
  On error resume next
  Buffer.Close()
  on error goto 0
  Buffer.Open()
 End Function

 Public Sub Append(byRef value)
  Buffer.WriteText(value)
 End Sub

 Public Sub AppendLine(byRef value)
   Buffer.WriteText(value & VbCrLf)
 End Sub

 Public Function GetIndex(Index)
  Dim p
  p = Buffer.Position 
  Seek(Index)
  GetIndex = Read(1)
  Buffer.Position = p
 End Function
	
 Public Function Read(Bytes)
  Read = Buffer.ReadText(Bytes)
 End Function

 Public Sub Seek(Position)
  Buffer.Position = Position
 End Sub

 Public Sub Skip(Value)
  Buffer.Position = Buffer.Position + Value
 End Sub
	
 Public default Function GetBuffer()
  Seek(0)
  GetBuffer = Buffer.ReadText()
 End Function

 Public Function Length()
  Length = Buffer.Size
 End Function

 Private Function MapPath(s)
  Dim Res
  on error resume next
  Res = Server.MapPath(s)
  if err.number<>0 then Res = s
   on error goto 0
  MapPath = Res
 End Function

 Public Sub SaveToFile(FileName,OverWrite)
  FileName = MapPath(FileName)
  If OverWrite=1 then 
   OverWrite=1
  elseif OverWrite=2 then
   OverWrite=2
  End if
  Buffer.SaveToFile FileName,OverWrite
 End Sub

 Private Sub Class_Terminate()
  Buffer.Close()
  Set Buffer = Nothing
 End Sub

End Class



 cartella="file_KIT"
 nome="prova"
 set stringa=new cString
 stringa.Append("prova riuscita")
 file=Server.Mappath(cartella) & "/" & Trim(nome) & ".kit"
 response.write file
 stringa.SaveToFile file,2
%>

Sul mio Pc (w2k pro) con IIS funziona e fa quello che deve: scrivermi l'indirizzo del file e crearlo con una scritta dentro. Premetto che la classe la uso spesso, quindi penso sia corretta. Sul server 2000 family del mio cliente da questo errore... è un problema di permessi sul server? Lui dice che sono a posto, anche se io non mi fido troppo!
Grazie
Rino

[Roby_72]

Io vedo barre rovesciate che non mi tornano...

Roby

[santino83]

anche io vedo barre rovesciate

magari se ci dici in dettaglio che devono fare tutte quelle funzioni uno capisce anche meglio cosa vuoi fare te e qual'è il problema

[rinosan_76]

scusate se non ho risposto... infatti facevo bene a non fidarmi... il codice è ok, erano i permessi non corretti.
Cmq grazie