loadVar non carica da txt

[dieresiLAB]

Ciao gente,
ho fatto uno script per poter caricare da .txt una variabile che altro non è che il nome del .flv da caricare nell'oggetto video, ma suddetta variabile (in questo caso _root.nome) non viene nemmeno tracciata. Perché??
eccovi il codice:



dati = new LoadVars();
dati.path = this;
dati.onLoad = function(success) {
_root.nome = this.nome_filmato;
_root.durata = this.durata_filmato;
};
dati.load("specifiche_filmato.txt");

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);
stream_ns.play("video.flv");
trace(_root.nome);


Tengo a sottolineare che entrambe le variabili del txt vengono perfettamente lette se le traccio all'interno di una funzione successiva (ad esempio qui dentro)

function checkTime(my_ns:NetStream) {
var ns_seconds:Number = my_ns.time;
var minutes:Number = Math.floor(ns_seconds/60);
var seconds = Math.floor(ns_seconds%60);
if (seconds<10) {
seconds = "0"+seconds;
}
time_txt.text = minutes+":"+seconds;
_root.bar_time._xscale = (100*my_ns.time)/_root.durata;
trace (_root.nome)
}


Quale può essere il problema?
non ci capisco più nulla
Grazie!!!

Marco

[negatyve]

La variabile la puoi usare "solo" dopo l'evento onLoad:

dati = new LoadVars();
dati.path = this;
dati.onLoad = function(success)
{
	_root.nome = this.nome_filmato;
	_root.durata = this.durata_filmato;
	var connection_nc:NetConnection = new NetConnection();
	connection_nc.connect(null);
	var stream_ns:NetStream = new NetStream(connection_nc);
	my_video.attachVideo(stream_ns);
	stream_ns.play("video.flv");
	trace(_root.nome);
};
dati.load("specifiche_filmato.txt");