duplicate mc progressivo

[shecort]

ciao a tutti
avrei bigono di creare un "tappeto" di palline, mi spiego ,mi deve apparire una pallina, poi un'altra poi sempre + velocemente un'altra e una'ltra ancora e così via finoa che mi si riempe lo stage.
sto cercando di rispolverare le mie poche nozioni sul duplicate mc ma dai tentativi che ho fatto non riesco a far si che il riempimento dello stage sia progressivo, mi appaiono tutte in una volta.
sapreste aiutarmi?
grazie 1000

[Stan]

invece di usare un ciclo for devi farlo all'onEnterFrame, dove dentro fai crescere la variabile. Per farlo sempre più veloce boh...io farei tipo un controllo saltando prima ad esempi 5 frame, poi 4, poi 3 etc...Non è bellissimo, ma funziona anche se non sarà una crescita logaritmica.

this.onEnterFrame=function(){
}

[Kaneda81]

Se puoi usare AS3 con la classe Timer fai al volo.

[Kaneda81]

Ok ti ho fatto un esempio, basta che copi sto codice nel primo fotogramma (deve però essere un progetto AS3).

var timer:Timer;
var decrement:int;
var interval:int = 1000;
var radius:int = 25;
var color:uint = 0x000000;
var ballX:int = radius;
var ballY:int = radius;

function init():void
{
    var stageArea:int = stage.stageWidth*stage.stageHeight;
    var ballArea:int = Math.pow(radius*2, 2);
    var maxBalls:int = stageArea/ballArea;
    
    decrement = Math.floor((interval-100)/maxBalls);
    timer = new Timer(interval, maxBalls);
    timer.addEventListener(TimerEvent.TIMER, createBall);
    timer.start();
}

function createBall(e:TimerEvent):void
{
    var s:Sprite = new Sprite();
    s.graphics.beginFill(color, 1);
    s.graphics.drawCircle(ballX, ballY, radius);
    s.graphics.endFill();
    addChild(s);
    
    if (ballX < (stage.stageWidth-radius))
    {
        ballX += radius*2;
    }
    else
    {
        ballX = radius;
        ballY += radius*2;
    }
    
    timer.delay -= decrement;
}

init(); 

E' abbastanza flessibile, quindi lo puoi usare impostando diverse dimensioni dello stage e diverse misure per la tua palla (oltre che a cambiare il colore e quant'altro).

P.S. al calcolo iniziale del decremento levo 100 all'intervallo per evitare che finisca fuori scala il timer.