dividere immagine con bitmap data

[sha]

buonasera

ho cercato ovunque ma nn trovo cio che mi serve per cui vi chiedo:

come si fa a dividere un'immagine (o meglio un movieclip) in modo da creare tanti piccoli pezzi? tipo puzzle ma senza incastri!!

ho trovato un articolo sulla cosa ma è per as3 e a me serve che sia in as2

la logica è:

faccio una copia del mio movie creandomi una bitmap con la classe bitmapdata
poi dovrei creare le righe e le colonne per tagliare..credo..
ma non so come si faccia..

quello che vorrei realizzare è l'esplosione di un movie (o immagine) in tanti piccoli pezzi che si disperdono...o qualcosa di simile..


qualcuno mi da un idea di come si faccia??
tutorial, pezzi di codice...qualcooooosa!!!!! pleaze! grazie mille

[and80]

avevo fatto questo:

import flash.display.BitmapData;
import flash.geom.Rectangle;
function splitImage (target:MovieClip, destination:MovieClip, splitX:Number, splitY:Number):Void {
    var totalSplit:Number = splitX*splitY;
    var wdt:Number = target._width/splitX;
    var hgt:Number = target._height/splitY;
    var coordArray:Array = new Array();
    for (var i = 0; i<totalSplit; i++) {
        var h = i-1;
        var x = (coordArray[h][0]<target._width-wdt) ? coordArray[h][0]+wdt : 0;
        var y = (x != 0) ? coordArray[h][1] : (h>-1) ? coordArray[h][1]+hgt : 0;
        coordArray.push([x, y]);
    }
    for (var k = 0; k<coordArray.length; k++) {
        var bitmap:BitmapData = new BitmapData(target._width, target._height);
        var bitmap2:BitmapData = new BitmapData(wdt, hgt);
        var blend:String = "normal";
        var rectangle:Rectangle = new Rectangle(coordArray[k][0], coordArray[k][1], wdt, hgt);
        bitmap.draw(target);
        bitmap2.copyPixels(bitmap, rectangle, new Point(0, 0));
        var c:MovieClip = destination.createEmptyMovieClip("bmd"+k, k);
        c._x = coordArray[k][0];
        c._y = coordArray[k][1];
        c.attachBitmap(bitmap2, 1);
        // codice di riprova della avvenuta separazione
        c.onPress = function() { this.startDrag() };
        c.onRelease = function() { this.stopDrag() };
        c.onReleaseOutside = function() { this.stopDrag() };
        // fine del codice di riprova
    }
}; 

e ad esempio lo puoi usare così

var mc1 = this.createEmptyMovieClip("mc1", 1);
var mc2 = this.createEmptyMovieClip("mc2", 2);
var mcload:Object = new MovieClipLoader();
mcload.onLoadStart = function(target) {
    target._alpha = 0;
};
mcload.onLoadInit = function(target) {
    splitImage(mc1, mc2, 5, 5);
};
mcload.loadClip("image.jpg", mc1); 

[sha]

grandissimo and!
è perfetto, fantastico!!!

piccolo problemino però:

ho provato a usarlo su un clip che contiene una scritta vettoriale e un pulsante..
lo taglia ma mi crea un fondo bianco..why?

c'è qualche proprietà da settare per la trasparenza?

[nep036]

Prova sostituendo queste due righe cosi:

var bitmap:BitmapData = new BitmapData(target._width, target._height, true, 0x00000000);
var bitmap2:BitmapData = new BitmapData(wdt, hgt, true, 0x00000000);

Non ho provato...

[nep036]

Ho editato perché avevo messo false al posto di true..

[sha]

grazie mille nep!

nel frattempo leggendo in giro ho trovato la tua stessa soluzione ma mettendo "0x00FFFFFF"


var bitmap:BitmapData = new BitmapData(target._width, target._height, true,0x00FFFFFF);
var bitmap2:BitmapData = new BitmapData(wdt, hgt, true,0x00FFFFFF);


ho testato anche col tuo codice e funziona comunque

ora mi manca solo da creare una funziona che spazzi via i vari pezzetti!!
se non ce la faccio vi rompo !!

[nep036]

si, cambia il colore, ma avendo alpha 00 praticamente il risultato è uguale...




PS

Senza stare li a leggere in giro, basta dare una occhiata alla documentazione, molto spesso si fa prima :-)

[sha]

grazie del consiglio molto apprezzato!

[sha]

problemino:

lo script splitta l'immagine ma tra i vari "pezzi" crea uno spazio di 1 o 2 pixel...è possibile toglierlo e fare in modo che le varie parti siano tutte adiacenti?

[and80]

è un problema di arrotondamenti che avviene quando la larghezza dell'immagine non divide esattamente per il numero di sezioni impostate
era una cosa che mi ero ripromesso di aggiustare per una cosa mia, ma cone non ho mai portato a termine, magari questa è la volta buona dammi tempo