Problema con la funzione "segnala questo sito ad un amico"

***3_Luca_X*** · 15-08-2006, 14:36

Sto provando ora la funzione "segnala questo sito ad un amico"...Siccome non ho fatto questa funzione da solo,ma l'ho presa dal web credo che il codice sia esatto.L'errore che mi da al momento che premo il tasto send é il seguente

Server object error 'ASP 0177 : 800401f3'

Server.CreateObject Failed

/page.asp, line 202

800401f3

la linea 202 della pagina che mi indica il server é questa

set myMail = server.CreateObject("CDONTS.Newmail")

Sapete per caso di che cosa si tratta?

**Mizushi** · 15-08-2006, 17:26

Significa che il server non supporta l'oggetto cdonts.

Controlla gli oggetti supportati dal sever con questo semplice script:

codice:

<html>
<head>
<title>Server Component Checker</title>
</head>
<body>
<%

	Dim comList(54)
		comList(0) = Array( "AB Mailer","ABMailer.Mailman" )
		comList(1) = Array( "ABC Upload","ABCUpload4.XForm" )
		comList(2) = Array( "ActiveFile","ActiveFile.Post" )
		comList(3) = Array( "ActiveX Data Object","ADODB.Connection" )
		comList(4) = Array( "Adiscon SimpleMail","ADISCON.SimpleMail.1" )
		comList(5) = Array( "ASP HTTP","AspHTTP.Conn" )
		comList(6) = Array( "ASP Image","AspImage.Image" )
		comList(7) = Array( "ASP Mail","SMTPsvg.Mailer" )
		comList(8) = Array( "ASP Simple Upload","ASPSimpleUpload.Upload" )
		comList(9) = Array( "ASP Smart Cache","aspSmartCache.SmartCache" )
		comList(10) = Array( "ASP Smart Mail","aspSmartMail.SmartMail" )
		comList(11) = Array( "ASP Smart Upload","aspSmartUpload.SmartUpload" )
		comList(12) = Array( "ASP Tear","SOFTWING.ASPtear" )
		comList(13) = Array( "ASP Thumbnailer","ASPThumbnailer.Thumbnail" )
		comList(14) = Array( "ASP WhoIs","WhoIs2.WhoIs" )
		comList(15) = Array( "ASPEmail","Persits.MailSender" )
		comList(16) = Array( "ASPSoft NT Object","ASPSoft.NT" )
		comList(17) = Array( "ASPSoft Upload","ASPSoft.Upload" )
		comList(18) = Array( "CDONTS","CDONTS.NewMail" )
		comList(19) = Array( "CDOSYS","CDO.Message" )
		comList(20) = Array( "Chestysoft Image","csImageFile.Manage" )
		comList(21) = Array( "Chestysoft Upload","csASPUpload.Process" )
		comList(22) = Array( "Chili!Mail","CDONTS.NewMail" )
		comList(23) = Array( "Dimac JMail","JMail.Message" )
		comList(24) = Array( "Distinct SMTP","DistinctServerSmtp.SmtpCtrl" )
		comList(25) = Array( "dkQMail","dkQmail.Qmail" )
		comList(26) = Array( "Dundas Mailer","Dundas.Mailer" )
		comList(27) = Array( "Dundas Upload","Dundas.Upload.2" )
		comList(28) = Array( "Dynu Encrypt","Dynu.Encrypt" )
		comList(29) = Array( "Dynu HTTP","Dynu.HTTP" )
		comList(30) = Array( "Dynu Mail","Dynu.Email" )
		comList(31) = Array( "Dynu Upload","Dynu.Upload" )
		comList(32) = Array( "Dynu WhoIs","Dynu.Whois" )
		comList(33) = Array( "Easy Mail","EasyMail.SMTP.5" )
		comList(34) = Array( "Emailtoolbox","ArclabEmailToolBox.Mailer" )
		comList(35) = Array( "File System Object","Scripting.FileSystemObject" )
		comList(36) = Array( "Geocel.Mailer","GeoCel" )
		comList(37) = Array( "IISMail","iismail.iismail.1" )
		comList(38) = Array( "JMail","Jmail.smtpmail" )
		comList(39) = Array( "Ticluse Teknologi HTTP","InteliSource.Online" )
		comList(40) = Array( "Last Mod","LastMod.FileObj" )
		comList(41) = Array( "Microsoft XML Engine","Microsoft.XMLDOM" )
		comList(42) = Array( "Persits ASP JPEG","Persits.Jpeg" )
		comList(43) = Array( "Persits ASPEmail","Persits.MailSender" )
		comList(44) = Array( "Persits ASPEncrypt","Persits.CryptoManager" )
		comList(45) = Array( "Persits File Upload","Persits.Upload.1" )
		comList(46) = Array( "SmartMail","aspSmartMail.SmartMail" )
		comList(47) = Array( "SMTP Mailer","SmtpMail.SmtpMail.1" )
		comList(48) = Array( "Soft Artisans File Upload","SoftArtisans.FileUp" )
		comList(49) = Array( "Image Size", "ImgSize.Check" )
		comList(50) = Array( "Microsoft XML HTTP", "Microsoft.XMLHTTP" )
		comList(51) = Array( "Grafici Excel", "OWC.Chart" )
		comList(52) = Array( "ADODB Stream", "ADODB.Stream" )
		comList(53) = Array( "VSEmail1.0","VSEmail.SMTPSendMail" )
		comList(54) = Array( "VSEmail2.0","VSEmail.SMTPSendMailEx" )


	Function IsAvailable( comIdentity )
		On Error Resume Next
		IsAvailable = False
		Err = 0
		Set xTestObj = Server.CreateObject( comIdentity )
		If Err = 0 Then IsAvailable = True
		Set xTestObj = Nothing
		Err = 0
	End Function

	Public Function CheckCOM()
		Avail = 0
		strTxt = "<table cellpadding=""3"" cellspacing=""0"" border=""1"" bordercolor=""#000000"" align=""center"" width=""300"">" & vbNewLine
		strTxt = strTxt & "<tr><td align=""center"" bgcolor=""#3399ff""><font face=""tahoma"" size=""3"" color=""#000000"">COMPONENTE</font></td><td align=""center"" bgcolor=""#3399ff""><font face=""tahoma"" size=""3"" color=""#000000"">STATUS</font></td></tr>"
		For Idx = LBound( comList ) To UBound( comList )
			Provider = Idx
			strTxt = strTxt & vbTab & "<tr><td width=""150""><font face=""tahoma"" size=""2"" color=""#000000"">" & comList(Idx)(0) & "</font></td>"
			strTxt = strTxt & "<td align=""left""><font face=""tahoma"" size=""2"" color=""#000000"">[  "
			If IsAvailable( comList(Idx)(1) ) Then
				strTxt = strTxt & "<font face=""tahoma"" size=""2"" color=""blue"">Installato</font>"
				Avail = Avail + 1
			Else
				strTxt = strTxt & "Non Installato</font>"
			End If
			strTxt = strTxt & "  <font face=""tahoma"" size=""2"" color=""#000000"">]</font></td></tr>" & vbNewLine
		Next
		strTxt = strTxt & vbTab & "<tr><td colspan=4 height=30><font face=""tahoma"" size=""2"" color=""blue"">" & Avail & "</font><font face=""tahoma"" size=""2"" color=""#000000""> su "
	strTxt = strTxt & UBound( comList ) + 1 & " componenti installati.</font></td></tr>" & vbNewLine
		CheckCOM = strTxt & "</table>" & vbNewLine
	End Function

	Response.Write( CheckCOM() )
