pezza in action script

[speake]

Ciao a tutti. Io sto cercando una classe o un qualsiasi codice che mi dia a delle immagini lo stesso effetto puntinato che c'è su questo sito http://www.daffys.com

Qui in questo caso potrebbe anche essere un movieclip attaccato sopra l'immagine con delle dimensioni molto grandi, ma io avrei bisogno di qualcosa di più tecnico perchè non mi posso permettere di ingrandire i miei movie clip dato che mi si sballerebbero tutte le dimensioni.

[and80]

Non hai dichiarato la versione di actionscript, comunque non è complesso utilizzando le bitmapdata, crei una bitmapdata di 3x3 pixel trasparenti e imposti il pixel centrale con una opacità più elevata, poi crei un movieclip vuoto e ci disegni un rettangolo con le dimensioni dell'immagine a cui vuoi applicare l'effetto riempiendolo con la bitmapdata creata.
Per AS3 avresti:

var d:BitmapData = new BitmapData(3, 3, true, 0x00808080);
d.setPixel32(2, 2, 0x80FFFFFF);
var l:Loader = addChild(new Loader()) as Loader;
l.contentLoaderInfo.addEventListener(Event.COMPLETE, complete);
l.load(new URLRequest("image.jpg"));
var m:MovieClip = addChild(new MovieClip()) as MovieClip;

function complete (evt:Event=null):void {
    m.graphics.beginBitmapFill(d);
    m.graphics.drawRect(0,0,evt.target.width,evt.target.height);
    m.graphics.endFill();
} 

[speake]

chiedo scusa,hai perfettamente ragione. Purtroppo sono ancora ancorato all'as2.

Al di la di questo, il mio grosso problema, come nell'esempio lincato è che se ingrandisco la pagina si ingrandisce anch l'immagine, ma l'effetto pixellato dovrebbe rimanere uguale all'occhio.

....per capirci meglio dovrei aver più puntini nel caso di un ingrandimento e di meno nel caso di un rimpiciolimento....

[and80]

Quello non sarebbe un problema, basterebbe far ridisegnare il clip ogni volta che si ingrandisce l'immagine (una sorta di refresh).
E non dovrebbe essere un grosso problema neanche applicare l'effetto in AS2, a patto che pubblichi almeno per flash player 8.

Questo è un esempio completo:

Stage.align = "TL";
Stage.scaleMode = "noScale";
Stage.showMenu = false;
var t:MovieClip = this.createEmptyMovieClip("canvas", this.getNextHighestDepth());
var g:MovieClip = this.createEmptyMovieClip("grid", this.getNextHighestDepth());
g.bd = new flash.display.BitmapData(3, 3, true, 0x00808080);
g.bd.setPixel32(2, 2, 0xFFFFFFFF);
g._alpha = 20;
var l:Object = new MovieClipLoader();
l.onLoadInit = function (t:MovieClip) {
    t._width = Stage.width;
    t._height = Stage.height;
    drawGrid(t._width, t._height);
}
l.loadClip("image.jpg", t);

var o:Object = {};
o.onResize = function () {
    l.onLoadInit(t);
}
Stage.addListener(o);

function drawGrid (w, h) {
    g.clear();
    g.beginBitmapFill(g.bd);
    g.lineTo(w, 0);
    g.lineTo(w, h);
    g.lineTo(0, h);
    g.lineTo(0, 0);
    g.endFill();
} 

[edit] Ah, se il caso è esattamente lo stesso di quello postato, tutte le sottigliezze di refresh ecc vanno a farsi benedire, basta impostare il tuo clip con le dimensioni dell'intero schermo (System.capabilities.screeResolutionX e System.capabilities.screeResolutionY) e pensare solo a ridimensionare la foto dietro, e la griglia rimane fissa.

[speake]

Grandioso! Tu sei sempre preciso. Grazie mille

[and80]

Ho aggiunto un [edit], leggi anche quello

[speake]

Tranquillo, no problem.

Faccio fatica a trovare i codici che mi interessano ma una volta che ce li ho in mano me li gestisco abbastanza bene ;-)