[VB6] Chiudere i form aperti in automatico

[tecnoguru]

Vorrei poter chiudere in automatico i vari form aperti clicando solo nel unload del Form Main(il Principale), come potrei fare?!

[oregon]

"Cliccando nell'Unload"? Che vuoi dire ? Hai un pulsante ?

In ogni caso, puoi scrivere

Unload Form5

o quello che vuoi ...

[tecnoguru]

Hai presente la X che sta a destra della form quella di default, vorrei che clicandoci sopra vengano chiusi tutti i form definitivamente.

[tecnoguru]

Originariamente inviato da tecnoguru
Hai presente la X che sta a destra della form quella di default, vorrei che clicandoci sopra vengano chiusi tutti i form definitivamente.

[LMondi]

Ciao tecnoguru,
quindi vuoi chiudere tutte le Frm ed uscire dal programma ?!
Prova queste routine, che naturalmente dovrai adattare alle tue necessità.
Da inserire nel modulo della MDIFrm:

Option Explicit
Dim byEsci As Byte
Dim intDomEsci As Integer
'-------------------------------------------------------------------------
' Esce dal programma con il clic sulla X:
Private Sub MDIForm_QueryUnload(Cancel As Integer, unloadMode As Integer)

' Invia al Comando di menu Esci:
        If byEsci = 0 Then
            Call mnuFileEsci_Click
        End If
' Annulla Esci dal programma:
        If intDomEsci = 2 Then
            Cancel = True
        End If
End Sub
'-------------------------------------------------------------------------
Private Sub mnuFileEsci_Click()

' Variabile di controllo Esci:
    byEsci = 0
    
        intDomEsci = MsgBox("Volete Uscire dal programma ?" & Chr(13) _
        & "Clic su OK per Chiudere il programma - su Annulla per continuare.", vbQuestion + vbOKCancel, "Prova")
        
        If intDomEsci = 1 Then
             byEsci = 1
            'Chiama la routine Esci - MDIFrm:
            Call MDIFrm.Esci2
        End If

' Annulla non esce dal programma:
        If intDomEsci = 2 Then
            ' Se ridotta a icona Massimizza:
            'Call mnuPopMax_Click
            Exit Sub
        End If
End Sub
'-------------------------------------------------------------------------
Public Sub Esci2()
        
    DoEvents

' Modulo Tools - Suono GRPITOOT.WAV:
    'Call SoundExit
    
    Dim Frm As Form
    
    For Each Frm In Forms
       If Frm.Name <> "MDIFrm" Then
            Unload Frm
            Set Frm = Nothing
        End If
    Next
    
   ' Set FSO = Nothing
    Unload MDIFrm
    Set MDIFrm = Nothing
End Sub

[oregon]

Non mi pare tu abbia fatto riferimento a form MDI ... quindi presumo che il codice seguente, inserito nel form principale, possa bastare ...

Private Sub Form_Unload(Cancel As Integer)
    Dim Frm As Form
    
    For Each Frm In Forms
        Unload Frm
        Set Frm = Nothing
    Next
End Sub

[LMondi]

Non mi pare tu abbia fatto riferimento a form MDI

Sì è vero, però l'intento era quello di dare un'informazione completa (Prima o poi una MDIFrm dovrà pure utilizzarla !).

[tecnoguru]

Grazie siete stati utilissimi !....