Email certificate con asp

**ciucciatiilcalzino** · 22-10-2010, 16:44

Ciao a tutti vorrei provare a modificare l'invio che faccio dal mio sito de email ai miei clienti facendole partire non più da una casella di posta normale ma ben si da una casella di posta certificata

Lo script che sto utilizzando funziona correttamente con qualsiasi indirizzo di posta, quindi l'ho configurato con i valori che utilizziamo anche all'interno di outlook per leggere inviare messaggi

il messaggio di errore restituito dalla pagina è questo :
The transport failed to connect to the server

è possibile inviare i messaggi certificati tramite cdo? online non ho trovato nessuna documentazione che dica di no, al contrario ci sono esempi realizzati con aspx, quindi credo che sia solo un problema di configurazione .

questo è quello che sto facendo

codice:

Dim objMessage, objConfig 

'Crea gli oggetti per il messaggio e per la configurazione 
Set objMessage = CreateObject("CDO.Message") 
Set objConfig = CreateObject("CDO.Configuration") 

'Configurazione server smtp 
objConfig.Fields(cdoSendUsingMethod) = cdoSendUsingPort 
objConfig.Fields(cdoSMTPServer) = "smtps.pec.aruba.it" 
objConfig.Fields(cdoSMTPServerPort) = 465 
objConfig.Fields(cdoSendUserName) = "posta@pec.miodominio.it"
objConfig.Fields(cdoSendPassword) = "miapassword"

'Aggiornamento configurazione 
objConfig.Fields.Update 
Set objMessage.Configuration = objConfig 

'crea il messaggio 
objMessage.To = trim(mailCliente) 
objMessage.From = "posta@pec.miodominio.it" 
objMessage.Subject = "Invio Email CDOsys" 
objMessage.HtmlBody = "<html><body>messaggio in formato HTML</body></html>" 

' gestione errori 
On Error Resume Next 

' Send the CDOSYS Message 
objMessage.Send 
Set objMessage = Nothing 
Set objConfig = Nothing

qualcuno di voi ha provato a inviare posta certificata dal server?

**Roby_72** · 22-10-2010, 17:27

Prova a chiedere ad Aruba.

Roby

**ciucciatiilcalzino** · 25-10-2010, 10:45

Ho chiesto, prima di scrivere qui, ma non ho ricevuto nessuna risposta (purtroppo)

**KOLOSSEO** · 21-07-2011, 03:22

Dim sSchema, objMail, bPEC, sIndirizzoEmailTest
Set objMail = Server.CreateObject("CDO.Message")
sSchema = "http://schemas.microsoft.com/cdo/configuration/"
bPEC = true
if bPEC then
sIndirizzoEmailTest = "info@pec.XXXX.it"
With objMail.Configuration.Fields
.Item(sSchema & "smtpserver") = "smtps.pec.aruba.it"
.Item(sSchema & "smtpserverport") = 465
.Item(sSchema & "sendusing") = 2
.Item(sSchema & "smtpauthenticate") = 1
.Item(sSchema & "sendusername") = "info@pec.XXXX.it"
.Item(sSchema & "sendpassword") = "XXXX"
.Item(sSchema & "smtpusessl") = True
End With
else
sIndirizzoEmailTest = "info@XXXX.it"
With objMail.Configuration.Fields
.Item(sSchema & "smtpauthenticate") = "smtp.aruba.it"
.Item(sSchema & "smtpserverport") = 25
.Item(sSchema & "sendusername") = "info@XXXX.it"
.Item(sSchema & "sendpassword") = "XXXX"
End With
end if
objMail.Configuration.Fields.Item(sSchema & "smtpconnectiontimeout") = 60
With objMail
.From = sIndirizzoEmailTest
.To = "marco@pec.XXXX.it"
'.Cc = "visibile@server.ext"
'.Bcc = "invisibile@server.ext"
.Subject = "Oggetto della mail..."
.TextBody = "Corpo della mail..."
.Configuration.Fields.Update
.Send
End With
Set objMail = Nothing

...trovato su internet...chi lo ha lasciato cortesemente ai posteri, sostiene che funziona, ma non l'ho ancora provato.

**marcocavicchioli** · 03-02-2012, 18:31

questo codice sul mio PC (con windows XP e IIS) funziona.

sul server aruba mi da:

CDO.Message.1 error '80040213'

The transport failed to connect to the server.

**marcocavicchioli** · 08-02-2012, 08:48

non riesco a trovare la risposta... qualcuno ha idea del perchè il codice riportato nel post precedente funziona perfettamente su pc con winxp e iis, mentre non funziona su windows server?

l'ho testato su 2 pc diversi (entrambi con xp + iis) e su 2 server diversi (entrambi con windows server): sui 2 pc ha funzionato, ma sui 2 server no.

non riesco proprio a capire a cosa possa essere dovuta questa differenza...

**Roby_72** · 08-02-2012, 10:57

Ammesso che tutti i parametri di configurazione siano corretti solo Aruba può fornirti un riscontro adeguato.
Tu stai spedendo dal dominio che a sua volta è certificato o da un dominio esterno NON certificato?
Io credo che Aruba non lo consenta.

Roby

**marcocavicchioli** · 08-02-2012, 11:30

la cosa curiosa è che ho lo stesso problema sul server dell'ufficio (che non è Aruba, ma un normale server HP con Windows Server 2003).
all'interno della LAN dell'ufficio con il mio PC riesco a far girare lo script, ma con il server no. in questo caso l'unica differenza è la piattaforma utilizzata (tutto il resto è uguale).

potrebbe essere un problema legato ai certificati di Windows Server? perchè se è così risolvo mettendo lo script a girare su un pc "di recupero" con xp, al posto che sul server, ma è una soluzione che non mi piace.

**Roby_72** · 08-02-2012, 11:32

Io penso che soltanto Aruba possa confermarti il tutto.
Attaccati al telefono o alle email...

Roby

**marcocavicchioli** · 09-02-2012, 15:18

Aruba ha risposto: ora il codice funziona. secondo me però c'erano problemi sul loro server smtp di posta certificata.

mi hanno anche lasciato il seguente codice.

codice:

<%
Const cdoSendUsingPickup = 1 'Send message using the local SMTP service pickup directory. 
Const cdoSendUsingPort = 2 'Send the message using the network (SMTP over the network). 

Const cdoAnonymous = 0 'Do not authenticate
Const cdoBasic = 1 'basic (clear-text) authentication
Const cdoNTLM = 2 'NTLM

Set objMessage = CreateObject("CDO.Message") 
objMessage.Subject = "invio da pec" 
objMessage.From = """Me"" <nomecasella@pec.nomedominio.xxx>" 
objMessage.To = "nomecasella@pec.nomedominio.xxx" 
objMessage.TextBody = "prova.." & vbCRLF & "It was sent using SMTP authentication."

'==This section provides the configuration information for the remote SMTP server.

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'Use SSL for the connection (False or True)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
 

'Name or IP of Remote SMTP Server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtps.pec.aruba.it"

'Type of authentication, NONE, Basic (Base64 encoded), NTLM
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic

'Your UserID on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusername") = "nomecasella@pec.nomedominio.xxx"

'Your password on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "password"

'Server port (typically 25)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465 


'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

objMessage.Configuration.Fields.Update

'==End remote SMTP server configuration section==

objMessage.Send

%>

Discussione: Email certificate con asp

Strumenti discussione

Ricerca discussione

Visualizza

Email certificate con asp

Permessi di invio