Pagina 2 di 2 primaprima 1 2
Visualizzazione dei risultati da 11 a 14 su 14
  1. #11
    Utente di HTML.it L'avatar di abellos
    Registrato dal
    Feb 2002
    Messaggi
    254
    EVVVVVAIIIIIIIII usando un recordset disconnesso sono riuscito ad usare tutta la parte di impaginazione che era già a posto!!!!
    grazie a tutti e due
    Da un grande potere derivano grandi responsabilità

  2. #12
    Moderatore di XHTML e HTML L'avatar di Vincent.Zeno
    Registrato dal
    May 2003
    residenza
    Emilia-Romagna (tortellini und cappelletti land!)
    Messaggi
    18,982


    ti va di riportare qui l'esempio pratico al quale sei arrivato?

  3. #13
    Utente di HTML.it L'avatar di abellos
    Registrato dal
    Feb 2002
    Messaggi
    254
    Ecco il codice che ho usato, in pratica creo un nuovo recordset disconnesso RSDiscon e aggiungo i record vuoti all'inizio, poi aggiungo i record che prendo da RSeti che contengono i dati da stampare.
    Uso la variabile etichetteVuote per sapere quanti record vuoti devo aggiungere
    codice:
    <!--#include file="../inc/liv1.asp"-->
    <!--#include file="../inc/adovbs.inc"-->
    <%
    codRichiesta = request("codRichiesta")
    ordinaPerPratica = request("ordinaPerPratica")
    etichetteVuote = request("etichetteVuote")
    
    if etichetteVuote = "" then etichetteVuote=0
    if ordinaPerPratica = "" then ordinaPerPratica=0
    
    if codRichiesta = "" then
         response.write "Selezionare una richiesta"
         response.end
    end if
    
    Set Conn = Server.CreateObject("ADODB.Connection")
    
    Conn.Open("Driver={Microsoft Access Driver (*.mdb)}; DBQ="& session("path")(0))
    
    'controllo il tipo di documento per sapere come ordinare le etichette, per le richieste o per
    ' l'invio in filiale
    SQL = "SELECT richieste.codTipoDoc FROM richieste GROUP BY richieste.codTipoDoc, richieste.codRichiesta "& _
    " HAVING (((richieste.codRichiesta)="& codRichiesta &"))"
    set RSord = conn.Execute(SQL)
    
    if RSord.EOF then
        response.Write "Etichette insesistenti per l'evasione n° "& codRichiesta
        response.End
    end if
    
    if RSord("codTipoDoc")=12 then
        ord = " richieste.progressivoRichiesta ASC;"
    else
        if ordinaPerPratica=1 then
            ord = " gest_arch.pratica; "
        else
            ord = " gest_arch.scatola DESC, gest_arch.progressivo DESC; "
        end if
    end if
    RSord.close
    set RSord = nothing
    
    Set RSEti = server.CreateObject("ADODB.RecordSet")
    SQL = "SELECT richieste.codRichiesta, gest_arch.coddoc, gest_arch.pratica, gest_arch.scatola, gest_arch.progressivo, richieste.codTipoDoc, def_tipo.descrizioneTipoDoc "& _
    " FROM (richieste INNER JOIN gest_arch ON richieste.codDoc = gest_arch.coddoc) LEFT JOIN def_tipo ON richieste.codTipoDoc = def_tipo.codTipoDoc "& _
    " WHERE (((richieste.codRichiesta)="& codRichiesta &")) ORDER BY "& ord
    
    RSEti.open SQL, conn
    
    'uso un recordset disconnesso aggiungendo i dati presi da RSEti :))))
    Set RSDiscon = server.CreateObject("ADODB.RecordSet")
    
    'fields.Append Name, Type, DefinedSize, Attrib, FieldValue
    RSDiscon.CursorType = adOpenKeyset
    RSDiscon.LockType = 2
    RSDiscon.Fields.Append "codRichiesta", adInteger
    RSDiscon.Fields.Append "codDoc", adInteger
    RSDiscon.Fields.Append "pratica", adInteger
    RSDiscon.Fields.Append "scatola", adInteger
    RSDiscon.Fields.Append "progressivo", adInteger
    RSDiscon.Fields.Append "codTipoDoc", adInteger
    RSDiscon.Fields.Append "descrizioneTipoDoc", adChar, 50
    RSDiscon.open
    
    'ciclo for per aggiungere n etichette vuote prima di quelle da stampare
    if etichetteVuote > 0 then
        for k = 1 to etichetteVuote
            RSDiscon.AddNew
            RSDiscon("codRichiesta").Value = 0
            RSDiscon("codDoc") = 0
            RSDiscon("pratica") = 0
            RSDiscon("scatola") = 0
            RSDiscon("progressivo") = 0
            RSDiscon("codTipoDoc") = 0
            RSDiscon("descrizioneTipoDoc") = "0"
            RSDiscon.Update
        next
    end if
    
    'ora posso aggiungere il vero recordset di etichette
    while not RSEti.EOF
        RSDiscon.AddNew
        RSDiscon("codRichiesta") = RSEti("codRichiesta")
        RSDiscon("codDoc") = RSEti("codDoc")
        RSDiscon("pratica") = RSEti("pratica")
        RSDiscon("scatola") = RSEti("scatola")
        RSDiscon("progressivo") = RSEti("progressivo")
        RSDiscon("codTipoDoc") = RSEti("codTipoDoc")
        RSDiscon("descrizioneTipoDoc") = RSEti("descrizioneTipoDoc")
        RSDiscon.Update
        RSEti.moveNext
    wend
    
    RSEti.close
    set RSEti = nothing
    %>
    
    <html>
    <head>
    <script language="JavaScript" src="../blocca.js"></script>
    <script language="JavaScript" src="../inc/jquery.js"></script>
    <script language="Javascript" type="text/javascript">
    $(document).ready(function()
     {    
        etichetteVuote = <%=etichetteVuote%>;
        
        $('#menoEti').click(function(evento) {
            evento.preventDefault();
            
            if (etichetteVuote > 0){
                eti = etichetteVuote - 1;
            }        
            window.location='etichette.asp?codRichiesta=<%=codrichiesta%>&ordinaPerPratica=<%=ordinaPerPratica%>&etichetteVuote='+ eti;
        });
        
        $('#piuEti').click(function(evento) {
            evento.preventDefault();
            
            if (etichetteVuote < 15){
                eti = etichetteVuote + 1;
            }        
            window.location='etichette.asp?codRichiesta=<%=codrichiesta%>&ordinaPerPratica=<%=ordinaPerPratica%>&etichetteVuote='+ eti;
        });
     });
    
    </script>
    <style>
    @media print{
       .noprint{
           display:none;
       }
    }
    </style>
    </head>
    <body style="margin-top: 0cm; margin-left: 0cm;"  title="Clicca per stampare">
    
    <table cellpadding="0" cellspacing="0" border="1" class="noprint">
    <tr><td><a href="" id="menoEti">meno</a></td><td><a href="" id="piuEti">piu</a></td><td><%=etichetteVuote%></td></tr>
    </table>
    
    <table border="0" style="width:17cm" cellpadding="0" cellspacing="0" onclick="self.print();">
    <tr>
    
    <%
    rowcount=0
    eti=0
    RSDiscon.moveFirst
    while NOT RSDiscon.EOF
    eti=eti+1
    rowcount=rowcount+1
    
    if (eti mod 16 = 1 or eti mod 16 = 2) or (eti mod 16 = 15 or eti mod 16 = 0) then
    %>
        <td><table border="0" style="width:10cm;height:3.277cm;"> <!-- 3.277cm-->
    <%
    else
    %>
        <td><table border="0" style="width:10cm;height:3.7cm;"> <!-- 3.7cm -->
    <%
    end if
    %>
    <%
    'verifico se codrichiesta = 0 non visualizzo niente
    if RSDiscon("codRichiesta")>0 then
    %>    
           <tr>
           <td align="center"><img src="../image/logo_small_b.jpg"></td>
           <td align="center"><input readonly type="text" value="<%=FormatNumber(RSDiscon("pratica"),0)%>" style="border: 1px dotted #000000;text-align:center;font-weight:bold;font-size:13pt">
           </td>
           </tr>
           <tr>
           <td valign="top">
           <table align="center">
           <tr><td style="text-align:center;font-size:9pt;font-family:tahoma" valign="top"><%=right("000" & session("path")(1),3)%>-<%=RSDiscon("codDoc")%>-<%=RSDiscon("codTipoDoc")%></td></tr>
           <tr><td style="text-align:center;font-size:9pt;font-family:tahoma" valign="top"><%=RSDiscon("scatola")%>-<%=RSDiscon("progressivo")%></td></tr>
           </table>
           </td>
           <td valign="top">
           <table align="center">
           <tr><td style="text-align:center;font-size:9pt;font-family:tahoma"><%=RSDiscon("descrizioneTipoDoc")%> n°</td></tr>
           <tr><td style="text-align:center;font-size:14pt;"><font face="39251">*<%=right("000"& session("path")(1),3)%>-<%=RSDiscon("codDoc")%>-<%=RSDiscon("codTipoDoc")%>*</font></td></tr>
           </table>
           </td>
           </tr>
           
    <%
    else
    %>
           <tr>
           <td></td>
           </tr>
    <%
    end if
    %>
           </table>
             
         </td>
    <%
    
    if eti mod 2 = 0 then 
        response.write "</tr><tr>"    
    elseif rowcount mod 2 = 0 and eti mod 16 = 0 then
        response.write "</tr><tr></table>"    
    end if
    
    if eti mod 16 = 0 then
        response.Write "</table><DIV STYLE='page-break-before:always;'></DIV><table border=0 style='width:17cm' cellpadding=0 cellspacing=0><tr>"
    end if
    RSDiscon.movenext
    wend
    
    RSDiscon.close
    set RSDiscon = nothing
    
    conn.Close
    set conn = nothing
    %>       
    
    </body>
    </html>
    Da un grande potere derivano grandi responsabilità

  4. #14
    Moderatore di XHTML e HTML L'avatar di Vincent.Zeno
    Registrato dal
    May 2003
    residenza
    Emilia-Romagna (tortellini und cappelletti land!)
    Messaggi
    18,982
    grazie per la condivisione

    poi mi fai sapere se la tua stampante digerisce bene il foglio cerato di supporto per le etichette?
    al primo riuso non mi da tanti problemi, ma dal secondo in poi è la rovina
    occhio a non lasciare bordi di carta adesiva sul foglio: finisce che si appiccicano sul rullo e si deve cambiarlo.

Permessi di invio

  • Non puoi inserire discussioni
  • Non puoi inserire repliche
  • Non puoi inserire allegati
  • Non puoi modificare i tuoi messaggi
  •  
Powered by vBulletin® Version 4.2.1
Copyright © 2019 vBulletin Solutions, Inc. All rights reserved.