Il primo riguarda la proprietà Pattern del FileListBox. Il valore che gli ho assegnato è "*.bmp; *.gif; *.jpg; *.jpeg; *.tif; *.tiff; *.psd; *.png", ma mi visualizza solo i file *.bmp...come mai ? ?
Perchè il carattere di separazione fra un'estensione e l'altra è ";" e non " ;" (senza spazio)
Il secondo riguarda il DirListBox. Quando clikko la periferica Floppy o Cd-Rom (ovviamente vuote) sul DriveListBox, mi genera un'errore sulla proprietà Path del DirListBox...come faccio a gestirlo ? ? ?
L'errore è il numero 68 (Periferica non pronta).
Puoi gestirlo ad esempio così:
codice:
Private Sub Drive1_Change()
On Error GoTo GestioneErrori
Dim RispostaMsg As VbMsgBoxResult

Dir1.Path = Drive1.Drive

Exit Sub
GestioneErrori:
If (Err.Number = 68) Then
  RispostaMsg = MsgBox("Impossibile accedere a " & UCase$(Drive1.Drive) & "\" & vbCr & vbCr & "Periferica non pronta.", vbRetryCancel + vbCritical, "Ricerca in " & UCase$(Drive1.Drive) & "\")
    If RispostaMsg = vbRetry Then
      Drive1_Change
    End If
    If RispostaMsg = vbCancel Then
      Drive_Precedente
    End If
End If
If (Err.Number <> 0 And Err.Number <> 68) Then
  MsgBox (CStr(Err.Number) & Err.Description), vbCritical, "Errore"
End If
End Sub

Private Sub Drive_Precedente()
On Error GoTo GestioneErrori

Drive1.Drive = Left$(Dir1.Path, 2)

Exit Sub
GestioneErrori:
If (Err.Number = 68) Then
  MsgBox "Impossibile accedere a " & UCase$(Drive1.Drive) & "\ e a " & UCase(Left$(Dir1.Path, 3)) & vbCr & vbCr & "Periferiche non pronte.", vbOKOnly + vbCritical, "Ricerca in " & UCase$(Drive1.Drive) & "\ e " & UCase(Left$(Dir1.Path, 3))
End If
If (Err.Number <> 0 And Err.Number <> 68) Then
  MsgBox (CStr(Err.Number) & Err.Description), vbCritical, "Errore"
End If
End Sub
Vi ringrazio...buona continuazione!!
continuazione...