campo di testo dinamico

[KiKkO_helpME]

ciao a tutti, qualcuno sa indicarmi qualche filmato già fatto con un campo di testo dinamico, un semplice preload e due pulsanti per scorrere il testo?

[rempox]

penso che un esempio ti possa creare problemi di adattamento
quindi ti realizzo uno script che puoi riapplicare da qualsiasi parte

unica cosa il file TXT deve essere nel formato

&testo=.......................................&

apri un FLA nuovo nella 1° frame incolli lo sript. Ciao

System.useCodepage=true
domain = "" // lo puoi variare tu
path="" // percorso dove risiede il file esterno
fileData="fullAS_loadData_Text.txt" // nome file esterno
/* nel file di testo esterno i dati devono essere scritti in questo modo

&testo=................................................
......................................................
&

*/
// dimensione campo dinamico
dimW = 300
dimH = 200
// posizione campo dinamico
posX = 20
posY = 20
// padding sposto il testo dal margine
padX = 2
padY = 2

// ========INIZIAMO da qui non toccare nulla ad eccezione dei param del TESTO ====

// creazione clip fondo per un effetto grafico
this.createEmptyMovieClip("bgText", this.getNextHighestDepth())
with (bgText) {
        lineStyle(1, 0x000000, 100);
        beginFill(0xF2F2F2, 100);
        moveTo(0, 0);
        lineTo(dimW , 0);
        lineTo(dimW, dimH);
        lineTo(0, dimH);
        lineTo(0, 0);
        endFill();
    }

// creazione clip contenitore
this.createEmptyMovieClip("containerText", this.getNextHighestDepth())

// creazione MASK clip contenitore    
this.createEmptyMovieClip("maskText", this.getNextHighestDepth())
with (maskText) {
        lineStyle(1, 0x000000, 100);
        beginFill(0xF2F2F2, 100);
        moveTo(0, 0);
        lineTo(dimW , 0);
        lineTo(dimW, dimH);
        lineTo(0, dimH);
        lineTo(0, 0);
        endFill();
    }
containerText.setMask(maskText)

//posizionamento dei vari clip
containerText._x = posX
containerText._y = posY
bgText._x = containerText._x
bgText._y = containerText._y
maskText._x = containerText._x
maskText._y = containerText._y


// creo campo dinamico per la ricezione dati dall'esterno
containerText.createTextField("dyn_field",1,padX,padY,dimW-padX,dimH-padY)
containerText.dyn_field.textFont = "_sans"
containerText.dyn_field.textColor= 0x003366
containerText.dyn_field.textSize = 10
containerText.dyn_field.multiline = true
containerText.dyn_field.wordWrap = true
containerText.dyn_field.embedFonts = false

// caricamento dati dall'esterno
leggi=new LoadVars()
leggi.onLoad=function(success){
    if(success){
        containerText.dyn_field.text = this.testo
        containerText.dyn_field.autoSize = "Left"
        containerText._height = containerText.dyn_field._height
    }else{
        containerText.dyn_field.text = "Error! External Data file not available."
    }
}
leggi.load(domain+path+fileData)


// creazione grafica freccia up e posizionamento
this.createEmptyMovieClip("arrowUP",this.getNextHighestDepth())
with (arrowUP) {
        lineStyle(1, 0x000000, 100);
        beginFill(0xF2F2F2, 100);
        moveTo(5, 0);
        lineTo(10 , 0);
        lineTo(10, -10);
        lineTo(15, -10);
        lineTo(7.5, -15);
        lineTo(0, -10);
        lineTo(5, -10);
        lineTo(5, 0);
        endFill();
    }
arrowUP._x = posX + dimW + 10
arrowUP._y = posY+15

// creazione grafica freccia dwn e posizionamento
this.createEmptyMovieClip("arrowDWN",this.getNextHighestDepth())
with (arrowDWN) {
        lineStyle(1, 0x000000, 100);
        beginFill(0xF2F2F2, 100);
        moveTo(5, 0);
        lineTo(10 , 0);
        lineTo(10, 10);
        lineTo(15, 10);
        lineTo(7.5, 15);
        lineTo(0, 10);
        lineTo(5, 10);
        lineTo(5, 0);
        endFill();
    }
arrowDWN._x = posX + dimW + 10
arrowDWN._y = posY + dimH - 15

// gestione colori e eventi frecce
cUP = new Color(arrowUP)
cDWN = new Color(arrowDWN)
cUP.setRGB(0x333333)
cDWN.setRGB(0x333333)

arrowUP.onRollOver=function(){ cUP.setRGB(0xFF9900)}
arrowUP.onRollOut=function(){cUP.setRGB(0x333333)}
arrowDWN.onRollOver=function(){cDWN.setRGB(0xFF9900)}
arrowDWN.onRollOut=function(){cDWN.setRGB(0x333333)}

arrowUP.onPress=function(){STATO = true; slideUP()}
arrowDWN.onPress=function(){STATO = true;slideDWN()}
arrowUP.onRelease=function(){STATO = false;}
arrowDWN.onRelease=function(){STATO = false}

function slideDWN(){
    containerText.onEnterFrame=function(){
        if(STATO){
            if(this._y+this._height>maskText._y+maskText._height){this._y-=10}
                        else{STATO=false}
        }else{delete this.onEnterFrame}
    }
}
function slideUP(){
    containerText.onEnterFrame=function(){
        if(STATO){
            if(this._y < maskText._y){this._y+=10}
                        else{STATO=false}
        }else{delete this.onEnterFrame}
    }
} 

[rempox]

che strano neanche un Ciao !

[crescenzo]

Originariamente inviato da rempox
che strano neanche un Ciao !

come minimo dovrebbe pagarti un caffè

x lo script che hai postato

[rempox]

No niente caffè mi accontento di sapere se lo ha provato, visto che aveva un problema il 12/12 ed al 14/12 ancora non è andato a vedere se qualcuno ha risposto.

Avrà risolto.

[digitos]

forse gli è esploso il pc