%>

<p align="center">
	<font face="Tahoma" size="2">Server Component Checker
Direttamente dal forum di html.it</font>
</p>
</body>
</html>

***3_Luca_X*** · 15-08-2006, 17:31

questo é il responso

COMPONENTE STATUS
AB Mailer [ Non Installato ]
ABC Upload [ Non Installato ]
ActiveFile [ Non Installato ]
ActiveX Data Object [ Installato ]
Adiscon SimpleMail [ Non Installato ]
ASP HTTP [ Non Installato ]
ASP Image [ Non Installato ]
ASP Mail [ Non Installato ]
ASP Simple Upload [ Non Installato ]
ASP Smart Cache [ Non Installato ]
ASP Smart Mail [ Non Installato ]
ASP Smart Upload [ Non Installato ]
ASP Tear [ Non Installato ]
ASP Thumbnailer [ Non Installato ]
ASP WhoIs [ Non Installato ]
ASPEmail [ Non Installato ]
ASPSoft NT Object [ Non Installato ]
ASPSoft Upload [ Non Installato ]
CDONTS [ Non Installato ]
CDOSYS [ Installato ]
Chestysoft Image [ Non Installato ]
Chestysoft Upload [ Non Installato ]
Chili!Mail [ Non Installato ]
Dimac JMail [ Non Installato ]
Distinct SMTP [ Non Installato ]
dkQMail [ Non Installato ]
Dundas Mailer [ Non Installato ]
Dundas Upload [ Non Installato ]
Dynu Encrypt [ Non Installato ]
Dynu HTTP [ Non Installato ]
Dynu Mail [ Non Installato ]
Dynu Upload [ Non Installato ]
Dynu WhoIs [ Non Installato ]
Easy Mail [ Non Installato ]
Emailtoolbox [ Non Installato ]
File System Object [ Installato ]
Geocel.Mailer [ Non Installato ]
IISMail [ Non Installato ]
JMail [ Non Installato ]
Ticluse Teknologi HTTP [ Non Installato ]
Last Mod [ Non Installato ]
Microsoft XML Engine [ Installato ]
Persits ASP JPEG [ Non Installato ]
Persits ASPEmail [ Non Installato ]
Persits ASPEncrypt [ Non Installato ]
Persits File Upload [ Non Installato ]
SmartMail [ Non Installato ]
SMTP Mailer [ Non Installato ]
Soft Artisans File Upload [ Non Installato ]
Image Size [ Non Installato ]
Microsoft XML HTTP [ Installato ]
Grafici Excel [ Non Installato ]
ADODB Stream [ Installato ]
VSEmail1.0 [ Non Installato ]
VSEmail2.0 [ Non Installato ]
6 su 55 componenti installati.

