suono di sottofondo

[dutlui]

In un template di Flashmo -> http://www.flashmo.com/preview/flashmo_172_building volevo mettere la musica di sottofondo, però loro .fla di standar avevano commentato il relativo script che copio sotto:

/*
var bg_music:Sound = new flashmo_music();
var music_channel:SoundChannel = bg_music.play(0, 10000);
var music_volume:SoundTransform = new SoundTransform();

sound_control.stop();
sound_control.addEventListener( MouseEvent.CLICK, play_pause );

function play_pause(e:MouseEvent):void
{
if( e.target.currentFrame == 1 )
music_volume.volume = 0;
else
music_volume.volume = 1;

music_channel.soundTransform = music_volume;

e.target.play();
}
*/

Se tolgo il commento mi da errore e il filmato sclera in loop...
Cosa devo fare per mettere un mp3 che voglio io?
Dove lo devo mettere e con che nome? Non trovo nessun riferimento...
Grazie.

[randi]

Non che di As 3 me ne intenda, comunque quello che hai postato e il codice di un controller, e non un loader per la musica, per caricare un brano mp3 puoi inserire questo codice

var snd:Sound = new Sound()
snd.addEventListener(Event.COMPLETE, onComplete, false,0, true)
snd.load(new URLRequest("brano.mp3"))
var channel:SoundChannel = new SoundChannel()
function onComplete(evt:Event):void{
channel = snd.play()
snd.removeEventListener(Event.COMPLETE, onComplete)

var trans:SoundTransform = channel.soundTransform
//trans.volume= (1)
	trans.volume=Math.random()
	trans.pan=Math.random()*2-1
	channel.soundTransform = trans				 

	}

PS. magari per non creare problemi al codice pre esistente apri un nuovo livello e incollaci il codice.

[randi]

Ecco incolla questo codice modificato al posto dell'originale cosi funziona anche il pulsante play/stop

fm_button.visible = false;

// To make a link to an external page, write label as "Label|URL" in array value
// EXAMPLE 1: "Flash Templates|http://www.flashmo.com/store"
// EXAMPLE 2: "Donate|http://www.flashmo.com/donate"

var menu_label:Array = new Array("Introduction", "Architectures", "Modern Designs", 
								 "Our Company", "Contact Us");

var total:Number = menu_label.length;
var i:Number = 0;
var page:Number;
var main_menu:MovieClip = new MovieClip();
stage.addChild(main_menu);

for( i = 0; i < total; i++ )
{
	var btn = new flashmo_button();
	btn.name = "btn" + i;
	btn.x = fm_button.x;
	btn.y = fm_button.y + (fm_button.height + 12) * i;
	btn.item_no = i;
	btn.addEventListener( Event.ENTER_FRAME, btn_enter );
	btn.flashmo_button_pic.gotoAndStop( i + 1 );
	btn.flashmo_no.button_no.text = "0" + ( i + 1 ) + ".";
	
	var each_substring:Array = menu_label[i].split("|");  
	btn.flashmo_button_label.fm_label.text = each_substring[0];  
	btn.item_url = each_substring[1];
	main_menu.addChild(btn);
}

function btn_over(e:MouseEvent):void
{
	e.target.over = true;
}

function btn_out(e:MouseEvent):void
{
	e.target.over = false;
}

function btn_click(e:MouseEvent):void
{
	var mc = e.target.parent;
	if( mc.item_url != undefined )  
		navigateToURL( new URLRequest( mc.item_url ), "_parent" );
	else  
		change_page(mc.item_no);
}

function btn_enter(e:Event):void
{
	var mc = e.target;
	if( mc.over == true )
		mc.nextFrame();
	else
		mc.prevFrame();
}

function change_page(no:Number):void
{
	for( var i:Number = 0; i < main_menu.numChildren; i++ )
	{
		var mc = MovieClip( main_menu.getChildAt(i) );
		mc.over = false;
		mc.flashmo_click_area.visible = true;
		
		mc.addEventListener( MouseEvent.ROLL_OVER, btn_over );
		mc.addEventListener( MouseEvent.ROLL_OUT, btn_out );
		mc.addEventListener( MouseEvent.CLICK, btn_click );
	}
	var mc_selected = MovieClip( main_menu.getChildAt(no) );
		mc_selected.over = true;
		mc_selected.flashmo_click_area.visible = false;
		mc_selected.removeEventListener( MouseEvent.ROLL_OVER, btn_over );
		mc_selected.removeEventListener( MouseEvent.ROLL_OUT, btn_out );
		mc_selected.removeEventListener( MouseEvent.CLICK, btn_click );
		
	page = no + 1;
	play();
}

change_page(0);	// default page on load

flashmo_credit.addEventListener( MouseEvent.CLICK, credit_link );

function credit_link(e:MouseEvent):void
{
	navigateToURL( new URLRequest( "http://www.flashmo.com" ), "_parent" );
}
//----------------------------------------------

var snd:Sound = new Sound()
snd.addEventListener(Event.COMPLETE, onComplete, false,0, true)
snd.load(new URLRequest("brano.mp3"))
var channel:SoundChannel = new SoundChannel()
function onComplete(evt:Event):void{
channel = snd.play()
snd.removeEventListener(Event.COMPLETE, onComplete)

	}
//------------------------------------------------------------
var default_volume:Number = 1.00; // 0.00 to 1.00

var music_volume:SoundTransform = new SoundTransform();

music_volume.volume = default_volume;
channel.soundTransform = music_volume;

sound_control.stop();
sound_control.addEventListener( MouseEvent.CLICK, play_pause );

function play_pause(e:MouseEvent):void
{
	music_volume.volume = default_volume;
	
	if( e.target.currentFrame == 1 )
		music_volume.volume = 0;
		
	channel.soundTransform = music_volume;
	e.target.play();
}

[dutlui]

Grazie, però il file .mp3 lo posso mettere dove voglio? Basta metterlo nella root della libreria?

[randi]

Il file mp3 non lo devi inserire in libreria, in quanto questo viene caricato come file esterno, lo devi mettere nella medesima cartella dove metti lo swf del sito.

[dutlui]

Perfetto, ancora meglio!