[VB5] Uso di ImageList per caricare menu di immagini

[tony.hood]

Siccome sto imparando ho Problemi ad imparare a far funzionare imagelist,
mi potete aituare con qualche esempio di VB come fare un menu di immagini che carica
le immagini presenti in una cartella fissa?
"uso Visual basic 5" per alka

[alka]

Originariamente inviato da tony.hood
"uso Visual basic 5" per alka

Non ho capito il riferimento... cosa c'entro io?

[tony.hood]

almeno ci sei Tu

[Boolean]

perchè non provi a rispiegare meglio il problema, dicendo *esattamente* cosa ti serve fare?

Boolean

[tony.hood]

ecco cosa......

Praticamente devo fare

Un programmino che da percorso fisso Del tipo E o D
attraverso un pulsante comando mi apra il contenuto in un elenco di file in piccole anteprime.

fine

ecco tutto..........

Grazie

[Boolean]

copia per intero il testo qui sotto, incollalo in Blocco Note, e salvalo come frmPreview.frm, poi caricalo con VB

VERSION 5.00
Object = "{831FDD16-0C5C-11D2-A9FC-0000F8754DA1}#2.0#0"; "MsComCtl.ocx"
Begin VB.Form frmPreview 
   Caption         =   "Form1"
   ClientHeight    =   6510
   ClientLeft      =   60
   ClientTop       =   375
   ClientWidth     =   8595
   LinkTopic       =   "Form1"
   ScaleHeight     =   6510
   ScaleWidth      =   8595
   StartUpPosition =   3  'Windows Default
   Begin VB.PictureBox Picture1 
      Height          =   825
      Left            =   3435
      ScaleHeight     =   765
      ScaleWidth      =   945
      TabIndex        =   2
      Top             =   180
      Visible         =   0   'False
      Width           =   1005
   End
   Begin MSComctlLib.ImageList ilsAnteprime 
      Left            =   2205
      Top             =   180
      _ExtentX        =   1005
      _ExtentY        =   1005
      BackColor       =   -2147483643
      MaskColor       =   12632256
      _Version        =   393216
   End
   Begin MSComctlLib.ListView lvwElenco 
      Height          =   5160
      Left            =   210
      TabIndex        =   1
      Top             =   1065
      Width           =   8115
      _ExtentX        =   14314
      _ExtentY        =   9102
      LabelWrap       =   -1  'True
      HideSelection   =   -1  'True
      _Version        =   393217
      ForeColor       =   -2147483640
      BackColor       =   -2147483643
      BorderStyle     =   1
      Appearance      =   1
      NumItems        =   0
   End
   Begin VB.CommandButton Command1 
      Caption         =   "Command1"
      Height          =   420
      Left            =   195
      TabIndex        =   0
      Top             =   315
      Width           =   1515
   End
End
Attribute VB_Name = "frmPreview"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Dim FSO As Object


Private Sub Command1_Click()
Dim FLD As Object
Dim IMG As Object
Dim tmpImg As StdPicture
       
    Set FLD = FSO.GetFolder("E:\Grafica\Images\Immagini")
    
    lvwElenco.ColumnHeaders.Add , , "Anteprima", 3000
    
    lvwElenco.View = lvwReport
    
    On Error Resume Next
    W = 128 * Screen.TwipsPerPixelX
    H = 96 * Screen.TwipsPerPixelY
    Picture1.Width = W
    Picture1.Height = H

    ilsAnteprime.ListImages.Add , , Picture1.Image
    Set lvwElenco.SmallIcons = ilsAnteprime
    
For Each IMG In FLD.Files
    Set tmpImg = LoadPicture(IMG.Path)
    Picture1.BorderStyle = 0
    Picture1.AutoRedraw = True
    Picture1.PaintPicture tmpImg, 0, 0, W, H
    ilsAnteprime.ListImages.Add , , Picture1.Image
    lvwElenco.ListItems.Add , , IMG.Name, , ilsAnteprime.ListImages.Count
    DoEvents
Next

End Sub

Private Sub Form_Load()
Set FSO = CreateObject("Scripting.FileSystemObject")
End Sub

Boolean

[tony.hood]

Grazie mille stavo cercando proprio questo!!!!!!!!!!!!!!!!!!!
ma come faccio ad impostarlo in modo che siano messe in ordine da cinque o sei colonne ?

Sei Grande BOOLEAN

TONY.HOOD : IPPIP A BOOLEAN!!

CORO: URRA!!
TONY.HOOD : IPPIP A BOOLEAN!!

CORO: URRA!!
TONY.HOOD : IPPIP A BOOLEAN!!

CORO: URRA URRA!!

GRAZIE ANCORA!!!!!!!!!!!! :maLOL:

[Boolean]

puoi provare a cambiare questa proprietà, utilizzando gli altri tipi di visualizzazione

lvwElenco.View = lvwList

oppure

lvwElenco.View = lvwSmallIcon

Boolean

[tony.hood]

Hai capito bene!!!!!!!!


Scusa ancora.
Ma invece di usare il percorso fisso come si fa?
io ho un esempio di visualizzatore che ora ti faccio vederre
"come si fa a mettere tutto il codice come hai fatto tu nel bloc note cosi ti invio Questo esempio?"

Sub Form_Load()
Dircartelle.Path = CurDir
drvdrive.Drive = Dircartelle.Path
filListafile.Path = Dircartelle.Path
filListafile.Pattern = "*.BMP;*.GIF;*.JPG;*.PNG"
If filListafile.ListCount > 0 Then
filListafile.ListIndex = 0
End If
End Sub
Private Sub Dircartelle_Change()
filListafile.Path = Dircartelle.Path
filListafile.Pattern = "*.BMP;*.GIF;*.JPG;*.PNG"
End Sub
Private Sub Dircartelle_LostFocus()
Dircartelle.Path = Dircartelle.List(Dircartelle.ListIndex)
End Sub
Private Sub drvDrive_Change()
Dircartelle.Path = drvdrive.Drive
End Sub
Private Sub filListaFile_Click()
Imgfigura.Picture = LoadPicture(filListafile.Path + "\" _
+ filListafile.List(filListafile.ListIndex))
End Sub
Private Sub cmdfine_click()
End
End Sub

In questo esempio attraverso:
image
drivelistbox
fileLista
dirCartella
e un comond
attraverso questo esempio si riesce a visualizzare Qualsiasi immagine presente in una Cartella di qualsiasi indizzo
quale di questo codice si usa? e si se si usa?

Grazie ancora e Scusa il disturbo.

[Boolean]

per postare tutto il Form, salvalo, e poi aprilo con Blocco Note, il contenuto del file lo posti sul Forum.