Errore CDOSYS

**mr_chiocco** · 17-07-2006, 18:14

non capisco perchè mi da errore:

codice:

	Dim mail 'As CDO.Message
	Dim conf 'As CDO.Configuration
	Const NAMESPACE = "http://schemas.microsoft.com/cdo/configuration/"
	Const cdoSendUsingPort = 2
	Set mail = CreateObject("CDO.Message")
	Set conf = CreateObject("CDO.Configuration")
	conf.Fields(NAMESPACE & "sendusing") = cdoSendUsingPort
	conf.Fields(NAMESPACE & "smtpserver") = "localhost"
	conf.Fields(NAMESPACE & "smtpserverport") = 25
	conf.Fields.Update
	mail.Configuration = conf
	mail.CreateMHTMLBody "email.asp?nome="& nome
	mail.From = nominativo & " <"& email &">"
	mail.Subject = "Prenotazione"
	mail.To = "Prova <mrcdesign@gmail.com>"
	mail.Send

mi da errore sulla riga:

codice:

mail.CreateMHTMLBody "email.asp?nome="& nome

l'errore è questo:

codice:

CDO.Message.1 error '800c000d' 

The specified protocol is unknown. 

/prenota.asp, line 198

**viki1967** · 17-07-2006, 20:24

Verifica che il componente sia installato sul server:

codice:

<html>
<head>
<title>Server Component Checker</title>
</head>
<body>
<%

	Dim comList(54)
		comList(0) = Array( "AB Mailer","ABMailer.Mailman" )
		comList(1) = Array( "ABC Upload","ABCUpload4.XForm" )
		comList(2) = Array( "ActiveFile","ActiveFile.Post" )
		comList(3) = Array( "ActiveX Data Object","ADODB.Connection" )
		comList(4) = Array( "Adiscon SimpleMail","ADISCON.SimpleMail.1" )
		comList(5) = Array( "ASP HTTP","AspHTTP.Conn" )
		comList(6) = Array( "ASP Image","AspImage.Image" )
		comList(7) = Array( "ASP Mail","SMTPsvg.Mailer" )
		comList(8) = Array( "ASP Simple Upload","ASPSimpleUpload.Upload" )
		comList(9) = Array( "ASP Smart Cache","aspSmartCache.SmartCache" )
		comList(10) = Array( "ASP Smart Mail","aspSmartMail.SmartMail" )
		comList(11) = Array( "ASP Smart Upload","aspSmartUpload.SmartUpload" )
		comList(12) = Array( "ASP Tear","SOFTWING.ASPtear" )
		comList(13) = Array( "ASP Thumbnailer","ASPThumbnailer.Thumbnail" )
		comList(14) = Array( "ASP WhoIs","WhoIs2.WhoIs" )
		comList(15) = Array( "ASPEmail","Persits.MailSender" )
		comList(16) = Array( "ASPSoft NT Object","ASPSoft.NT" )
		comList(17) = Array( "ASPSoft Upload","ASPSoft.Upload" )
		comList(18) = Array( "CDONTS","CDONTS.NewMail" )
		comList(19) = Array( "CDOSYS","CDO.Message" )
		comList(20) = Array( "Chestysoft Image","csImageFile.Manage" )
		comList(21) = Array( "Chestysoft Upload","csASPUpload.Process" )
		comList(22) = Array( "Chili!Mail","CDONTS.NewMail" )
		comList(23) = Array( "Dimac JMail","JMail.Message" )
		comList(24) = Array( "Distinct SMTP","DistinctServerSmtp.SmtpCtrl" )
		comList(25) = Array( "dkQMail","dkQmail.Qmail" )
		comList(26) = Array( "Dundas Mailer","Dundas.Mailer" )
		comList(27) = Array( "Dundas Upload","Dundas.Upload.2" )
		comList(28) = Array( "Dynu Encrypt","Dynu.Encrypt" )
		comList(29) = Array( "Dynu HTTP","Dynu.HTTP" )
		comList(30) = Array( "Dynu Mail","Dynu.Email" )
		comList(31) = Array( "Dynu Upload","Dynu.Upload" )
		comList(32) = Array( "Dynu WhoIs","Dynu.Whois" )
		comList(33) = Array( "Easy Mail","EasyMail.SMTP.5" )
		comList(34) = Array( "Emailtoolbox","ArclabEmailToolBox.Mailer" )
		comList(35) = Array( "File System Object","Scripting.FileSystemObject" )
		comList(36) = Array( "Geocel.Mailer","GeoCel" )
		comList(37) = Array( "IISMail","iismail.iismail.1" )
		comList(38) = Array( "JMail","Jmail.smtpmail" )
		comList(39) = Array( "Ticluse Teknologi HTTP","InteliSource.Online" )
		comList(40) = Array( "Last Mod","LastMod.FileObj" )
		comList(41) = Array( "Microsoft XML Engine","Microsoft.XMLDOM" )
		comList(42) = Array( "Persits ASP JPEG","Persits.Jpeg" )
		comList(43) = Array( "Persits ASPEmail","Persits.MailSender" )
		comList(44) = Array( "Persits ASPEncrypt","Persits.CryptoManager" )
		comList(45) = Array( "Persits File Upload","Persits.Upload.1" )
		comList(46) = Array( "SmartMail","aspSmartMail.SmartMail" )
		comList(47) = Array( "SMTP Mailer","SmtpMail.SmtpMail.1" )
		comList(48) = Array( "Soft Artisans File Upload","SoftArtisans.FileUp" )
		comList(49) = Array( "Image Size", "ImgSize.Check" )
		comList(50) = Array( "Microsoft XML HTTP", "Microsoft.XMLHTTP" )
		comList(51) = Array( "Grafici Excel", "OWC.Chart" )
		comList(52) = Array( "ADODB Stream", "ADODB.Stream" )
		comList(53) = Array( "VSEmail1.0","VSEmail.SMTPSendMail" )
		comList(54) = Array( "VSEmail2.0","VSEmail.SMTPSendMailEx" )


	Function IsAvailable( comIdentity )
		On Error Resume Next
		IsAvailable = False
		Err = 0
		Set xTestObj = Server.CreateObject( comIdentity )
		If Err = 0 Then IsAvailable = True
		Set xTestObj = Nothing
		Err = 0
	End Function

	Public Function CheckCOM()
		Avail = 0
		strTxt = "<table cellpadding=""3"" cellspacing=""0"" border=""1"" bordercolor=""#000000"" align=""center"" width=""300"">" & vbNewLine
		strTxt = strTxt & "<tr><td align=""center"" bgcolor=""#3399ff""><font face=""tahoma"" size=""3"" color=""#000000"">COMPONENTE</font></td><td align=""center"" bgcolor=""#3399ff""><font face=""tahoma"" size=""3"" color=""#000000"">STATUS</font></td></tr>"
		For Idx = LBound( comList ) To UBound( comList )
			Provider = Idx
			strTxt = strTxt & vbTab & "<tr><td width=""150""><font face=""tahoma"" size=""2"" color=""#000000"">" & comList(Idx)(0) & "</font></td>"
			strTxt = strTxt & "<td align=""left""><font face=""tahoma"" size=""2"" color=""#000000"">[  "
			If IsAvailable( comList(Idx)(1) ) Then
				strTxt = strTxt & "<font face=""tahoma"" size=""2"" color=""blue"">Installato</font>"
				Avail = Avail + 1
			Else
				strTxt = strTxt & "Non Installato</font>"
			End If
			strTxt = strTxt & "  <font face=""tahoma"" size=""2"" color=""#000000"">]</font></td></tr>" & vbNewLine
		Next
		strTxt = strTxt & vbTab & "<tr><td colspan=4 height=30><font face=""tahoma"" size=""2"" color=""blue"">" & Avail & "</font><font face=""tahoma"" size=""2"" color=""#000000""> su "
	strTxt = strTxt & UBound( comList ) + 1 & " componenti installati.</font></td></tr>" & vbNewLine
		CheckCOM = strTxt & "</table>" & vbNewLine
	End Function

	Response.Write( CheckCOM() )
