rss nel proprio sito

**gabar-el** · 20-10-2006, 17:42

ciao,ho letto vari articoli ma nn riesco a trovare nulla che faccia al caso mio.vorrei inserire gli rss della gazzetta dello sport sul mio sito ma nn so come fare,qualcuno sa darmi una mano?ho letto e riletto di feed2js ,ma a quanto ho capito fa solo x php che il mio servere nn supporta....
thank's.....

**michele.santoro** · 20-10-2006, 22:20

codice:

<%
Dim NumFeeds
NumFeeds = 6
ReDim ArrUrls(NumFeeds)
ReDim ArrNums(NumFeeds)
ArrUrls(0) = "http://www.gazzetta.it/rss/Home.xml"
ArrNums(0) = 2
ArrUrls(1) = "http://www.gazzetta.it/rss/Calcio.xml"
ArrNums(1) = 2
ArrUrls(2) = "http://www.gazzetta.it/rss/Formula1.xml"
ArrNums(2) = 4
ArrUrls(3) = "http://www.gazzetta.it/rss/Motomondiale.xml"
ArrNums(3) = 5
ArrUrls(4) = "http://www.gazzetta.it/rss/Motori.xml"
ArrNums(4) = 3
ArrUrls(5) = "http://www.gazzetta.it/rss/Ciclismo.xml"
ArrNums(5) = 4

%>
<html>
<head>
<style>
#feedStyle dl {
  font-family:Verdana, Arial, Helvetica, sans-serif;
  width: 280px;
  margin-top: 4px;
  margin-left: 0px;
  padding-bottom: 8px;
  border-top: 10px solid #2C6E91;
  border-bottom: 1px solid #2C6E91;
  background: #FFFFFF;
}
#feedStyle dl dt {
  font-size: 0.8em;
  font-weight: bold;
  color: #E5F4FC;
  text-align: left;
  padding-right: 5px;
  padding-left: 5px;
  border-top: 1px solid #E5F4FC;
  background: #93C1DB;
}
#feedStyle dl dd {
  font-size: 0.8em;
  color: #000;
  line-height: 1em;
  margin-top: 4px;
  margin-left:0px;
  padding-left: 5px;
}
#feedStyle dl dd a, #colMenu dl dd a:visited {
  color: #2C6E91;
  text-decoration: none;
}
#feedStyle dl dd a:hover, #colMenu dl dd a:active {
  color: #2C6E;
  text-decoration: underline;
}
</style>
</head>
<body>
<div id="feedStyle">
<%
For i = 0 to NumFeeds-1
  call PrintFeed(ArrUrls(i),ArrNums(i))
Next
%>
</div>
</body>
</html>
<script language="vbscript" runat="server">
Sub PrintFeed(url,NumNews)
  html = ""
  Set XMLdoc = Server.CreateObject("msxml2.DOMDocument.3.0") 
  XMLdoc.async = false 
  XMLdoc.setProperty "ServerHTTPRequest", True 
  XMLdoc.validateOnParse =false
  XMLdoc.preserveWhiteSpace = false 
  Loaded = XMLdoc.Load(url) 
  If Loaded Then
    set NodesList = XMLdoc.getElementsByTagName("channel")
    For Each aNode In NodesList 
      For Each aNode2 In aNode.childNodes 
        Select Case aNode2.nodeName 
          Case "title" 
            html = html & "<dt>" & aNode2.firstChild.nodevalue & "</dt>"
        End Select 
      Next 
    Next 
    Set NodesList = XMLdoc.getElementsByTagName("item") 
    j = 0
    For Each aNode In NodesList 
      j = j + 1
      For Each aNode2 In aNode.childNodes 
        Select Case aNode2.nodeName 
          Case "title" 
            strTitle = aNode2.firstChild.nodevalue 
          Case "link" 
            strURL = aNode2.firstChild.nodevalue 
        End Select 
      Next 
      html = html & "<dd>" & strTitle & "</dd>"
      strTitle = "" 
      strURL = "" 
      strDescription = "" 
      if (j >= NumNews) Then Exit For
    Next 
    html = "<dl>" & html & "</dl>"
    set NodesList = Nothing 
  End if 
  Response.write (html)
End Sub
</script>

Semplice e funzionale.
Se vuoi aggiungere o rimuovere un rss modifica la riga
NumFeeds = 6
aumentando o diminuendo il numero e aggiungi o togli le righe
ArrUrls(5) = "http://www.gazzetta.it/rss/Ciclismo.xml"
ArrNums(5) = 4
Se aggiungi un rss devi mettere ArrUrls(6) e NumFeeds = 7.

**gabar-el** · 21-10-2006, 01:47

wow!cavolo,grazie....domani lo provo sicuro,ma ormai che ci sono cerco d'imparare qualcosa.....nn mi è chiara la riga ArrNums.....cosa sta a indicare il numero che segue?grazie mille davvero.....immagino che posso usare il codice x qualsiasi feed rss.o no?

**michele.santoro** · 21-10-2006, 08:36

Originariamente inviato da gabar-el
wow!cavolo,grazie....domani lo provo sicuro,ma ormai che ci sono cerco d'imparare qualcosa.....nn mi è chiara la riga ArrNums.....cosa sta a indicare il numero che segue?grazie mille davvero.....immagino che posso usare il codice x qualsiasi feed rss.o no?

Scusa credevo di averlo scritto.
Indica il numero dei titoli delle news (il numero di righe) che vuoi visualizzare nella pagina

**gabar-el** · 21-10-2006, 11:37

