mc riflesso

[slay]

ciao sto creando una gallery

var spazio:Number = 190;
var kl:Number = parsed.length;
var k:Number = 0;
    // PRELOAD IMG ////////////////////////////////////////////// 
    var mcLoad:MovieClipLoader = new MovieClipLoader(); 
    var obj23 = new Object() 
    //target e il clip attuale che viene processato che sartebbe mc.imgin_mc
        obj23.onLoadProgress = function(target, bytesLoaded, bytesTotal){ 
        target._parent.enabled = false;
        var percentuale:Number = Math.floor((bytesLoaded/bytesTotal)*100); 
        target._parent.perc.perc = percentuale +  " %"; 
            if (percentuale == 100) { 
                target._parent.perc._visible = false;
                target._parent.enabled = true;
        } 
    } 
// definisce altezza e larghezza delle thumb prima del caricamento
obj23.onLoadInit = function(target) { 
    
    target._y = - target._height;
    target._x = - target._parent._width/2; 
    //_root.largfoto = target._width; 
}
mcLoad.addListener(obj23); 
// FINE PRELOAD ////////////////////////////////////////////////////////////


while (k<kl) {
    var name:String = "immagine" + k + "_mc";
    immagine_mc.duplicateMovieClip(name, k);
    mc = eval([name])
    mc._x = (mc._x) + (k * spazio);
    mc.imgpic = parsed[k].imgpic
    mcLoad.loadClip("gallery/" + mc.imgpic, mc.imgin_mc);


    
    
    
++k
    } 

per ogni mc duplicato vorrei creare la copia riflessa sotto quindi dupliare l'mc in rifletti in verticale qualche aiutino..

[and80]

versione di flash?

[slay]

flash 8 as2
l'immagine principale si trova su mc.imgin_mc quindi dovrei duplicare solo imgin_mc oppure devo duplicare tutto mc

[and80]

tempo fa scrissi una funzione che faceva una copia bitmap ribaltata del clip a cui l'applicavo, con tanto di sfumatura... ma va bene solo per FP8+AS2, per questo ti ho chiesto la versione
un attimo che la cerco e la posto...

[slay]

azz.. sarebbe la sua morte ...

[and80]

è un po' lunga, forse sarebbe più conveniente trasformarla in classe, comunque ecco qui:

function drawAlphaRoundRect(target:MovieClip, name:String, level:Number, width:Number, height:Number, radius:Number, border:Number, borderColor:Number, color:Number, alpha:Number, initObject:Object):MovieClip {
    target.createEmptyMovieClip(name, level);
    with (target[name]) {
        if (initObject != undefined) {
            _x = initObject._x != undefined ? initObject._x : 0;
            _y = initObject._y != undefined ? initObject._y : 0;
            _xscale = initObject._xscale != undefined ? initObject._xscale : 100;
            _yscale = initObject._yscale != undefined ? initObject._yscale : 100;
            _alpha = initObject._alpha != undefined ? initObject._alpha : 100;
            _rotation = initObject._rotation != undefined ? initObject._rotation : 0;
            alphaFill = initObject.alphaFill != undefined ? initObject.alphaFill : 100;
        } else {
            _x = 0;
            _y = 0;
            _xscale = 100;
            _yscale = 100;
            _alpha = 100;
            _rotation = 0;
            alphaFill = 100;
        }
        colors = [color, color];
        alphas = [alpha, 0];
        ratios = [0, 255];
        lineStyle(((border != 0) ? border : undefined), borderColor, 100, false, "normal", "none", "miter", 255);
        matrix = {matrixType:"box", x:0, y:0, w:width, h:height, r:(90/180)*Math.PI};
        beginGradientFill("linear", colors, alphas, ratios, matrix);
        moveTo(0, height);
        lineTo(0, radius);
        curveTo(0, 0, radius, 0);
        lineTo(width-radius, 0);
        curveTo(width, 0, width, radius);
        lineTo(width, height);
        lineTo(0, height);
        endFill();
    }
    return target[name];
}
function reflectClip (target:MovieClip, distance:Number, alphafill:Number, intensity:Number):MovieClip {
    var version = getVersion().split(",").join("").split(" ").join("").split("WIN").join("").substr(0, 1);
    var temp = target._parent.createEmptyMovieClip("temp", target._parent.getNextHighestDepth());
    if (version>=8) {
        temp.createEmptyMovieClip("t1",1);
        drawAlphaRoundRect(temp,"t2",2,target._width,target._height,0,0,0,0,alphafill,{_x:target._width, _y:target._height, _rotation:180,_yscale:intensity});
        temp.b = new flash.display.BitmapData(target._width, target._height, true, 0x00000000);
        temp.b.draw(target);
        temp.t1.attachBitmap(temp.b,1);
        temp.t1.cacheAsBitmap = temp.t2.cacheAsBitmap=true;
        temp.t1.setMask(temp.t2);
        var m:MovieClip = target._parent.createEmptyMovieClip("reflection", target._parent.getNextHighestDepth());
        var b:flash.display.BitmapData = new flash.display.BitmapData(target._width, target._height, true, 0x00000000);
        b.draw(temp);
        m.attachBitmap(b,1);
        temp.removeMovieClip();
        m._yscale = -100;
        m._x = target._x;
        m._y = (target._y+target._height*2)+distance;
    }
    return m;
}
// utilizzo: 
var r:MovieClip = reflectClip(prova, 30, 50, 50); 

[edit] ho modificato leggermente la funzione per comprendere la distanza, l'intensità e l'opacità del riflesso, se l'hai già scaricata, riprendila così modificata

[slay]

azz.. aspe.. non capisco .. dove la devo mettere..

mi segnala un qualche errore qui:
matrix = {matrixType:"box", x:0, y:0, w:width, h:height, r<img src="images/smilies/frown.gif

[and80]

Originariamente inviato da slay
azz.. aspe.. non capisco .. dove la devo mettere..

mi segnala un qualche errore qui:
matrix = {matrixType:"box", x:0, y:0, w:width, h:height, r<img src="images/smilies/frown.gif

il forum ha cambiato delle cose aspè...

[edit] ok, modificato... le dichiarazioni delle funzioni si mettono sempre nei frame poi richiami quando ti serve la singola riga segnalata sotto il commento "// utilizzo:"

[slay]

boh.. non ho capito come implementarla nel mio codice .. scusa la durezza ..

[slay]

ok risolto così:

obj23.onLoadInit = function(target) {

target._y = - target._height;
target._x = - target._parent._width/2;
var r:MovieClip = reflectClip(target, 10, 50, 50);
}

complimenti una figata questa classe...

ora vorrei disabilitare l'mc duplicato riflesso perchè l'mc originale è un clip con della azioni rollover - out.. :master:

ho fatto così: target._parent.reflection.enabled = false; ma non mi funge..