[VB6] Riempimento stringa di spazi

[mistersuperstar]

Ciao a tutti,
dovrei visualizzare un campo che ho nel recordset, però ho bisogno di visualizzare sempre e comunque una stringa di 20 caratteri,anche se il campo è lungo 4, come faccio?

grazie a tutti

[oregon]

Aggiungi 16 spazi ...

[mistersuperstar]

okkei, :-)

ma chiedevo se c'era una funzione che già imposta la mia stringa a 20

[GudFella]

Originariamente inviato da oregon
Aggiungi 16 spazi ...

:rollo:

Dim str As String * 20

[mistersuperstar]

già provato, ma nel momento in cui la visualizzo, nn mi occupa 20 spazi, ma la lunghezza della stringa

[oregon]

Ci fai vedere il codice che usi ... ?

[alka]

Originariamente inviato da mistersuperstar
[vb 6]

Per favore, usa titoli più significativi e sintetizza il problema oltre ad indicare il linguaggio.

Ciao!

[Socket2000]

If Len(TuaStringa) < 20 Then TuaStringa = TuaStringa & Space(20 - Len(TuaStringa))

[oregon]

Oppure

Dim a As String

a = Space$(20)
LSet a = "CIAO"

[xegallo]

Public Function PadL(s As Variant, n As Integer) As String
' Allinea a sinistra
'   INPUT: variant:  stringa da riempire
'          integer:  totale lunghezza stringa
'   ESEMPIO: PadL("Pippo", 10) = "Pippo     "
        
    s = CStr(s)
    If Len(s) >= n Then
        PadL = Left$(s, n)
    Else
        PadL = s & Space(n - Len(s))
    End If
    
End Function

Public Function PadR(s As Variant, n As Integer) As String
' Allinea a destra
'   INPUT: variant:  stringa da riempire
'          integer:  totale lunghezza stringa
'   ESEMPIO: PadR("Pippo", 10) = "     Pippo"
    
    s = CStr(s)
    If Len(s) >= n Then
        PadR = Left$(s, n)
    Else
        PadR = Space(n - Len(s)) & s
    End If

End Function

Public Function PadC(s As Variant, n As Integer) As String
' Allinea a sinistra
'   INPUT: variant:  stringa da riempire
'          integer:  totale lunghezza stringa
'   ESEMPIO: PadC("Pippo", 10) = "  Pippo   "
'
        
    s = CStr(s)
    If Len(s) >= n Then
        PadC = Left$(s, n)
    Else
        If (n - Len(s)) Mod 2 = 0 Then
            PadC = Space((n - Len(s)) \ 2) & s & Space((n - Len(s)) \ 2)
        Else
            PadC = Space((n - Len(s)) \ 2) & s & Space((n - Len(s)) \ 2) & " "
        End If
    End If
    
End Function