[VB6] Risultati di una query in ListBox

[Khris22]

Ciao a tutti.. mi scuso per il disturbo già dal primo post ma sono nella melma
ho già spulciato un po' sul cerca e un problema me lo son tolto... ora ne ho uno un po' + complesso...

sto costruendo un programma ke gestisce immobili, perciò lavora interagendo con un database SQL

la connessione è a posto (creata con data environment) infatti riesco sia ad inserire nuovi record sia a gestire una skermata iniziale di login con user e password...
al momento dovrei crearmi un form per la ricerca nel db.. con ovviamente una query sql..
la query ce l'ho in mente , soltanto ke nn ho in mente come poter prendere i risultati della query in questione e inserirli in una listbox...
questi risultati in listbox dovrebbero mostrarmi anke solo poki campi di ogni riga (per esempio solo comune e via) ma poi con un doppio click su ognuno dovrei aver la possibilità di aprire un form di riepilogo ke mi contenga tutti i campi di questo record.. spero di nn essermi spiegato male... faccio un esempietto


1-pagina di ricerca ------------> ricerco tutti i record ke corrispondono a certe caratteristike
2-si apre una listbox con una lista dei record con i requisiti rikiesti, ma ke nn mi mostrano tutti i campi ma solo per esempio comune e via
3-con un doppio-click su una "voce" si questa listbox mi apre la finestra riepilogativa ke contiene tutti i campi del record


loso ke è tutto un po' complesso e nn vi kiedo di farmi tutto, anke solo darmi una direzione perkè al momento son proprio nella bratta e nn ho idea di dove sbattere la testa.. grazie in anticipo

[LMondi]

Ciao Khris22,
guarda che la ListBox non è adatta al lavoro che vuoi svolgere, anche il DataEnvironment è molto limitativo; a mio avviso dovresti usare una ListView e per il DB usare ADO.
Ti posto un esempio d'utilizzo della LV, nel predetto contesto:

Option Explicit

' Carica la ListView per lettera iniziale della Via:
Sub Ricerca()
    
    ' sLetteraRic è una variabile str caricata con la lettera iniziale
    ' della via (non importa se maiuscola o minuscola):
    If Len(sLetteraRic) > 0 Then
        ' Imposta Mouse Clessidra:
            Screen.MousePointer = 11
            DoEvents
        
        ' Formatta ListView per visualizzare i dati :
        FrmArch.LVArchivio.ListItems.Clear
        
        Dim OggSR As New ADODB.Command
        Dim ConSR As New ADODB.Connection
        Dim RSTrc As New ADODB.Recordset
        
        Dim itmX As ListItem
    
    'Esegue la connessione con il DataBase:
        With ConSR
            .ConnectionString = DataConnessione
            .CursorLocation = adUseClient   'tipo di cursore
            .Mode = adModeShareDenyNone     'nessuna limitazione
            .CommandTimeout = 15
            .Open
       End With
       
        OggSR.ActiveConnection = ConSR
        OggSR.CommandType = adCmdText
        
        RSTrc.Source = "SELECT Via, NomeVia, Ncivico, Cap, Citta, Provincia FROM TblAnagImmob WHERE NomeVia Like '" & sLetteraRic & "%' Order by NomeVia "
        RSTrc.Open , ConSR, adOpenDynamic, adLockOptimistic
        
        ' Controlla che il DB contenga i dati da visualizzare:
        If RSTrc.EOF = False And RSTrc.BOF = False Then
            Do Until RSTrc.EOF
                Set itmX = LVArchivio.ListItems.Add()
                With RSTrc
                    itmX.Text = .Fields("Via")
                    itmX.SubItems(1) = .Fields("Via")
                    itmX.SubItems(2) = .Fields("NomeVia")
                    itmX.SubItems(3) = .Fields("Ncivico")
                    itmX.SubItems(4) = .Fields("Cap")
                    itmX.SubItems(5) = .Fields("Citta")
                    itmX.SubItems(6) = .Fields("Provincia")
                    RSTrc.MoveNext
                End With
            Loop
            ' Se i records sono stati caricati vengono visualizzati
            ' nella LV altrimenti appare il messaggio:
            ElseIf RSTrc.EOF = True And RSTrc.BOF = True Then
                LVArchivio.ListItems.Add.Text = "Ricerca completata, nessun record trovato ..."
                LVArchivio.ToolTipText = "Ricerca completata, nessun record trovato ..."
        End If

' Imposta Mouse Default:
    Screen.MousePointer = 0

    'Chiude e cancella il recordSet:
        RSTrc.Close
        Set RSTrc = Nothing
    'Chiude la connessione:
        ConSR.Close
        Set ConSR = Nothing
End Sub

[Khris22]

ti ringrazio in anticipo per la risposta VVoVe:

stasera il cervello l'ho spaccato ben bene ma domattina provo a tirarlo giù subito

purtroppo per lavoro una settimana fa mi han messo in mano vb6 (ke nn avevo mai visto in vita mia) e sql e mi han detto di sviluppare sto programma.. ho avuto un momento di panico