Query pivot con colonne variabili

[xstef@tin.it]

Ho una query pivot che a seconda dei where mi restituisce da 0 a 5 colonne.

Esiste un comand o rs.xxx che mi restituisce il numero e il nome delle colonne in modo da generare con un do loop la tabella in maniera dinamica?

Chiedo scusa se ho sbagliatoo il forum

Ciao

[xstef@tin.it]

ho risolto.

se vi può interessare.

rs.fields.count restituisce il numero di colonne

rs.fields(x).name restituisce il nome della colonna x

Ciao

[Mems]

<%
sqlServer_name = "xxxxxx"
sqlServer_db = "xxxxxx"
sqlServer_login = "xxxxxx"
sqlServer_password = "xxxxxx"

connString = "Provider=sqloledb;" &_
						 "Network Library=DBMSSOCN;" &_
						 "Encrypt=yes;" &_
						 "Data Source=" & sqlServer_name & ";" &_
						 "Initial Catalog=" & sqlServer_db & ";" &_
						 "User Id=" & sqlServer_login &";" &_
						 "Password=" & sqlServer_password & ";"

set conn = server.createObject("ADODB.Connection")
conn.open connString

sql = "SELECT * FROM tabella1"

set rs = server.createObject("ADODB.Recordset")
rs.open sql, conn, 3, 1

	if not rs.eof then
		response.write "<table border=""1"">"	& vbCrLf
		response.write "	<tr>" & vbCrLf
		for i = 0 to (rs.fields.count - 1)		
			response.write "		<td>" & rs(i).name & "</td>" & vbCrLf
		next
		response.write "	</tr>" & vbCrLf
			do until rs.eof
				response.write "	<tr>" & vbCrLf
				for i = 0 to (rs.fields.count - 1)
					response.write "		<td>" & rs(i) & "</td>" & vbCrLf
				next
				rs.moveNext
				response.write "	</tr>" & vbCrLf
			loop					
		response.write "</table>" & vbCrLf
	end if

rs.close
set rs = nothing

conn.close
set conn = nothing
					 
%>