Ciclare effetto

[Coralba]

Ho applicato alcuni degli effetti della classe Photomatrix, sviluppata da and80, ma non riesco a rendere ciclica l'animazione.

var mcLoad:MovieClipLoader = new MovieClipLoader();
var mcList:Object = new Object();
mcList.onLoadStart = function(target:MovieClip) {
target._alpha = 0;
};
mcList.onLoadProgress = function(target:MovieClip) {
target._parent.testo.text = this[target._name+"__perc"]+"%";
};
mcList.onLoadInit = function(target:MovieClip) {
target._alpha = 100;
var effect = new PhotoMatrixMotion(target, "sepia", "normal", None.easeNone, 5, true);
effect.onMotionFinished = function(){
var effect1 = new PhotoMatrixMotion(target, "normal", "sepia", None.easeNone, 5, true);
}
};



mcLoad.addListener(mcList);
var mc:MovieClip = this.createEmptyMovieClip("mc", 1);
mcLoad.loadClip("../img/8.swf", mc);

Ho anche provato ad inserire un onMotionFinished...yoyo(); ma senza esito...lo so è domenica ma qualcuno è in grado di aiutarmi?
Il massimo sarebbe and80, cioè il proprietario ma chiunque sia in grado di aiutarmi è il benvenuto!

[Coralba]

Buongiorno, scusate se quoto ma dovrei proprio risolvere questa cosa, perchè il mio capo vuole per forza, quel tipo di effetto, cioè che renda le immagini datate...nessuno?

[and80]

Ciao, ho visto ora il messaggio.
La classe non contiene un metodo yoyo e bisognerebbe crearselo, ma in questi giorni sono un pochino occupato e penso che non riuscirò ad aiutarti a fare questa modifica.
Comunque non ho ben capito quello che devi fare esattamente, se hai bisogno di creare un rollover/rollout la cosa è più semplice.

[Coralba]

no devo semplicemente applicare i filtri così come tu li hai creati, ma in modo che ritornino ad applicarsi di nuovo dall'inizio, cioè nell'esempio che ti ho inviato, dal sepia iniziale e così via.
carico già un movie esterno con un fade in/fade out di alcune foto, e vorrei (non tanto io, quanto il mio capo...) che l'effetto si ripetesse in continuazione...spero di essermi spiegata

[and80]

Tanto per capire, come se una palla si spostasse da un punto ad un altro per poi tornare al punto di partenza, ciclicamente?

[Coralba]

[and80]

Forse riesco ad aiutarti, ma non subito. Ora devo uscire, se riesco ti do qualche notizia più tardi o dopo pranzo.

[Coralba]

Esattamente...è un sito per un negozio di mobili che compie 50 anni di attività, e l'idea era quella di far vedere il passaggio del tempo applicando appunto un filtro seppia o che desaturi a delle immagini moderne...

[Coralba]

Va bene quando puoi...già è molto avere un aiuto...a dopo

[and80]

ho fatto una prova ed ho visto che la classe era inappropriata per questa cosa
così l'ho modificata:

