[AS3] problema con gestione timeLine external swf

[tecinese]

Ciao a tutti

Sto cercando di gestire la timeline di un swf esterno caricato all'interno del mio main.fla

Il codice che sto utilizzando è questo:

var carCont:*;
var ext:MovieClip=carCont;
var swf:String = "external.swf";
var caricatore:Loader  = new Loader();
caricatore.load(new URLRequest(swf));
 
pulsante_mc.addEventListener(MouseEvent.CLICK, onClick);
 
function onClick(event:MouseEvent):void {
 
var carCont:*=caricatore.content;
addChild(caricatore);
ext.gotoAndPlay(2);
} 

Ma ho questa notfica di errore:

TypeError: Error #1009: Impossibile accedere a una proprietà o a un metodo di un riferimento oggetto null.
at appunti_fla::MainTimeline/frame1()

Come potrei fare per risolvere?

[and80]

Se non è verificato che il caricamento esterno sia andato a buon fine, non è possibile gestire la timeline del file esterno.

var caricatore:Loader = Loader(addChild(new Loader()));
caricatore.contentLoaderInfo.addEventListener(Event.INIT, init);
caricatore.load(new URLRequest("external.swf"));
function init (e:Event) {
    pulsante_mc.addEventListener(MouseEvent.CLICK, onClick);
}
function onClick(event:MouseEvent):void {
    var ext:MovieClip = MovieClip(caricatore.content);
    ext.gotoAndPlay(2);
} 

[tecinese]

Grazie And!

Avevo il sospetto fosse questo il problema....ma non sapevo da dove partire per affrontarlo.
In effetti mi ero incastrato provando l'ADDED_TO_STAGE all'interno del swf esterno, ma senza capire bene come utilizzarlo.

Provo immediatamente la tua soluzione.

[tecinese]

Funziona perfettamente, inoltre hai messo anche un po' d'ordine nel mio codice.

Ora vorrei farti un'altra domanda:

a tuo giudizio, i listener che gestiscono il ROLL OVER e il ROLL OUT di "pulsante_mc" conviene metterli all'interno della funzione "init()", oppure è meglio gestirli separatamente?

Ciao e grazie ancora.

[and80]

Mah, il rollover e rollout volendo li puoi mettere anche fuori, salvo che non effettuino azioni che coinvolgono quello stesso file esterno, ma credo di no.

[tecinese]

Rieccomi dopo qualche giorno di studio.

Sto cercando di implentare quanto appreso prima, per creare una classe esterna (Principale.as) da associare al mio fla. Questa classe contiene due array.

Il primo è un array delle istanze del menù principale
Il secondo è un array dei path dei file.swf esterni che dovranno essere caricati

Tutti i file.swf esterni hanno animazioni su timeline con intro e outro
Il mio scopo è di controllarne la timeline

ecco la classe (in fase di costruzione):

package myClasses
{
    import flash.net.URLRequest;
    import flash.display.*;
    import flash.events.*;


    public class Principale extends MovieClip
    {

        var swf:String;
        var caricatore:Loader;


        public function Principale ()
        {
            inizia ();
        }



        function inizia ():void
        {

            mainButton_array = new Array
            (
             home_btn,
             section1_btn,
             section2_btn,
             section3_btn
             );

            sezioni_array = new Array
            (
             "sito_sezioni/home.swf",
             "sito_sezioni/section1.swf",
             "sito_sezioni/section2.swf",
             "sito_sezioni/section3.swf"
            );

            for (var i:Number=0; i < sezioni_array.length; i++)
            {
                swf = sezioni_array[i];
                var caricatore:Loader  = new Loader();
                caricatore.load (new URLRequest(swf));
                addChild (caricatore);
                caricatore.contentLoaderInfo.addEventListener (Event.INIT, controllaSezioni);
            }
        }

        }


        function controllaSezioni (event:Event):void
        {
            for (var i:int=0; j < mainButton_array.length; i++)
            {
                mainButton_array[i].addEventListener (MouseEvent.CLICK, onClick);
            }
        }

        function onClick (event:MouseEvent):void
        {
            var ext:MovieClip = MovieClip(caricatore.content);
            trace(ext);
        }


    }
} 

