Originariamente inviato da simcario
Il problema è che a volte la finestra di dos rimane aperta, il ciclo si blocca e rimango fregato...

Dovrei trovare un modo per far continuare il programma solo le la finestra di Dos è chiusa

Sai suggerirmi qualcosa?

Grazie Tante
Non ha molto senso cominciare un altro thread sullo stesso problema se la soluzione c'e'. Il fatto che la Shell debba essere sincrona lo risolvi non utilizzando l'istruzione Shell ma il codice che segue (suggerito da MS stessa ...)

Nel form inserisci le seguenti dichiarazioni di strutture, costanti e API

codice:
Private Type STARTUPINFO
   cb As Long
   lpReserved As String
   lpDesktop As String
   lpTitle As String
   dwX As Long
   dwY As Long
   dwXSize As Long
   dwYSize As Long
   dwXCountChars As Long
   dwYCountChars As Long
   dwFillAttribute As Long
   dwFlags As Long
   wShowWindow As Integer
   cbReserved2 As Integer
   lpReserved2 As Long
   hStdInput As Long
   hStdOutput As Long
   hStdError As Long
End Type

Private Type PROCESS_INFORMATION
   hProcess As Long
   hThread As Long
   dwProcessID As Long
   dwThreadID As Long
End Type

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
   hHandle As Long, ByVal dwMilliseconds As Long) As Long

Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
   lpApplicationName As String, ByVal lpCommandLine As String, ByVal _
   lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
   ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
   ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As String, _
   lpStartupInfo As STARTUPINFO, lpProcessInformation As _
   PROCESS_INFORMATION) As Long

Private Declare Function CloseHandle Lib "kernel32" _
   (ByVal hObject As Long) As Long

Private Declare Function GetExitCodeProcess Lib "kernel32" _
   (ByVal hProcess As Long, lpExitCode As Long) As Long

Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const INFINITE = -1&
aggiungi la funzione che segue

codice:
Private Function ExecCmd(cmdline As String)
    Dim ret As Long
    Dim proc As PROCESS_INFORMATION
    Dim start As STARTUPINFO
    
    start.cb = Len(start)
    
    ret = CreateProcessA(vbNullString, cmdline, 0&, 0&, 1&, _
                         NORMAL_PRIORITY_CLASS, 0&, vbNullString, start, proc)
    
    ret = WaitForSingleObject(proc.hProcess, INFINITE)
    Call GetExitCodeProcess(proc.hProcess, ret&)
    Call CloseHandle(proc.hThread)
    Call CloseHandle(proc.hProcess)
    
    ExecCmd = ret
End Function
e, nel tuo codice, elimina l'istruzione Shell sostituendola con

codice:
ret = ExecCmd("cmd /c pslist \\" & ip & " -u administrator -p " & pass & " " & txtprocesso.Text & " >c:\output.txt", 1)
in cui ret e' una variabile Long (non dimenticare di dichiarare esplicitamente tutte le variabili ... usa Option Explicit sempre nel tuo codice ...) che puoi esaminare prima di continuare nel codice per capire se c'e' stato un problema. Se e' 0 allora puoi continuare eliminando il Delay ...