Problemi di Privacy sui files

[maxmalici]

Salve a tutti,

ho un dubbio da cui non riesco a venir fuori.....
gia' trovare un titolo non è stato semplice......

in una applicazione web che sto sviluppando in asp ho la necessità di
far visualizzare e/o scaricare ad un utente solamente i files che lo interessano....

chiaramente l'utente accede previa autenticazione solamente il fatto è che tutti i files
di tutti gli utenti si trovano per forza di cose in un unica directory
e i nomi dei files sono facilmente intuibili da tutti ( es. Cognome_ggmmyyyy.doc)
e quindi qualche malintenzionato potrebbe andare a carpire files che non gli competono....
stando al fatto che non posso cambiare i presupposti
cosa mi consigliate per aggirare il problema???

grazie MAX

[optime]

*ovviamente* NON farglieli scaricare direttamente, ma spediscili tu!

[maxmalici]

spedirli ...?????
e come ????
tu parli di inviare una mail....?????


gli utenti si collegano al sito tramite browser.....
e dovrebbero poter scaricare direttamente dal sito.....

non esiste altro metodo????

mm

[optime]

no, ma che mail. lo *spedisci* tramite browser. cerca ADOSEND (anche su gugol) ci sono esempi

[maxmalici]

ho cercato

ADOSEND su google e ho trovato 8 risultati

di cui 4 fasulli, 1 russo e 1 cinese

+ 2 tuoi in cui consigli di usare ADOSEND......

gli stessi che mi tornano se faccio una ricerca all'interno del forum.....

sbaglio nella ricerca?????

grazie Max....

[optime]

questo è adosend.asp

<%

Session.Timeout = 20

	'8***********************************************8
	' Jason Withrow - For ASP101 July 2001
	' This page forces the save as dialogue to prevent
	' files from being opened in the browser.
	'
	' jwithrow@mediaone.net
	'8***********************************************8


Response.Buffer = True

Dim strFilePath, strFileSize, strFileName

' added by edc 7.1.2003

	If Session("FileName") = "" Then
		Response.Redirect "default.asp"
	End If

	Dim oFso, oFile

	strFilePath = Server.MapPath(Session("FileName"))
	Set oFso = CreateObject("Scripting.FileSystemObject")
	Set oFile = oFso.GetFile(strFilePath)
	strFileName = UCase(oFile.Name)
	strFileSize = CLNG(oFile.size)
	Set oFile = Nothing
	Set oFso = Nothing

' end add

Const adTypeBinary = 1

'strFilePath = Request.QueryString("File")
'strFileSize = Request.QueryString("Size")
'strFileName = Request.QueryString("Name")

Response.Clear

'8*******************************8
' Requires MDAC 2.5 to be stable
' I recommend MDAC 2.6 or 2.7
'8*******************************8
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
objStream.Type = adTypeBinary
objStream.LoadFromFile strFilePath

strFileType = lcase(Right(strFileName, 4))
    
	' Feel Free to Add Your Own Content-Types Here
    Select Case strFileType
        Case ".asf"
            ContentType = "video/x-ms-asf"
        Case ".avi"
            ContentType = "video/avi"
        Case ".doc"
            ContentType = "application/msword"
        Case ".zip"
            ContentType = "application/zip"
            ContentType = "application/x-zip-compressed"
        Case ".xls"
            ContentType = "application/vnd.ms-excel"
        Case ".gif"
            ContentType = "image/gif"
        Case ".jpg", "jpeg"
            ContentType = "image/jpeg"
        Case ".wav"
            ContentType = "audio/wav"
        Case ".mp3"
            ContentType = "audio/mpeg3"
        Case ".mpg", "mpeg"
            ContentType = "video/mpeg"
        Case ".rtf"
            ContentType = "application/rtf"
		Case ".htm", "html"
            ContentType = "text/html"
		Case ".asp"
            ContentType = "text/asp"
        Case Else
            'Handle All Other Files
            ContentType = "application/octet-stream"
    End Select
	
	Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName
	Response.AddHeader "Content-Length", strFileSize
	' In a Perfect World, Your Client would also have UTF-8 as the default 
	' In Their Browser
	Response.Charset = "UTF-8"
	Response.ContentType = ContentType
	
	Do While Not objStream.EOS
		Response.BinaryWrite objStream.Read(8192)	'	1024*8
		Response.Flush
	Loop

objStream.Close
Set objStream = Nothing

%>


<SCRIPT LANGUAGE='JavaScript'>
{
	window.close();
}
</SCRIPT>


x</p>

metti il nome del file nella session e richiami lo script