alla fine ho messo un trace(ext);

che mi dà il solito errore di prima :


TypeError: Error #1009: Impossibile accedere a una proprietà o a un metodo di un riferimento oggetto null.
at myClasses::Principale/onClick()


evidentemente c'è qualcosa che non va. Dove sbaglio?

[and80]

Dentro a quella funzione "caricatore" non esiste perchè la stai creando in un'altra funzione che non è collegata all'oggetto.
Ci sono un po' di cose che non vanno nella classe, se ricrei ogni volta "caricatore", non avrai mai un riferimento preciso al caricatore che effettivamente devi usare e quindi "onClick" non saprà neanche cosa dovrebbe cercare.
Meglio che ti crei un array per ospitare i caricatori che usi, anche se... aspetta ma non devi utilizzare un solo caricatore che carichi e scarichi i filmati dall'esterno? O i filmati già caricati devono restare sullo stage?

[tecinese]

Il mio obiettivo finale, a cui sto cercando di arrivare per gradi è di:

1 - caricare e scaricare i filmati esterni alla pressione di differenti pulsanti.
2 - avere delle transizioni in uscita ed in entrata

Con questo tentativo ho pensato che avrei potuto caricare tutti i filmati insieme (i filmati esterni hanno il primo frame vuoto), per poi controllarne la timeline in un secondo momento.
Ma forse non è la strada migliore per arrivare dove voglio arrivare io.

[and80]

Non è malvagia come idea, anche se avrai un po' di risorse occupate per via del caricamento multiplo, volendo potresti fare tutto con un solo Loader, ma ponendo di seguire la strada che hai descritto, dovresti muoverti un tantino meglio con i caricatori, usa un array anche per quelli, o ancora meglio, per far sì che funzioni tutto il meccanismo, inserisci ogni loader dentro un movieclip, in modo che in questo stesso movieclip potrai aggiungere delle variabili da sfruttare poi nelle varie funzioni della classe.
Io la classe la vedrei così:

package myClasses {
    import flash.display.Loader;
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.net.URLRequest;
    public class Principale extends MovieClip {
        private var array_pulsanti:Array;
        private var array_sezioni:Array;
        private var array_caricatori:Array;
        public function Principale () {
            array_pulsanti = [home_btn, section1_btn, section2_btn, section3_btn];
            array_sezioni = ["sito_sezioni/home.swf", "sito_sezioni/section1.swf", "sito_sezioni/section2.swf", "sito_sezioni/section3.swf"];
            array_caricatori = [];
            array_sezioni.forEach(__foreach__);
        }
        private function __foreach__ (e:*, i:uint, a:Array) {
            array_pulsanti[i].index = i;
            array_caricatori.push (addChild(new MovieClip()) as MovieClip);
            array_caricatori[i].caricatore = array_caricatori[i].addChild(new Loader());
            array_caricatori[i].pulsante = array_pulsanti[i];
            array_caricatori[i].caricatore.load (new URLRequest(e));
            array_caricatori[i].caricatore.contentLoaderInfo.addEventListener(Event.INIT, __init__);
        }
        private function __init__ (e:Event) {
            var c:MovieClip = MovieClip(e.target.loader.parent);
            c.pulsante.addEventListener(MouseEvent.CLICK, __click__);
        }
        private function __click__ (e:MouseEvent) {
            var ext:MovieClip = array_caricatori[e.target.index].caricatore.content;
            trace(ext);
        }
    }
} 

Salvo che non mi sia scordato qualche import, dovrebbe funzionare già così.
Se mi confermi il funzionamento, passiamo poi ad analizzarla.

[edit] C'era un errore nei nomi che ho corretto, spero che non ce ne siano altri simili.

[tecinese]

Intanto grazie ancora.

Testo e mi studio la tua versione e poi ti faccio sapere.