PhotoMatrixMotion

[Stan]

Innanzitutto un grazie a and80 per aver condiviso questa cosa fighissima. Ma mi domandavo un paio di cose.

		mm.effect
		mm.onRollOver=function(){
			//var trans:Transform = new Transform(this);
			//trans.colorTransform = colorTrans_2
			this.effect = new PhotoMatrixMotion(this, "normal", "luminance", None.easeNone, 50, false);			
		}
		mm.onRollOut=mm.onDragOut=function(){
			//var trans:Transform = new Transform(this);
			//trans.colorTransform = colorTrans_1
			this.effect = new PhotoMatrixMotion(this, "luminance", "normal", None.easeNone, 50, false);
		}

Si può passare come stato iniziale un valore del tipo "attuale" perchè se io faccio in out nel mezzo delle transizioni non parto da normal e da luminance.

Chiedo troppo? E' già possibile farlo ma sono n00b? Richiede troppo sbatti? Nel caso lascia perdere^^

Per capirci sarebbe un po' come in una tween così

new Tween(target, "_alpha", Regular.easeOut, target._alpha,100,20,false)

[and80]

prova così

import mx.transitions.easing.*;
var matr:Object = new PhotoMatrixMotion(mc, "satured", "satured", None.easeNone, .1, true);
var mt:Array = matr.matrix;
mc.onRollOver = function() {
    mt = _root.matr.matrix;
    _root.matr = new PhotoMatrixMotion(mc, mt, "normal", None.easeNone, .5, true);
};
mc.onRollOut = function() {
    mt = _root.matr.matrix;
    _root.matr = new PhotoMatrixMotion(mc, mt, "satured", None.easeNone, .5, true);
}; 

[Stan]

Lunedì provo e ti faccio sapere

[Stan]

Non mi pare che funzi, ho provato a fare il trace di matr.matrix appena dopo lanciata
var matr:Object = new PhotoMatrixMotion(mc, "satured", "satured", None.easeNone, .1, true);

e ho undefined

[and80]

devo aggiornare il link, mi pareva di averlo fatto

la classe corretta è questa:

import mx.transitions.*;
import mx.transitions.easing.*;
import flash.filters.ColorMatrixFilter;
class PhotoMatrixMotion {
    /*
    Elenco degli effetti disponibili
    "normal", "luminance", "negative", "satured", "in_satured", "hue", "contrast", "in_contrast", "deep_red", "deep_blue", "deep_yellow", "fluorescent", "sepia"
    */
    private var normalMatrix:Array = [1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0];
    private var luminanceMatrix:Array = [1, 0, 0, 0, 255, 0, 1, 0, 0, 255, 0, 0, 1, 0, 255, 0, 0, 0, 1, 255];
    private var negativeMatrix:Array = [-1, 0, 0, 0, 255, 0, -1, 0, 0, 255, 0, 0, -1, 0, 255, 0, 0, 0, 1, 0];
    private var saturedMatrix:Array = [0.3086, 0.6094, 0.082, 0, 0, 0.3086, 0.6094, 0.082, 0, 0, 0.3086, 0.6094, 0.082, 0, 0, 0, 0, 0, 1, 0];
    private var in_saturedMatrix:Array = [3.0742, -1.8282, -0.246, 0, 0, -0.9258, 2.1718, -0.246, 0, 0, -0.9258, -1.8282, 3.754, 0, 0, 0, 0, 0, 1, 0];
    private var hueMatrix:Array = [-0.574, 1.43, 0.144, 0, 0, 0.426, 0.43, 0.144, 0, 0, 0.426, 1.43, -0.856, 0, 0, 0, 0, 0, 1, 0];
    private var contrastMatrix:Array = [0, 0, 0, 0, 63.5, 0, 0, 0, 0, 63.5, 0, 0, 0, 0, 63.5, 0, 0, 0, 1, 0];
    private var in_contrastMatrix:Array = [11, 0, 0, 0, -635, 0, 11, 0, 0, -635, 0, 0, 11, 0, -635, 0, 0, 0, 1, 0];
    private var deep_redMatrix:Array = [1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0];
    private var deep_blueMatrix:Array = [0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0];
    private var deep_yellowMatrix:Array = [0, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0];
    private var fluorescentMatrix:Array = [0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0];
    private var sepiaMatrix:Array = [0.35, 0.35, 0.35, 0, 0, 0.30, 0.30, 0.30, 0, 0, 0.21, 0.21, 0.21, 0, 0, 0, 0, 0, 1, 0];
    // Variabili della classe
    private var __target:MovieClip;
    private var __initialMatrix:Array;
    private var __finalMatrix:Array;
    private var __easeType;
    private var __time:Number;
    private var __useSeconds:Boolean;
    // Eventi
    public var onMotionFinished:Function;
    // Costruttore della classe
    function PhotoMatrixMotion(target:MovieClip, from:Object, to:Object, easeType:Function, time:Number, useSeconds:Boolean) {
        __target = target;
        __initialMatrix = return_matrix(from);
        __finalMatrix = return_matrix(to);
        __easeType = easeType;
        __time = time;
        __useSeconds = useSeconds;
        __process__(__target, __initialMatrix, __finalMatrix, __easeType, __time, __useSeconds);
    }
    private function return_matrix(effect):Array {
        if (typeof(effect) == "string") {
            var matrix:Array = this[effect+"Matrix"].slice(0, this[effect+"Matrix"].length-1);
            return matrix;
        } else {
            var matrix:Array = effect.slice(0, effect.length);
            return matrix;
        }
    }
    private function __process__(target:MovieClip, from:Array, to:Array, easeType:Function, time:Number, useSeconds:Boolean):Void {
        target.filters = [new ColorMatrixFilter(from)];
        var path:Object = this;
        for (var i = 0; i<from.length; i++) {
            this['tw'+i] = new Tween(from, i.toString(), easeType, from[i], to[i], time, useSeconds);
            this['tw0'].onMotionChanged = function() {
                target.filters = [new ColorMatrixFilter(from)];
            };
            this['tw0'].onMotionFinished = function() {
                path["onMotionFinished"]();
            };
        }
    }
    public function get matrix():Array {
        return this['__initialMatrix'];
    }
} 

[Stan]

Ok, domani provo

[Stan]

Ok, finalmente ho avuto un po' di tempo per provare, e confermo che funziona

Grazie

Edit: piccola aggiunta.


La prima animazione credo serva solo per creare l'oggetto e quindi caricare una matrice di partenza. Nell'esempio hai usato satured satured, ma immagino vada bene qualsiasi valore (e per correttezza direi il valore che avrà lo stato "naturale" della foto).

Se quanto detto è giusto credo ci sia qualche piccolo inghippo nelle matrici.
Se vado da normal a in_contrast e poi torno indietro (anche facendo completare le tween), la foto mi rimane un po' blu.

Personalmente non mi crea un problema, ma volevo segnalartela.

[and80]

ho fatto diversi test e non ho avuto riscontri del genere, apparte un riabituarsi più lento dell'occhio se il passaggio era forte (es da fluorescente a normale)

[Stan]

Avrò sbagliato qualcosa io