import mx.transitions.*;
import mx.transitions.easing.*;
import flash.filters.ColorMatrixFilter;
class flash.PhotoMatrixMotion {
    /*
    Elenco degli effetti disponibili
    "normal", "luminance", "negative", "satured", "in_satured", "hue", "contrast", "in_contrast", "deep_red", "deep_blue", "deep_yellow", "fluorescent", "sepia"
    */
    private var normalMatrix:Array = [1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0];
    private var luminanceMatrix:Array = [1, 0, 0, 0, 255, 0, 1, 0, 0, 255, 0, 0, 1, 0, 255, 0, 0, 0, 1, 255];
    private var negativeMatrix:Array = [-1, 0, 0, 0, 255, 0, -1, 0, 0, 255, 0, 0, -1, 0, 255, 0, 0, 0, 1, 0];
    private var saturedMatrix:Array = [0.3086, 0.6094, 0.082, 0, 0, 0.3086, 0.6094, 0.082, 0, 0, 0.3086, 0.6094, 0.082, 0, 0, 0, 0, 0, 1, 0];
    private var in_saturedMatrix:Array = [3.0742, -1.8282, -0.246, 0, 0, -0.9258, 2.1718, -0.246, 0, 0, -0.9258, -1.8282, 3.754, 0, 0, 0, 0, 0, 1, 0];
    private var hueMatrix:Array = [-0.574, 1.43, 0.144, 0, 0, 0.426, 0.43, 0.144, 0, 0, 0.426, 1.43, -0.856, 0, 0, 0, 0, 0, 1, 0];
    private var contrastMatrix:Array = [0, 0, 0, 0, 63.5, 0, 0, 0, 0, 63.5, 0, 0, 0, 0, 63.5, 0, 0, 0, 1, 0];
    private var in_contrastMatrix:Array = [11, 0, 0, 0, -635, 0, 11, 0, 0, -635, 0, 0, 11, 0, -635, 0, 0, 0, 1, 0];
    private var deep_redMatrix:Array = [1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0];
    private var deep_blueMatrix:Array = [0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0];
    private var deep_yellowMatrix:Array = [0, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0];
    private var fluorescentMatrix:Array = [0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0];
    private var sepiaMatrix:Array = [0.35, 0.35, 0.35, 0, 0, 0.30, 0.30, 0.30, 0, 0, 0.21, 0.21, 0.21, 0, 0, 0, 0, 0, 1, 0];
    // Variabili della classe
    private var __target:MovieClip;
    private var __initialMatrix:Array;
    private var __finalMatrix:Array;
    private var __easeType;
    private var __time:Number;
    private var __useSeconds:Boolean;
    // Eventi
    public var onMotionFinished:Function;
    // Costruttore della classe
    function PhotoMatrixMotion(target:MovieClip, from:Object, to:Object, easeType:Function, time:Number, useSeconds:Boolean) {
        __target = target;
        __initialMatrix = return_matrix(from);
        __finalMatrix = return_matrix(to);
        __easeType = easeType;
        __time = time;
        __useSeconds = useSeconds;
    }
    private function return_matrix(effect):Array {
        if (typeof(effect) == "string") {
            var matrix:Array = this[effect+"Matrix"].slice(0, this[effect+"Matrix"].length-1);
            return matrix;
        } else {
            var matrix:Array = effect.slice(0, effect.length);
            return matrix;
        }
    }
    private function __process__(target:MovieClip, from:Array, to:Array, easeType:Function, time:Number, useSeconds:Boolean):Void {
        target.filters = [new ColorMatrixFilter(from)];
        var path:Object = this;
        for (var i = 0; i<from.length; i++) {
            this['tw'+i] = new Tween(from, i.toString(), easeType, from[i], to[i], time, useSeconds);
            this['tw0'].onMotionChanged = function() {
                target.filters = [new ColorMatrixFilter(from)];
            };
            this['tw0'].onMotionFinished = function() {
                path["onMotionFinished"]();
            };
        }
    }
    public function startMotion () {
        if (__target != undefined) {
            __process__(__target, __initialMatrix, __finalMatrix, __easeType, __time, __useSeconds);
        }
    }
    public function set target (m:MovieClip) {
        __target = m;
    }
    public function get target ():MovieClip {
        return __target;
    }
    public function set fromMatrix (o:Object) {
        __initialMatrix = return_matrix(o);
    }
    public function get fromMatrix ():Object {
        return __initialMatrix;
    }
    public function set toMatrix (o:Object) {
        __finalMatrix = return_matrix(o);
    }
    public function get toMatrix ():Object {
        return __finalMatrix;
    }
    public function get matrix():Array {
        return this['__initialMatrix'];
    }
} 

e l'ho testata con questo codice:

import flash.PhotoMatrixMotion;
var fromMatrix = "sepia";
var toMatrix = "normal";
function switchMatrix () {
    fromMatrix = fromMatrix == "sepia" ? "normal" : "sepia";
    toMatrix = toMatrix == "normal" ? "sepia" : "normal";
}
var mcLoad:Object = new MovieClipLoader ();
mcLoad.onLoadInit = function (target:MovieClip) {
    target._alpha = 100;
    effect.startMotion();
};
mcLoad.loadClip("image.jpg", _root.createEmptyMovieClip("mc", 1));
var effect:PhotoMatrixMotion = new PhotoMatrixMotion (mc, fromMatrix, toMatrix, null, 5, true);
effect.onMotionFinished = function () {
    switchMatrix();
    this.fromMatrix = fromMatrix;
    this.toMatrix = toMatrix;
    this.startMotion();
}