Server Component Checker
Direttamente dal forum di html.it

é uguale usare il CDOSYS a posto di CDONTS?...bisogna cambiare tutto il codice dello script che uso o solo quella stringa?

**Mizushi** · 15-08-2006, 17:32

CDONTS è un componente utilizzato sui windows server NT e 2000; sui windows server 2003 si utilizza il componente CDOSYS:

http://www.w3schools.com/asp/asp_send_email.asp

***3_Luca_X*** · 15-08-2006, 19:11

Originariamente inviato da Mizushi
CDONTS è un componente utilizzato sui windows server NT e 2000; sui windows server 2003 si utilizza il componente CDOSYS:

http://www.w3schools.com/asp/asp_send_email.asp

quindi il mio codice come lo devo modificare?...ho provato a cambiare la stringa modificando da cdonts a cdosys ma mi da comunque l'errore,ciò significa che bisogna rifare tutto il codice...adessocerco una funzione cdosys su questo sito,se siete già a conoscenza di dove ne posso trovare una potete postarla tranquillamente

***3_Luca_X*** · 15-08-2006, 19:32

Cioé,fino ad ora ho cercato sui siti che offrono spiegazioni in asp e non ho trovato nessuno script che avesse la funzione segnala sito ad un amico con cdosys...é possibile che non ce ne siano in giro?

**Mizushi** · 15-08-2006, 19:33

Ma te l'ho già postata!:

codice:

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="mymail@mydomain.com"
myMail.To="someone@somedomain.com"
myMail.TextBody="This is a message."

myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing")=2

'Name or IP of remote SMTP server
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") _
="smtp.server.com"

'Server port
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") _
=25 

myMail.Configuration.Fields.Update
myMail.Send
set myMail=nothing
%>

***3_Luca_X*** · 15-08-2006, 20:55

Ma non esiste un file .zip con le pagine già impostate?...non sono un esperto e non so come integrare questi codici

***3_Luca_X*** · 16-08-2006, 10:35

Io fino ad ora non ho trovato nulla,solo funzioni con cdonts...

E' possibile mai che non si riesca a trovare la stessa funzione "segnala il sito ad un amico",già completata, che funzioni per cdosys?

**djkoma** · 16-08-2006, 10:50

Io no penso sia molto difficile....il codice di Mizushi è "altamente" modificabile. Basta fare un link "Segnala questo sito ad un amico" e farlo puntare ad una pagina che contiene un form dove è possibile inserire l'email del tuo amico. Questo form poi lo fai puntare ad un pagina che contiene il codice di Mizushi con i dati da te scelti..Tipo così:

codice:

<%

email_amico = request.form("email_amico")

Set myMail=CreateObject("CDO.Message")
myMail.Subject="Segnalazione Sito Interessante"
myMail.From="webmaster@tuosito.com"
myMail.To= email_amioo
myMail.TextBody="Ciao un tuo amico ha scelto di farti conoscere questo sito...bla bla bla"

myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing")=2

'Name or IP of remote SMTP server
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") _
="smtp.server.com"

'Server port
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") _
=25 

myMail.Configuration.Fields.Update
myMail.Send
set myMail=nothing
%>

e il gioco è fatto

Discussione: Problema con la funzione "segnala questo sito ad un amico"

Strumenti discussione

Ricerca discussione

Visualizza

Problema con la funzione "segnala questo sito ad un amico"

Permessi di invio