%>

<p align="center">
	<font face="Tahoma" size="2">Server Component Checker
Direttamente dal forum di html.it</font>
</p>
</body>
</html>

**santino83_11_04** · 17-07-2006, 20:45

CreateMHTMLBody ma sei sicuro che sia questo il comando giusto di cdo?

**mr_chiocco** · 18-07-2006, 09:06

Originariamente inviato da santino83_11_04
CreateMHTMLBody ma sei sicuro che sia questo il comando giusto di cdo?

No, non sono sicuro ma l'ho letto su una guida di HTML.it, mi vien da pensare che l'autore si sia sbagliato...

il componente il componente dovrebbe esserci, adesso controllo...

**mr_chiocco** · 18-07-2006, 09:07

questo è il link dove l'ho letto...

link

**mr_chiocco** · 18-07-2006, 09:27

Ho controllato, il componente c'è e funziona... sapete dirmi come risolvere??

**michele.santoro** · 18-07-2006, 13:37

Forse non dipenderà da questo, ma hai provato con:

codice:

mail.CreateMHTMLBody "http://tuoserver.com/email.asp?nome="& nome

oppure

codice:

mail.CreateMHTMLBody "http://www.tuoserver.com/email.asp?nome="& nome

sai, alle volte ....

**mr_chiocco** · 18-07-2006, 15:43

Dopo un'accurata ricerca ho trovato qualcuno che diceva che in realtà quel metodo non esiste in CDOSYS, quindi per risolvere il problema è necessario usare l'oggetto XMLHTTP...

ho riscritto il codice così e funziona:

codice:

response.expires = -1500 
response.AddHeader "PRAGMA", "NO-CACHE" 
response.CacheControl = "PRIVATE"

strURL = "http://www.nomesito.it/email.asp?nome="& nome
Set objXML = Server.CreateObject("Microsoft.XMLHTTP") 
objXML.Open "get", strURL, False
objXML.Send 
html = objXML.responseText 
Set objXML = Nothing 

	Dim mail 'As CDO.Message
	Dim conf 'As CDO.Configuration
	Const NAMESPACE = "http://schemas.microsoft.com/cdo/configuration/"
	Const cdoSendUsingPort = 2
	Set mail = CreateObject("CDO.Message")
	Set conf = CreateObject("CDO.Configuration")
	conf.Fields(NAMESPACE & "sendusing") = cdoSendUsingPort
	conf.Fields(NAMESPACE & "smtpserver") = "localhost"
	conf.Fields(NAMESPACE & "smtpserverport") = 25
	conf.Fields.Update
	mail.Configuration = conf
	mail.HTMLBody = html
	mail.From = nominativo & " <"& email &">"
	mail.Subject = "Oggetto"
	mail.To = "Nome <info@nomesito.it>"
	mail.Send

non so bene perchè ho scritto le prime tre righe ma funziona...

Discussione: Errore CDOSYS

Strumenti discussione

Ricerca discussione

Visualizza

Errore CDOSYS

Permessi di invio