no, lo trasformi.
guardati questa funzione dove:
sTplName è il percorso al file xsl
PageXml è una stringa contenente il tuo codice XML
codice:
Function TransformXML(sTplName, PageXml) 
	' sTplName: stringa, nome file xsl PRIVO di estensione
	' PageXml: stringa, buffer file XML
	Dim PageTemplate, PageProcessor, PageHTML, docXml 
	If isobject(Application(sTplName & "_xsl")) and Application("cachedTemplates") then 
		Set PageTemplate = Application(sTplName & "_xsl")
	else
		dim PageXsl
		set PageXsl = Server.CreateObject("MSXML2.FreeThreadedDOMDocument.3.0")
		With PageXsl	
			.async = false
			.load (Application("xsl_path") & sTplName & ".xsl")
		End with
		set PageTemplate = Server.CreateObject ("MSXML2.XSLTemplate.3.0")
		PageTemplate.stylesheet = PageXsl
		set Application(sTplName & "_xsl") = PageTemplate
	end if
	' carica l'xml
	Set docXml = Server.CreateObject("MSXML2.FreeThreadedDOMDocument.3.0")
	With docXml 	
		.async = false
		.loadXML(PageXml)
	End with
	' crea il processore xsl
	set PageProcessor = PageTemplate.createProcessor()
	With PageProcessor
		.input = docXml ' carica l'xml nell'xsl
		.transform() ' effettua la trasformazione
		PageHtml = .output ' inserisce il risultato in una variabile
	End with
	Set PageProcessor = Nothing
	Set docXml = nothing
	TransformXML = PageHtml
End Function
Ciao, Massimiliano anch'io