Visualizzazione dei risultati da 1 a 5 su 5
  1. #1
    Utente di HTML.it L'avatar di abellos
    Registrato dal
    Feb 2002
    Messaggi
    324

    Win server 2012 Asp classic errori personalizzati

    Ciao a tutti,
    ho impostato iis 8 in modo da non visualizzare gli errori dettagliati come da immagine 1.
    Funziona come da immagine 2, ma sull'errore 500 vorrei che mi visualizzasse l'errore dell'asp come prima in modo da poterlo conoscere e risolvere e non l'errore generico di immagine 3.
    Mi potete dare una mano?
    grazie
    Immagini allegate Immagini allegate
    Da un grande potere derivano grandi responsabilità

  2. #2
    Utente di HTML.it L'avatar di Joe Taras
    Registrato dal
    Nov 2003
    residenza
    Taranto
    Messaggi
    918
    Dalla immagine 1 che hai postato, quel popup è contestualizzato al codice di errore, quindi lasci per gli altri diversi da 500 la configurazione che hai impostato, mentre per il 500 lasci la detailed

  3. #3
    Utente di HTML.it L'avatar di abellos
    Registrato dal
    Feb 2002
    Messaggi
    324
    Ciao, no purtroppo non e' cosi, se provo a cambiare l'errore 404 cambia anche quell'impostazione per tutti gli altri errori, e' un impostazione che vale per tutti
    Da un grande potere derivano grandi responsabilità

  4. #4
    Utente di HTML.it L'avatar di Joe Taras
    Registrato dal
    Nov 2003
    residenza
    Taranto
    Messaggi
    918
    Quote Originariamente inviata da abellos Visualizza il messaggio
    Ciao, no purtroppo non e' cosi, se provo a cambiare l'errore 404 cambia anche quell'impostazione per tutti gli altri errori, e' un impostazione che vale per tutti
    Ciao,
    potrebbe esserti utile questa guida:

    https://docs.microsoft.com/en-us/iis...er/httperrors/

  5. #5
    Utente di HTML.it L'avatar di abellos
    Registrato dal
    Feb 2002
    Messaggi
    324
    Ciao Joe,
    seguendo la guida ho fatto un passo avanti, ora ho questo nel mio web.config
    codice:
    <httpErrors errorMode="Custom">                        
    			<remove statusCode="500" subStatusCode="-1" />
    			<error statusCode="500" prefixLanguageFilePath="" path="/errori/500-100.asp" responseMode="ExecuteURL" />
    		</httpErrors>
    ma non riesco ad avere come risposta
    codice:
    Errore di compilazione di Microsoft VBScript error '800a0409'
    Costante String senza terminazione
    /errori/errore.asp, riga 3
    var = "stringa
    --------------^
    il file 500-100.asp l'ho trovato nella cartella degli errori custom di IIS ed e' questo, ma non mi visualizza il report qui sopra che e' quello che mi servirebbe:
    codice:
    <%@ language="VBScript" %>
    <%
      Option Explicit
    
    
      Const lngMaxFormBytes = 200
    
    
      Dim objASPError, blnErrorWritten, strServername, strServerIP, strRemoteIP
      Dim strMethod, lngPos, datNow, strQueryString, strURL
    
    
      If Response.Buffer Then
        Response.Clear
        Response.Status = "500 Internal Server Error"
        Response.ContentType = "text/html"
        Response.Expires = 0
      End If
    
    
      Set objASPError = Server.GetLastError
    %>
    <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01//EN" "http://www.w3.org/TR/html4/strict.dtd">
    <HTML><HEAD><TITLE>Impossibile visualizzare la pagina</TITLE>
    <META HTTP-EQUIV="Content-Type" Content="text/html; charset=Windows-1252">
    <STYLE type="text/css">
      BODY { font: 8pt/12pt verdana }
      H1 { font: 13pt/15pt verdana }
      H2 { font: 8pt/12pt verdana }
      A:link { color: red }
      A:visited { color: maroon }
    </STYLE>
    </HEAD><BODY><TABLE width=500 border=0 cellspacing=10><TR><TD>
    
    
    <h1>The page cannot be displayed</h1>
    There is a problem with the page you are trying to reach and it cannot be displayed.
    <hr>
    <p>Please try the following:</p>
    <ul>
    <li>Contact the Web site administrator to let them know that this error has occured for this URL address.</li>
    </ul>
    <h2>HTTP 500.100 - Internal server error: ASP error.<br>Internet Information Services</h2>
    <hr>
    <p>Technical Information (for support personnel)</p>
    <ul>
    <li>Error Type:<br>
    <%
      Dim bakCodepage
      on error resume next
    	bakCodepage = Session.Codepage
    	Session.Codepage = 1252
      on error goto 0
      Response.Write Server.HTMLEncode(objASPError.Category)
      If objASPError.ASPCode > "" Then Response.Write Server.HTMLEncode(", " & objASPError.ASPCode)
        Response.Write Server.HTMLEncode(" (0x" & Hex(objASPError.Number) & ")" ) & "<br>"
      If objASPError.ASPDescription > "" Then 
    	Response.Write Server.HTMLEncode(objASPError.ASPDescription) & "<br>"
      elseIf (objASPError.Description > "") Then 
    	Response.Write Server.HTMLEncode(objASPError.Description) & "<br>" 
      end if
      blnErrorWritten = False
      ' Only show the Source if it is available and the request is from the same machine as IIS
      If objASPError.Source > "" Then
        strServername = LCase(Request.ServerVariables("SERVER_NAME"))
        strServerIP = Request.ServerVariables("LOCAL_ADDR")
        strRemoteIP =  Request.ServerVariables("REMOTE_ADDR")
        If (strServerIP = strRemoteIP) And objASPError.File <> "?" Then
          Response.Write Server.HTMLEncode(objASPError.File)
          If objASPError.Line > 0 Then Response.Write ", line " & objASPError.Line
          If objASPError.Column > 0 Then Response.Write ", column " & objASPError.Column
          Response.Write "<br>"
          Response.Write "<font style=""COLOR:000000; FONT: 8pt/11pt courier new""><b>"
          Response.Write Server.HTMLEncode(objASPError.Source) & "<br>"
          If objASPError.Column > 0 Then Response.Write String((objASPError.Column - 1), "-") & "^<br>"
          Response.Write "</b></font>"
          blnErrorWritten = True
        End If
      End If
      If Not blnErrorWritten And objASPError.File <> "?" Then
        Response.Write "<b>" & Server.HTMLEncode(  objASPError.File)
        If objASPError.Line > 0 Then Response.Write Server.HTMLEncode(", line " & objASPError.Line)
        If objASPError.Column > 0 Then Response.Write ", column " & objASPError.Column
        Response.Write "</b><br>"
      End If
    %>
    </li>
    <li>Browser Type:<br>
    <%= Server.HTMLEncode(Request.ServerVariables("HTTP_USER_AGENT")) %>
    <br><br></li>
    <li>Page:<br>
    <%
      strMethod = Request.ServerVariables("REQUEST_METHOD")
      Response.Write Server.HTMLEncode(strMethod & " ")
      If strMethod = "POST" Then
        Response.Write Request.TotalBytes & " bytes to "
      End If
      Response.Write Server.HTMLEncode(Request.ServerVariables("SCRIPT_NAME"))
      Response.Write "</li>"
      If strMethod = "POST" Then
        Response.Write "<p><li>POST Data:<br>"
        ' On Error in case Request.BinaryRead was executed in the page that triggered the error.
        On Error Resume Next
        If Request.TotalBytes > lngMaxFormBytes Then
          Response.Write Server.HTMLEncode(Left(Request.Form, lngMaxFormBytes)) & " . . ."
        Else
          Response.Write Server.HTMLEncode(Request.Form)
        End If
        On Error Goto 0
        Response.Write "</li>"
      End If
    %>
    <br><br></li>
    <li>Time:<br>
    <%
      datNow = Now()
      Response.Write Server.HTMLEncode(FormatDateTime(datNow, 1) & ", " & FormatDateTime(datNow, 3))
      on error resume next
    	Session.Codepage = bakCodepage 
      on error goto 0
    %>
    <br><br></li>
    <li>More information:<br>
    <%  
      strQueryString = "prd=iis&sbp=&pver=5.0&ID=500;100&cat=" & Server.URLEncode(objASPError.Category) & "&os=&over=&hrd=&Opt1=" & Server.URLEncode(objASPError.ASPCode)  & "&Opt2=" & Server.URLEncode(objASPError.Number) & "&Opt3=" & Server.URLEncode(objASPError.Description) 
      strURL = "http://www.microsoft.com/ContentRedirect.asp?" & strQueryString
    %>
      <ul>
      <li>Click on <a href="<%= strURL %>">Microsoft Support</a> for a links to articles about this error.</li>
      <li>Go to <a href="http://go.microsoft.com/fwlink/?linkid=8180" target="_blank">Microsoft Product Support Services</a> and perform a title search for the words <b>HTTP</b> and <b>500</b>.</li>
      <li>Open <b>IIS Help</b>, which is accessible in IIS Manager (inetmgr), and search for topics titled <b>Web Site Administration</b>, and <b>About Custom Error Messages</b>.</li>
      <li>In the IIS Software Development Kit (SDK) or at the <a href="http://go.microsoft.com/fwlink/?LinkId=8181">MSDN Online Library</a>, search for topics titled <b>Debugging ASP Scripts</b>, <b>Debugging Components</b>, and <b>Debugging ISAPI Extensions and Filters</b>.</li>
      </ul>
    </li>
    </ul>
    
    
    </TD></TR></TABLE></BODY></HTML>
    Da un grande potere derivano grandi responsabilità

Permessi di invio

  • Non puoi inserire discussioni
  • Non puoi inserire repliche
  • Non puoi inserire allegati
  • Non puoi modificare i tuoi messaggi
  •  
Powered by vBulletin® Version 4.2.1
Copyright © 2022 vBulletin Solutions, Inc. All rights reserved.