[VB6] Disabilitare connessione di rete

[Jupy64]

Ciao a tutti, avrei la necessita, da programma, di disabilitare la connessione di rete ad un certo orario e poi riabilitarla in un'altro orario.. ho cercato di vedere anche tramite le WMI ma non sono riuscito a trovare niente. Qualcuno sa come posso fare?
In pratica ho un server che è sempre acceso, giorno e notte, dove gira oracle, onde evitare che qualcuno si possa collegare dopo l'orario di lavoro, dovrei scollegarlo dalla rete (non serve disabilitare gli utenti, in quanto se uno conosce l'indirizzo ip del server e account/password del db oracle, può entrare lo stesso), senza staccare il cavo e senza spegnere il server, per questo pensavo a disabilitare la rete. Altrimenti qualcuno conosce un metodo diverso? magari se c'è la possibilità di schedulare tramite oracle gli accessi in determinati orari sarebbe l'ideale..
grazie

[oregon]

Non sono certo che tu stia scegliendo la strada giusta disabilitando la rete ... comunque eccoti il codice che ho scritto un paio di anni fa ... Controlla se funziona (!), elimina i MsgBox se non ti servono e, soprattutto, adattalo alla lingua inglese dove serve se lo usi con W2K3 ...

Option Explicit
Private Const sNetConn = "Rete e connessioni remote"
Private Const sConnName = "Connessione alla rete locale (LAN)"

Private Sub Command1_Click()
    DoNetVerb "&Abilita"
End Sub

Private Sub Command2_Click()
    DoNetVerb "&Disabilita"
End Sub

Private Sub DoNetVerb(ByVal NetVerb As String)
    Dim oShellApp As Object
    Dim oCtrlPanel As Object
    Dim oNetConnections As Object
    Dim oFolder As Object
    Dim oLanConnection As Object
    Dim oNetVerb As Object
    Dim oVerb As Object
    Dim Wait As Boolean

    Set oShellApp = CreateObject("Shell.Application")
    Set oCtrlPanel = oShellApp.Namespace(3)

    Set oNetConnections = Nothing
    For Each oFolder In oCtrlPanel.items
      If LCase(oFolder.Name) = LCase(sNetConn) Then
        Set oNetConnections = oFolder.GetFolder
        Exit For
      End If
    Next

    If oNetConnections Is Nothing Then
        MsgBox "Il folder '" & sNetConn & "' non e' stato trovato.", vbCritical, "Attenzione"
    Else
        Set oLanConnection = Nothing
        For Each oFolder In oNetConnections.items
            If LCase(oFolder.Name) = LCase(sConnName) Then
                Set oLanConnection = oFolder
                Exit For
            End If
        Next

        If oLanConnection Is Nothing Then
            MsgBox "La connessione '" & sConnName & "' non e' stata trovata.", vbCritical, "Attenzione"
        Else
            Set oNetVerb = Nothing
            For Each oVerb In oLanConnection.verbs
                If oVerb.Name = NetVerb Then
                    Set oNetVerb = oVerb
                    Exit For
                End If
            Next

            If oNetVerb Is Nothing Then
                MsgBox "Impossibile eseguire il verbo '" & NetVerb & "'", vbCritical, "Attenzione"
            Else
                oNetVerb.DoIt
                Do
                    Wait = False
                    DoEvents
                    For Each oVerb In oLanConnection.verbs
                        If oVerb.Name = NetVerb Then
                            Wait = True
                            Exit For
                        End If
                    Next
                Loop While Wait

                MsgBox "Operazione eseguita."
            End If
        End If
    End If

    Set oVerb = Nothing
    Set oNetVerb = Nothing
    Set oLanConnection = Nothing
    Set oFolder = Nothing
    Set oNetConnections = Nothing
    Set oCtrlPanel = Nothing
    Set oShellApp = Nothing
End Sub

[Jupy64]

Intanto grazie, l'ho proverò e ti farò sapere.
Dici che non è la strada giusta per raggiungere il mio obiettivo.. secondo te quale sarebbe la soluzione migliore? Visto che ho già un programmino fatto da me per abbattere/avviare il servizi di windows, avrei pensato anche di abbattere i servizi di oracle..e poi riavviarli prima dell'orario di lavoro.. ma non so.. visto che alla fine il server è sempre in rete.. e magari è sempre esposto in qualche maniera..

[oregon]

Ma il problema qual e'?

Anch'io gestisco (molti) server che sono attivi 24h su 24h.
C'e' il firewall, l'antivirus e sono aggiornati con le ultime patch di sicurezza. Ai servizi sono abilitati gli utenti con le relative password.

Non ho mai avuto la necessita' di spegnerli o disattivarli nel periodo in cui non sono utilizzati.

[Jupy64]

Il problema non deriva nella sede dove lavoro, ma dalla sede centrale, dove possono connettersi al db oracle (conoscono l'ip del server), e hanno un loro utente oracle con diritti di amministratore (che non posso disabilitare per questioni tecniche).. ora io voglio evitare che si connettino oltre l'orario di lavoro, a meno che non mi avvisino per tempo.

[oregon]

Non so cosa dirti ma la situazione e' veramente strana.

Non mi sognerei mai di negare l'accesso alle mie macchine ad un utente amministratore, in qualsiasi ora della giornata perche' mi fido. In caso contrario, revocherei lo status di amministratore a tale persona.

[Jupy64]

capisco quello che dici, e sono daccordo con te, ma la mia è una situazione un po' particolare... per determinati montivi non posso disabilitare questo utente admin. Il tutto è nato dal fatto che ho il sospetto che da altre sedi (non la centrale) siano a conoscenza di utenti/password che possono usare solo ed esclusivamente quelli della sede centrale..ma non ho prove di questo.. e per evitare ogni problema avevo pensato di disabilitare la connessione..
Mi rendo conto che non sapendo tutta la situazione, non è facile capire il perchè di questa necessita'...