Ciao Pietro, ho letto da un tuo post che hai script di select dinamiche in asp/ajax.
Puoi postarle sul forum o inviarle via msg privati?
Grazie
Preferisco il forum rispetto ai messaggi privati. Perciò ti rispondo qui.

Un esempio che ho fatto solo a scopo didattico, lo trovi qui:

http://web.tiscali.it/archivio_esemp...nce_comuni.zip

Nota: controlla bene perchè è da un pezzo che non uso asp.

Ti voglio fare notare la funziona abc.js di Andrea Giammarchi. Ma con prototype sarebbe lo stesso.

Per qualunque cosa, a disposizione. Ciao.


ps. con prototype ho questo esempio
codice:
<%@ Language=VBScript %>
<%
	option explicit
	
	Response.Buffer = true
	
	onload

%>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" >
<head>
    <title>Pagina senza titolo</title>
    <link href="../../../stili/Styles.css" rel="stylesheet" type="text/css" />
    <script type="text/javascript" src="../../../js/prototype.js"></script>

    <script language="javascript" type="text/javascript">
// <!CDATA[
function recupera_province(v)
{
    var id_regione = v.value;
    if(id_regione == "")
    {
        $("div1").innerHTML = '<select style="width: 200px"></select>';
        return;
    }
    
    var parametri = "id_regione=" + id_regione;
    var url_action = "?comando_ajax=trova_province";
    
    var j = new Ajax.Updater(
                'div1',
                url_action,
                {parameters:parametri}
                );
    
    
    /*
    new Ajax.Request(url_action, {onComplete:showResponse, parameters:parametri} );
    function showResponse(originalRequest)
    {
        var t = originalRequest.responseText;
	    $("div1").innerHTML = t;
    }
    */
    
}


// ]]>
    </script>
</head>
<body>
    <h3>Esempio Regioni-province</h3>
    <table>
        <tr>
            <td>Regioni:</td>
            <td><select id="regioni" onchange="recupera_province(this);" style="width: 200px"><%=regioni()%></select></td>
        </tr>
        <tr>
            <td>Province</td>
            <td><div id="div1"><select style="width: 200px"></select></div></td>
        </tr>
    </table>
</body>
</html>

<%

sub onload()
    dim comando_ajax
    
    comando_ajax = Request("comando_ajax")
    if(comando_ajax = "trova_province") then
        trova_province
    end if

end sub

sub trova_province()
    dim id_regione
    id_regione = Request("id_regione")
    response.Clear
    response.Write province(id_regione)
    response.End
end sub

function regioni()
    dim db, rs, sql

    set db = server.CreateObject("ADODB.Connection")
    set rs = server.CreateObject("ADODB.RECORDSET")

    db.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\dati\test\test.mdb;User Id=admin;Password=;" 


    sql = "SELECT * FROM REGIONI"

    rs.Open sql, db, 3, 3
    dim s
    
    s = "<option value=""""></option>"
    do while not rs.EOF
	    s = s & "<option value=""" + rs(0) + """ >" & rs(1) & "</option>"
	    rs.MoveNext
    loop
    regioni = s
    
    rs.Close: set rs = nothing
    db.Close: set db = nothing

end function

function province(id_regione)
    On error resume next
    
    dim db, rs, sql, s

    set db = server.CreateObject("ADODB.Connection")
    set rs = server.CreateObject("ADODB.RECORDSET")

    db.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\dati\test\test.mdb;User Id=admin;Password=;" 


    sql = "SELECT * FROM Q_PROVINCIE WHERE CODICE_ISTAT_REGIONE = """ & id_regione & """"
    rs.Open sql, db, 3, 3
    if Err.number <> 0 then
        province = "Errore: " & err.number & "
" & err.Description
        err.Clear
        exit function
    end if
    
    
    's = "<select size=""" & rs.RecordCount & """ >"
    s = "<select style=""width: 200px"">" & "<option></option>"
    do while not rs.EOF
	    s = s & "<option value=""" + rs(0) + """ >" & rs(1) & "</option>"
	    rs.MoveNext
    loop
    s = s & "</select>"
    province = s
        
    rs.Close: set rs = nothing
    db.Close: set db = nothing

    if Err.number <> 0 then
        province = "Errore: " & err.number & "
" & err.Description
        err.Clear
        exit function
    end if
    
end function
%>