[AS3] - Video in sequenza in un loop infinito

[cichity74]

Premessa: non conosco AS3... ho mollato flash alla V 6... dopo anni mi ritrovo a ricominciare con la CS 4...

Devo riprodurre dei video in sequenza in un loop infinito l'elenco dei video è presente
in un array, non so come fare in modo che al termine del video 1, proceda al 2 e cosi via all'infinito

per il momento sono riuscito a fare solo questo:

// Elenco video
var playlist:Array = new Array("video/video_1.flv","video/video_2.flv","video/video_3.flv");

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);
ns.client = this;

// priroduco il primo
ns.play(playlist[0]);

var vid:Video = new Video();
vid.attachNetStream(ns);
addChild(vid);

cichity74

[cichity74]

Vorrei poter eseguire il II video al termine del primo ma non mi funziona ne mi da errore
gran parte del codice è ricavato da: http://flash.html.it/guide/lezione/3...ei-file-video/

// Elenco video
var playlist:Array = new Array("video/video_1.mp4", "video/video_5.mp4");

var netconn:NetConnection = new NetConnection();
netconn.connect(null);
var stream_video = new NetStream(netconn);
stream_video.client = this;
var player:Video= new Video();
addChild(player);
player.attachNetStream(stream_video);

// avviamo la riproduzione del file video desiderato
stream_video.play(playlist[0]);

function onMetaData(oggetto:Object):void{
// setto le dimensioni native
  player.width = oggetto.width;
  player.height = oggetto.height;
}

// verifica di stato
function controllaStatus(evt:NetStatusEvent):void{
    // fine del video in esecuzione
    if (evt.info.code == "NetStream.Play.Stop"){
        trace("Video Terminato");
        // tento IN VANO di caricare il succesivo
        this.stream_video.play(playlist[1]);
    }
}
stream_video.addEventListener(NetStatusEvent.NET_STATUS, controllaStatus); 

[and80]

Mi pare ok, apparte questa che mi stona parecchio:

this.stream_video.play(playlist[1]);

prova a levare il this.

[edit] No, ho provato direttamente e funziona correttamente con il codice che hai postato. Unica cosa, forse la chiave, ho usato due flv e non due mp4 (che non ho a disposizione).

[cichity74]

Grazie per i suggerimenti ho risolto cosi...

//-------------------------------------------------------------------------
// VIDEO
//-------------------------------------------------------------------------
// Elenco video
var playlist:Array = new Array(
    "video/video_1.mp4",
    "video/video_2.flv",
    "video/video_3.flv", 
    "video/video_5.flv", 
    "video/video_6.flv",
    "video/video_7.flv"    
);

// creiamo un oggetto NetConnection
var netconn:NetConnection = new NetConnection();
netconn.connect(null);

// impostiamo l'oggeto netStream, associandolo alla NetConnection creata
var stream_video = new NetStream(netconn);

// associamo un client allo stream video
stream_video.client = this;

// associamo li flusso netStream all'istanza dell'oggetto Video
var player:Video= new Video();

// aggiungiamo il player video sullo stage
addChild(player);

// associamo al player lo stream video
player.attachNetStream(stream_video);

// avviamo la riproduzione del file video desiderato
stream_video.play(playlist[0]);

// verifica di stato
var i = 0
function controllaStatus(evt:NetStatusEvent):void{
// ..
    //trace(evt.info.code);
// ..
    // fine del video in esecuzione
    if (evt.info.code == "NetStream.Play.Stop"){
        trace("Il Video N: "+ i + " Terminato");
        i++;
        if (i > (playlist.length-1)){
            i = 0;
            trace("Fine playlist ricomincia da: " + i);
        }
        trace("Riproduco il video N: " + i);
        stream_video.play(playlist[i]);
    }
// ..
} // END function
// ..
stream_video.addEventListener(NetStatusEvent.NET_STATUS, controllaStatus);
//------------------------------------------------------------------------- 

cichity74