Gestione Eventi

[TorturedSoul]

Salve sn nuovo di questo linguaggio e volevo chiedervi, io ho creato questa classe:

class Card {
var _points;
var _d;
var _i;
var _t;
public function Card(up, right, down, left, t, i, d) {
_points = new Array(up, right, down.left);
_root.createEmptyMovieClip(i, d);
_d = d;
_i = i;
_t = t;
}
public function get UpPoint() {
return _points[0];
}
public function set UpPoint(value) {
_points[0] = value;
}
public function get RightPoint() {
return _points[1];
}
public function set RightPoint(value) {
_points[1] = value;
}
public function get DownPoint() {
return _points[2];
}
public function set DownPoint(value) {
_points[2] = value;
}
public function get LeftPoint() {
return _points[3];
}
public function set LeftPoint(value) {
_points[3] = value;
}
public function DrawCard(x, y) {
_root.getInstanceAtDepth(_d).moveTo(x, y);
_root.getInstanceAtDepth(_d).lineStyle(1, 0x000000, 100);
if (_t == 1) {
var w = x+100;
var h = y+150;
} else {
var w = x+50;
var h = y+75;
}
_root.getInstanceAtDepth(_d).lineTo(w, y);
_root.getInstanceAtDepth(_d).lineTo(w, h);
_root.getInstanceAtDepth(_d).lineTo(x, h);
_root.getInstanceAtDepth(_d).lineTo(x, y);
}
}


ora però avrei bisogno di gestire gli eventi onClick e onMouseOver degli oggetti di questa classe... qualcuno sa aiutarmi? grazie

[and80]

Ma esattamente di quali oggetti legati alla classe? Parli del clip che crei all'inizio?

[TorturedSoul]

si

[and80]

Potresti creare un riferimento per l'oggetto direttamente nella classe e sfruttarlo per assegnargli le azioni.
Io la tua classe la vedrei meglio in questo modo:

class Card {
    private var P:Object; // points
    private var T:MovieClip; // target
    private var N:String; // name
    private var L:Number; // level
    private var B:Boolean; // 
    function Card (p:Object, t:MovieClip, n:String, l:Number, b:Boolean) {
        P = p != null ? p : {upPoint:0, rightPoint:0, bottomPoint:100, leftPoint:150};
        T = t != null ? t : _root;
        N = n != null ? n : randomID();
        L = l != null ? l : t.getNextHighestDepth();
        B = b != null ? b : true;
    }
    private function randomID ():String {
        var r:String = "";
        var s:String = "abcdefghkijlmnopqrstuvwxyz0123456789ABCDEFGHKIJLMNOPQRSTUVWXYZ";
        var a:Array = s.split("");
        for(var i:uint = 0; i < 8; i++){
            var n:uint = Math.floor(Math.random()*a.length);
            r+=a[n];
        }
        return r;
    }
    public function draw (x, y) {
        var rif:MovieClip = T[N];
        rif.moveTo(x, y);
        rif.lineStyle(1, 0, 100);
        var w:Number = B ? x+100 : x+50;
        var h:Number = B ? y+150 : y+75;
        rif.lineTo(w, y);
        rif.lineTo(w, h);
        rif.lineTo(x, h);
        rif.lineTo(x, y);
    }
    public function get cardMovie ():MovieClip {
        return T[N];
    }
    public function get upPoint ():Number {
        return P.upPoint;
    }
    public function get rightPoint ():Number {
        return P.rightPoint;
    }
    public function get bottomPoint ():Number {
        return P.bottomPoint;
    }
    public function get leftPoint ():Number {
        return P.leftPoint;
    }
    public function set upPoint (n:Number) {
        P.upPoint = n
    }
    public function set rightPoint (n:Number) {
        P.rightPoint = n
    }
    public function set bottomPoint (n:Number) {
        P.bottomPoint = n
    }
    public function set leftPoint (n:Number) {
        P.leftPoint = n
    }
} 

