Modificare script CDOSYS

[Giubass]

Ciao ragazzi, fino ad oggi ho utilizzato lo script sottostante per inviare email, ma visto che ho cambiato server adesso non funge, mi da l'errore " HTTP 500 - Errore interno del server " in locale ovviamente funziona e non da nessun errore. Ecco lo script:

<% Option Explicit %>  
<%
Dim Button, dtData, dtOra, Email
Button = Request.Form("Button")
IF Button="Invia" THEN

dtData    = Date()
dtOra     = Time()

Email     = Request.Form("Email")

' Controllo email
If Email = "" Then
   Session("error1")="Ok"  
   Response.Redirect ("error1.asp")
End If  

If Email <> "" Then
   If instr(Email, "@") = 0 or instr(Email, ".") = 0 Then
       'Email non valida
       Session("error1") = "Ok"
       Response.Redirect ("error1.asp")
   Else
       'Email valida
	        Dim objMail  
            Set objMail = Server.CreateObject("CDO.Message")
            objMail.HTMLBody = ""
 
            objMail.From = "modulo@sito.it"
            objMail.To = "nome@sito.it"
            objMail.Subject = "Modulo informazioni"
            objMail.Fields("urn:schemas:httpmail:importance").Value = 2
            objMail.Fields.Update()
            objMail.Send()
            Set objMail = nothing
  
            Session("Modulo") = "Ok"

            Response.Redirect ("grazie.asp")
		 
   End If
End If

Else

Response.Write("<script language=""JavaScript"">history.go(-1)</script>")

End If

%>

Ho contattato l'hoster e mi hanno consigliato di utilizzare un loro script per l'invio, eccolo:

<%
DIM corpoMessaggio, numeroCampi, invioA, invioDa, modulo

	'* voce da modificare con il proprio indirizzo email
	
invioA =  "support@ion.it"

	'* voce da modificare con un indirizzo email che funga da mittente: 
	'* in caso di errore riceverete notifica a questo indirizzo un MAILER-DAEMON
	'* dato che cdosys supporta questa notifica
	
    '* voce da modificare con il proprio indirizzo email	
invioDa =  "support@ion.it"


	'*rilevo i campi del form
	
FOR numeroCampi = 1 TO (Request.Form.Count())
   IF NOT Request.Form(numeroCampi) = "" THEN
      corpoMessaggio = corpoMessaggio & vbCrLf & Request.Form.Key(numeroCampi) & " = " & Trim(Request.Form(numeroCampi))
   END IF
NEXT

	'* creo gli oggetti cdosys sul server e li gestisco
	
DIM iMsg, Flds, iConf

Set iMsg = CreateObject("CDO.Message")
Set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields

With Flds 
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "localhost" 
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 

.Update 
End With 

With iMsg
   Set .Configuration = iConf
   .To = invioA
   .From = Request.Form("email")
   .Sender = invioDa
   .Subject = "Modulo sul mio sito"
   .TextBody = "Questi i dati inseriti nel modulo " & modulo & vbCrLf & corpoMessaggio & ""
   .Send
End With
%> 
<script>
document.location.replace('grazie.asp');
</script>

Adesso vi chiedo come posso unificare i due script? Cioè creare un unico script che mi dia sempre la possibilità di inviare come allegato una pagina html.

Ciao

[Roby_72]

Il componente di invio è lo stesso, non cambia nulla. devi solo aggiungere la parte di configurazione iniziale presente nel loro script.

Roby

[Giubass]

Originariamente inviato da Roby_72
Il componente di invio è lo stesso, non cambia nulla. devi solo aggiungere la parte di configurazione iniziale presente nel loro script.

Roby

Grazie Roby, ma quale dovrebbe essere?

[Roby_72]

Beh non è difficile

Set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields

With Flds 
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "localhost" 
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 

.Update 
End With

adattalo con i nomi delle tue variabili...

Roby

[Giubass]

Grazie Roby!

Per la cronaca ho risolto così:

<% Option Explicit %>  
<%
Dim Button, dtData, dtOra, Email
Button = Request.Form("Button")
IF Button="Invia" THEN

dtData    = Date()
dtOra     = Time()

Email     = Request.Form("Email")

' Controllo email
If Email = "" Then
   Session("error1")="Ok"  
   Response.Redirect ("error1.asp")
End If  

If Email <> "" Then
   If instr(Email, "@") = 0 or instr(Email, ".") = 0 Then
       'Email non valida
       Session("error1") = "Ok"
       Response.Redirect ("error1.asp")
   Else
       'Email valida
	   
Dim objMail, Flds, iConf 
Set objMail = Server.CreateObject("CDO.Message")
Set iConf = Server.CreateObject("CDO.Configuration")
Set Flds = iConf.Fields
With Flds 
  .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "localhost" 
  .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
  .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
  .Item("urn:schemas:httpmail:importance").Value = 2 
  .Update 
End With
		
With objMail
  Set .Configuration = iConf
  .To = "mail@sito.it"
  .From = "mail@sito.it"
  .Sender = "mail@sito.it"
  .Subject = "Modulo "
  .HTMLBody = ""
  .Send
End With

Session("Modulo") = "Ok"
Response.Redirect ("grazie.asp")
		 
   End If
End If

Else

Response.Write("<script language=""JavaScript"">history.go(-1)</script>")

End If

%>