Calendario settimanale

[cavicchiandrea]

Dovrei fare un calendario "settimanale" che si generi dinamicamente per le 52 settimane dal 01/01/2008 > 31/12/2008 (possibilmente che si auto incrementi di anno in anno) sono 2 giorni che ci sbatto la testa. Tra ricerche script etc.. non ci capisco più niente sono :berto: riuscireste a darmi una mano? (con un esempio pratico)

[optime]

ok, ma se non ci dici quale è il problema... (e sei pure moderatore!)

[cavicchiandrea]

Ricreare completamente lo script in asp che mi generi un calendario settimanale, il problema sta nello scrivere il codice asp completo.
Credevo si capisse ma se mai fatto questa domanda ho creduto male sorry (a desso che so che i moderatori non possono sbagliare non capiterà mai più... fino alla prossima volta)

[optime]

usa la funzione DateAdd e vai avanti di un giorno alla volta, dalla data di inziaio alla data di fine.

ogni 7 giorni o dopo ogni domenica o prima di ogni lunedi vai a capo con un <td>

più semplice a farsi che a dirsi

[cavicchiandrea]

Originariamente inviato da optime
usa la funzione DateAdd e vai avanti di un giorno alla volta, dalla data di inziaio alla data di fine.

ogni 7 giorni o dopo ogni domenica o prima di ogni lunedi vai a capo con un <td>

più semplice a farsi che a dirsi

Visto che è cosi semplice (e io come già detto non mi raccapezzo più con date etc...) potresti farmi un esempio pratico? Grazie

[Domenix]

Originariamente inviato da cavicchiandrea
Visto che è cosi semplice (e io come già detto non mi raccapezzo più con date etc...) potresti farmi un esempio pratico? Grazie

Tradotto in italiano schietto: me lo fai te, per piacere, che non ce la faccio?

[cavicchiandrea]

Originariamente inviato da Domenix
Tradotto in italiano schietto: me lo fai te, per piacere, che non ce la faccio?

Messa giù cosi suona male ma di fatto e questo, non sono abituato a chiedere cosi spudoratamente.
A mia difesa posso dire che molto è dovuto che da 2 giorni cerco informazioni faccio esperimenti, aggiungici che ho poca dimestichezza con le date che sono un po il mio tallone d'Achille ora come ora anche se una stupidata non riesco a pensare come risolvere/scrivere il codice.

Grazie per l'eventuale aiuto.

[br1]

Un tantino didattico... scusa

<%
anno = 2008

primo = DateSerial(anno,01,01)
' se occorre torno indietro al lunedi'
Do While Weekday(primo) <> 2
	primo = DateAdd("D", -1, primo)
Loop

ultimo = DateSerial(anno,12,31)
' vado avanti fino alla domenica
Do While Weekday(ultimo) <> 1
	ultimo = DateAdd("D", 1, ultimo)
Loop

response.write "<table border=1>"
response.write "<tr><th>Lunedi'</th><th>Martedi'</th><th>Mercoledi'</th><th>Giovedi'</th><th>Venerdi'</th><th>Sabato</th><th>Domenica</th></tr>" & vbcrlf

Do While primo <= ultimo
	If Weekday(primo) = 2 Then
		response.write "<tr>"
	End If
	response.write "<td>" & primo & "</td>"
	primo = DateAdd("D", 1, primo)
	If Weekday(primo) = 2 Then
		response.write "</tr>" & vbcrlf
	End If
Loop

response.write "</table>"

%>

[Domenix]

Inizia da questo:

<%
session.LCID = 1040
anno = datePart("yyyy",date())

inizio = cDate("01/01/" & anno)
do until giornoSettimanaInizio = 1
  giornoSettimanaInizio = weekDay(inizio)
  inizio = dateAdd("d",-1,inizio)
loop

fine = cDate("31/12/" & anno)
do until giornoSettimanaFine = 2
  giornoSettimanaFine = weekDay(fine)
  fine = dateAdd("d",1,fine)
loop
%>
<table>
  <tr>
    <td>Luned&amp;igrave;</td>
    <td>Marted&amp;igrave;</td>
    <td>Mercoled&amp;igrave;</td>
    <td>Gioved&amp;igrave;</td>
    <td>Venerd&amp;igrave;</td>
    <td>Sabato</td>
    <td>Domenica</td>
    <td>&amp;nbsp;</td>
  </tr>
<%
settimana = 1
data = inizio
while not data > fine
  giornoSettimanaNumerico = weekDay(data)
   if giornoSettimanaNumerico = 2 then 
%>
  <tr>
<%
  end if
%>
    <td><%=data%></td>
<%
  if giornoSettimanaNumerico = 1 then
%>
    <td>
      <select name="settimana_<%=settimana%>">
        <option value=""></option>
      </select>
    </td>
  </tr>
<%
    settimana = settimana + 1
  end if
  data = dateAdd("d",1,data)
wend
%>
</table>

Considera che non ho modo di testarlo perchè sto su Linux Ubuntu e ASP non ci gira, ovviamente.
Provalo a tuo rischio e pericolo (potrebbe esploderti il pc...) e vedi se va e semmai posta gli errori.

[cavicchiandrea]

Grazie a tutti per l'aiuto, x Bruno un mito (come sempre) è perfetto