Script x galleria immagini

[fragorino88]

Salve a tutti,

Con il sottostante script riesco a vedere solo la prima foto, quando clicco su NEXT, non appare la 2° foto, e non posso nemmeno tornare indietro alla prima.

Mi sapreste dire dove stà l'errore?


var imgs:Number = 7;
var imgNum:Number = 1;
var imgLoader:Loader = new Loader();
var imgRequest:URLRequest = new URLRequest(imgNum + ".jpg");
imgLoader.load(imgRequest);
addChild(imgLoader);

imgLoader.contentLoaderInfo.addEventListener(Event .INIT, getDimF);

function getDimF(event:Event):void{
var imgX:Number = (stage.stageWidth-imgLoader.width)/2;
var imgY:Number = (stage.stageHeight-imgLoader.height)/2;
imgLoader.x = imgX;
imgLoader.y = imgY;
}

nextBtn_mc.buttonMode = true;
prevBtn_mc.buttonMode = true;

nextBtn_mc.addEventListener(MouseEvent.CLICK, nextF);
prevBtn_mc.addEventListener(MouseEvent.CLICK, prevF);

function nextF(event:MouseEvent):void{
if(imgNum<imgs) {
removeChild(imgLoader);
imgNum++;
} else {
imgNum = 1;
}
}


function prevF(event:MouseEvent):void{
if(imgNum>1) {
imgNum--;
} else {
imgNum = imgs;
}
reloadF();
}

function reloadF():void{
removeChild(imgLoader);
imgRequest = new URLRequest(imgNum + ".jpg");
imgLoader.load(imgRequest);
addChild(imgLoader);
}

[Sleter]

Ciao

Quando clicchi sul pulsante next c'è solo un'istruzione per eliminare l'immagine caricata: removeChild(imgLoader);
Viene incrementato il numero dell'immagine da caricare ma non viene chiamata una funzione per il caricamento della successiva immagine.

Praticamente risolvi così:

var imgs:Number = 7;
var imgNum:Number = 1;
var imgLoader:Loader = new Loader();
var imgRequest:URLRequest = new URLRequest(imgNum + ".jpg");
imgLoader.load(imgRequest);
addChild(imgLoader);

imgLoader.contentLoaderInfo.addEventListener(Event.INIT, getDimF);

function getDimF(event:Event):void
{
    var imgX:Number = (stage.stageWidth-imgLoader.width)/2;
    var imgY:Number = (stage.stageHeight-imgLoader.height)/2;
    imgLoader.x = imgX;
    imgLoader.y = imgY;
}

nextBtn_mc.buttonMode = true;
prevBtn_mc.buttonMode = true;

nextBtn_mc.addEventListener(MouseEvent.CLICK, nextF);
prevBtn_mc.addEventListener(MouseEvent.CLICK, prevF);

function nextF(event:MouseEvent):void
{
    if (imgNum < imgs)
    {
        imgNum++;
    }
    else
    {
        imgNum = 1;
    }
    reloadF();
}
function prevF(event:MouseEvent):void
{
    if (imgNum > 1)
    {
        imgNum--;
    }
    else
    {
        imgNum = imgs;
    }
    reloadF();
}

function reloadF():void
{
    removeChild(imgLoader);
    imgRequest = new URLRequest(imgNum + ".jpg");
    imgLoader.load(imgRequest);
    addChild(imgLoader);
} 

ciao