[TorturedSoul]

ok grazie mille, ora provo...

[TorturedSoul]

scusa se rompo ma mi potresti fare un'esempio di creazione di un oggetto card non capisco bene cosa devo passargli come parametri... grazie

[and80]

var c:Card = new Card({upPoint:20, rightPoint:200, bottomPoint:200, leftPoint:20}, this, "test", 10, true);
c.draw(0, 0);
c.cardMovie.onPress = function () {
    trace("button pressed");
}
c.cardMovie.onRollOver = function () {
    trace("rollover");
}
c.cardMovie.onRollOut = function () {
    trace("rollout");
} 

[and80]

Ah, nel costruttore tutti i parametri sono opzionali.
Piuttosto rivendendo la classe mi sono accorto che l'unica cosa che crea effettivamente la grafica della "card" è la funzione "draw", ma non la vedo bene la cosa, cioè a quel punto fai tutto nella funzione draw e crei una classe con funzione "drawCard" statica che restituisce direttamente un riferimento al clip creato.

[TorturedSoul]

scusa mi io ora ho creato un nuovo documento flash e aggiungo il seguente codice

import Card; 
var c:Card = new Card({upPoint:20, rightPoint:200, bottomPoint:200, leftPoint:20}, this, "test", 10, true); 
c.draw(0, 0); 
c.cardMovie.onPress = function() {
     trace("button pressed");
};
c.cardMovie.onRollOver = function() {
     trace("rollover"); 
}; 
c.cardMovie.onRollOut = function() {
     trace("rollout"); 
}; 
stop(); 

però non fa nulla... e non na neanche errori...

[and80]

Vero, non l'avevo testata e ho scordato di riportare il createEmptyMovieClip dalla tua classe.

class Card {
    private var P:Object;// points
    private var T:MovieClip;// target
    private var N:String;// name
    private var L:Number;// level
    private var B:Boolean;//
    function Card (p:Object, t:MovieClip, n:String, l:Number, b:Boolean) {
        P = p != null ? p : {upPoint:0, rightPoint:0, bottomPoint:100, leftPoint:150};
        T = t != null ? t : _root;
        N = n != null ? n : randomID ();
        L = l != null ? l : t.getNextHighestDepth ();
        B = b != null ? b : true;
        T.createEmptyMovieClip(N, L);
    }
    private function randomID ():String {
        var r:String = "";
        var s:String = "abcdefghkijlmnopqrstuvwxyz0123456789ABCDEFGHKIJLMNOPQRSTUVWXYZ";
        var a:Array = s.split ("");
        for (var i:Number = 0; i < 8; i++) {
            var n:Number = Math.floor (Math.random () * a.length);
            r += a[n];
        }
        return r;
    }
    public function draw (x, y) {
        var rif:MovieClip = T[N];
        trace(rif);
        rif.moveTo (x,y);
        rif.lineStyle (1,0,100);
        rif.beginFill (0xFFFFFF);
        var w:Number = B ? x + 100 : x + 50;
        var h:Number = B ? y + 150 : y + 75;
        rif.lineTo (w,y);
        rif.lineTo (w,h);
        rif.lineTo (x,h);
        rif.lineTo (x,y);
        rif.endFill();
    }
    public function get cardMovie ():MovieClip {
        return T[N];
    }
    public function get upPoint ():Number {
        return P.upPoint;
    }
    public function get rightPoint ():Number {
        return P.rightPoint;
    }
    public function get bottomPoint ():Number {
        return P.bottomPoint;
    }
    public function get leftPoint ():Number {
        return P.leftPoint;
    }
    public function set upPoint (n:Number) {
        P.upPoint = n;
    }
    public function set rightPoint (n:Number) {
        P.rightPoint = n;
    }
    public function set bottomPoint (n:Number) {
        P.bottomPoint = n;
    }
    public function set leftPoint (n:Number) {
        P.leftPoint = n;
    }
}