ok,grazie ancora....l'ho appena provato e funziona alla grande...certo che il codice nn lo capisco molto,ma mi ci metterò x cercare di capirlo.fatico un pò anche con alcune proprietà dei css,ma a grandi linee sono riuscito a personalizzarle a puntino.ho veduto che posso utilizzare il codice x altri rss e volevo chiederti cosa devo fare se voglio inserire nella stessa pagina anche quelli del fantacalcio di kataweb.sostituendo l'url nel codice che mi hai passato ho visto che il procedimento è lo stesso,ma nn capisco come implementare il dim,ho dei dubbi circa il fatto che dopo nn si sappia + qual'è il codice di uno e quale quello dell'altro(ok,devo aver fatto un pò di casino....).forse rinominando alcuni paramentri posso personalizzare il codice x un altro rss?
un ultima cosa....come mai si usa il simbolo di cancelletto x le classi?a me avevano insegnato a usare il punto,che differenza c'è?
grazie.....
ciaux...

**gabar-el** · 21-10-2006, 11:42

cavolo,ho appena provato a validare la mia pagina e ci son un casino di errori,che però deduco siano della gazzetta circa il link......nn ci posso fare nulla vero?

**michele.santoro** · 21-10-2006, 13:18

Puoi prelevare gli RSS anche da siti diversi, basta che inserisci l'url del sito da dove lo prelevi, per esempio:

codice:

<%
Dim NumFeeds
NumFeeds = 7
ReDim ArrUrls(NumFeeds)
ReDim ArrNums(NumFeeds)
ArrUrls(0) = "http://www.gazzetta.it/rss/Home.xml"
ArrNums(0) = 2
ArrUrls(1) = "http://www.gazzetta.it/rss/Calcio.xml"
ArrNums(1) = 8
ArrUrls(2) = "http://www.gazzetta.it/rss/Formula1.xml"
ArrNums(2) = 2
ArrUrls(3) = "http://www.gazzetta.it/rss/Motomondiale.xml"
ArrNums(3) = 2
ArrUrls(4) = "http://www.gazzetta.it/rss/Motori.xml"
ArrNums(4) = 2
ArrUrls(5) = "http://www.gazzetta.it/rss/Ciclismo.xml"
ArrNums(5) = 2
ArrUrls(6) = "http://www.corriere.it/rss/cronache.xml"
ArrNums(6) = 2
%>

Come vedi ho aggiunto il feed rss del corriere della sera.
Fai il confronto col primo e vedi cosa è cambiato.
Per quanto riguarda la faccenda della validazione, non ho capito cosa intendi dire.

**gabar-el** · 21-10-2006, 13:40

quindi devo creare un altro dim x implementare un altro feed senza nessun problema di contrasto? x validazione intendo che ho validato la pagina con html validoter del w3c e ora ci sono 24 errori dati dai link della gazzetta che prima nn c'erano.....

**michele.santoro** · 21-10-2006, 13:48

Originariamente inviato da gabar-el
quindi devo creare un altro dim x implementare un altro feed senza nessun problema di contrasto? x validazione intendo che ho validato la pagina con html validoter del w3c e ora ci sono 24 errori dati dai link della gazzetta che prima nn c'erano.....

Si alla prima domanda.
Per quanto riguarda la validazione non saprei dirti, ma penso sia un problema della gazzetta. Puoi provare ad eliminare i link alla gazzetta e lasciane uno ad un altro sito e riprovare a fare la validazione, così potrai avere la certezza che dipende da quello.

**gabar-el** · 21-10-2006, 14:04

ok,vediamo se ho capito....questa parte di codice non la replico....

codice:

<script language="vbscript" runat="server">
Sub PrintFeed(url,NumNews)
  html = ""
  Set XMLdoc = Server.CreateObject("msxml2.DOMDocument.3.0") 
  XMLdoc.async = false 
  XMLdoc.setProperty "ServerHTTPRequest", True 
  XMLdoc.validateOnParse =false
  XMLdoc.preserveWhiteSpace = false 
  Loaded = XMLdoc.Load(url) 
  If Loaded Then
    set NodesList = XMLdoc.getElementsByTagName("channel")
    For Each aNode In NodesList 
      For Each aNode2 In aNode.childNodes 
        Select Case aNode2.nodeName 
          Case "title" 
            html = html & "<dt>" & aNode2.firstChild.nodevalue & "</dt>"
        End Select 
      Next 
    Next 
    Set NodesList = XMLdoc.getElementsByTagName("item") 
    j = 0
    For Each aNode In NodesList 
      j = j + 1
      For Each aNode2 In aNode.childNodes 
        Select Case aNode2.nodeName 
          Case "title" 
            strTitle = aNode2.firstChild.nodevalue 
          Case "link" 
            strURL = aNode2.firstChild.nodevalue 
        End Select 
      Next 
      html = html & "<dd>" & strTitle & "</dd>"
      strTitle = "" 
      strURL = "" 
      strDescription = "" 
      if (j >= NumNews) Then Exit For
    Next 
    html = "<dl>" & html & "</dl>"
    set NodesList = Nothing 
  End if 
  Response.write (html)
End Sub
</script>

mentre nella prima parte do ovviamente dei nomi diversi,io ho fatto cosi

codice:

<%
Dim NumFeedsFanta
NumFeedsFanta = 1
ReDim ArrUrlsFanta(NumFeedsFanta)
ReDim ArrNumsFanta(NumFeedsFanta)
ArrUrlsFanta(0) = "http://www.fantacalcio.kataweb.it/image/rss/feed.xml"
ArrNumsFanta(0) = 6
%>

poi ovviamente personalizzo con i css.....
ho detto e/o fatto delle castronate mai viste?

Discussione: rss nel proprio sito

Strumenti discussione

Ricerca discussione

Visualizza

rss nel proprio sito

Permessi di invio