upload

**cablos** · 08-08-2006, 15:30

ciao
mi postate x favore un semplicissimo script x uplodare un immagine in una cartella sul server

x favore nn mi dite di andare a vedere gli esempi di baul74 xkè nn ci capisco una mazza

grazie mille

**gensole** · 08-08-2006, 15:38

upload_form.asp

codice:

<html>
<head>
	<title>UPLOAD FILE</title>
</head>
<body>


<table border=0 width=360 bgcolor=#40576f cellspacing=1 align=center>
	<tr>
		<td width=400 align=center bgcolor=#40576f><FONT FACE="tahoma" color=#ffffff size=2>SELEZIONARE IL FILE PER L'UPLOAD</FONT></td>
	</tr>
  <tr>
    <td width="400" height="0" bgcolor="#E6E6FF">
    	<form method="POST" enctype="multipart/form-data" action="upload.asp">
          <p align="center"><font color="#000080" size="2" face="Arial">

          File: </font><input type="file" name="blob" size=30>

          <input type="submit" name="Enter" value="Aggiungi">
      </form>
    </td>
  </tr>
</table>


</body>
</html>

upload.asp

codice:

<%
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Upload con ASP by ASPCode.it - http://www.aspcode.it						 '
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'variabili di configurazione
Dim folder
folder = "\prova"				'directory sul server con accesso in scrittura
'fine variabili di configurazione

Response.Expires=0
Response.Buffer = TRUE
Response.Clear

Sub BuildUploadRequest(RequestBin)
	PosBeg = 1
	PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
	boundary = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
	boundaryPos = InstrB(1,RequestBin,boundary)
		Do until (boundaryPos=InstrB(RequestBin,boundary & getByteString("--")))
		Dim UploadControl
		Set UploadControl = CreateObject("Scripting.Dictionary")
		'Get an object name
		Pos = InstrB(BoundaryPos,RequestBin,getByteString("Content-Disposition"))
		Pos = InstrB(Pos,RequestBin,getByteString("name="))
		PosBeg = Pos+6
		PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
		Name = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
		PosFile = InstrB(BoundaryPos,RequestBin,getByteString("filename="))
		PosBound = InstrB(PosEnd,RequestBin,boundary)
			If  PosFile<>0 AND (PosFile<PosBound) Then
			PosBeg = PosFile + 10
			PosEnd =  InstrB(PosBeg,RequestBin,getByteString(chr(34)))
			FileName = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
			UploadControl.Add "FileName", FileName
			Pos = InstrB(PosEnd,RequestBin,getByteString("Content-Type:"))
			PosBeg = Pos+14
			PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
			ContentType = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
			UploadControl.Add "ContentType",ContentType
			PosBeg = PosEnd+4
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
			Value = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
			Else
			Pos = InstrB(Pos,RequestBin,getByteString(chr(13)))
			PosBeg = Pos+4
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
			Value = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
		End If
		UploadControl.Add "Value" , Value	
		UploadRequest.Add name, UploadControl	
		BoundaryPos=InstrB(BoundaryPos+LenB(boundary),RequestBin,boundary)
	Loop
End Sub
Function getByteString(StringStr)
 For i = 1 to Len(StringStr)
 	char = Mid(StringStr,i,1)
	getByteString = getByteString & chrB(AscB(char))
 Next
End Function
Function getString(StringBin)
 getString =""
 For intCount = 1 to LenB(StringBin)
	getString = getString & chr(AscB(MidB(StringBin,intCount,1))) 
 Next
End Function

byteCount = Request.TotalBytes

RequestBin = Request.BinaryRead(byteCount)
Dim UploadRequest
Set UploadRequest = CreateObject("Scripting.Dictionary")

BuildUploadRequest  RequestBin

contentType = UploadRequest.Item("blob").Item("ContentType")
filepathname = UploadRequest.Item("blob").Item("FileName")
filename = Right(filepathname,Len(filepathname)-InstrRev(filepathname,"\"))
value = UploadRequest.Item("blob").Item("Value")

'Create FileSytemObject Component
Set ScriptObject = Server.CreateObject("Scripting.FileSystemObject")

'Create and Write to a File
Set MyFile = ScriptObject.CreateTextFile(Server.mappath(folder)&"\"&filename)
 
For i = 1 to LenB(value)
	MyFile.Write chr(AscB(MidB(value,i,1)))
Next
 
MyFile.Close
%>

<html>
<head>
	<title>UPLOAD FILE</title>
</head>
<body>


<table border=0 width=360 bgcolor=#40576f cellspacing=1 align=center>
	<tr>
		<td width=400 align=center bgcolor=#40576f><FONT FACE="tahoma" color=#ffffff size=2>Il file <%=filename%> è stato uploadato con successo.</FONT></td>
	</tr>
  <tr>
    <td width="400" height="30" bgcolor="#E6E6FF" align=center>&lt; &lt; UPLOAD DI UN ALTRO FILE</font></td>
  </tr>
  <tr>
    <td width="400" height="10" bgcolor="#40576f" align=right>www.aspcode.it</font></td>
  </tr>
</table>


</body>
</html>

Il tutto gentilmente offerto da Aspcode.it

**cablos** · 08-08-2006, 15:42

graziee !!!

**cablos** · 08-08-2006, 15:47

l'ho provato su IIS ma mi da questo errore:

Informazioni tecniche (per il personale del supporto tecnico)

Tipo di errore:
Errore di run-time di Microsoft VBScript (0x800A004C)
Impossibile trovare il percorso
/up/upload.asp, line 84

Tipo di browser:
Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1; SV1)

Pagina:
POST 84158 bytes to /up/upload.asp

POST Data:
error '80020009'
Eccezione.

/iisHelp/common/500-100.asp, line 222

**gensole** · 08-08-2006, 15:52

devi settare la variabile forlder che trovi in testa al file upload.asp..... con il nome di una directory che hai nel tuo progetto.....l'hai lasciata a PROVA e non penso tu abbia una cartella di nome Prova

**cablos** · 08-08-2006, 15:54

si l'avevo cambiata cmq ho risolto, l'errore stava nel fatto che nn avevo dato i permessi in scrittura nella cartella

grazie lo stesso

**gensole** · 08-08-2006, 15:58

o quello che dicevo io o i permessi.....è sempre così......
ciao

Discussione: upload

Strumenti discussione

Ricerca discussione

Visualizza

upload

Permessi di invio