Problema codica caratteri nella creazione di un file xml

[marcopaolo79]

Ciao a tutti... il mio problema è questo, creo un file xml leggendo i suoi valori da un database access, il file xml generato però poi ha degli errori di codifica dei caratteri.... tutti i caratteri accentati sono sballati.
Nel database i caratteri accentati sono giusti il problema si pone quando li vado a salvare come xml.
Ho letto da varie parti che il problema è che io salvo in formato ascii mentre a me serve il formato utf-8 per non avere questi errori di codifica.
Uso questo codice per generare il file xml...

'apro il recordset che recupera i dati dal database
Set select_immobile_cmd = Server.CreateObject ("ADODB.Command")
select_immobile_cmd.ActiveConnection = Mia_connessione
select_immobile_cmd.CommandText = "SELECT * FROM Tabella"
select_immobile_cmd.Prepared = true
Set select_immobile = select_immobile_cmd.Execute
select_immobile_numRows = 0
...
...
'creo il file xml
Dim OggFile, origine, OggTextStream
origine=server.Mappath("mio percorso")
Set fso = CreateObject("Scripting.FileSystemObject")
fso.CreateTextFile (origine)
Set OggFile = fso.GetFile (origine)
Set OggTextStream = OggFile.OpenAsTextStream(2)
OggTextStream.WriteLine "<NewDataSet>"
OggTextStream.WriteLine "<tag_xml>"&Trim(select_immobile.Fields.Item("colonna").Value)&"</tag_xml>"
...
OggTextStream.WriteLine "</NewDataSet>"
OggTextStream.close

ho letto che il problema è che Scripting.FileSystemObject usa solo Ascii e non posso impostargli la codifica con Utf-8 ma dovrei usare ado.stream ma non ho capito come fare... potete aiutarmi per favore?

Grazie a tutti

[Vincent.Zeno]

qui la spiegazione sembra abbastanza semplice.
http://wiki.mcneel.com/developer/scriptsamples/readutf8

se riesci facci sapere cosa hai fatto

[marcopaolo79]

Ciao e sopratutto stra-grazie perchè ho risolto!
Ho seguito quello che era scritto li ed ho risolto anche diciamo abbastanza facilmente così:

'apro il recordset che recupera i dati dal database
Set select_immobile_cmd = Server.CreateObject ("ADODB.Command")
select_immobile_cmd.ActiveConnection = Mia_connessione
select_immobile_cmd.CommandText = "SELECT * FROM Tabella"
select_immobile_cmd.Prepared = true
Set select_immobile = select_immobile_cmd.Execute
select_immobile_numRows = 0

Dim objStream
Set objStream = CreateObject("ADODB.Stream")
objStream.CharSet = "utf-8"
objStream.Open
objStream.WriteText "<NewDataSet>" & vbcrlf
objStream.WriteText "<tag_xml>"&Trim(select_immobile.Fields.Item("colonna").Value)&"</tag_xml>" & vbcrlf
...
...
objStream.WriteText "</NewDataSet>"

objStream.SaveToFile "C:\Users\admin\Desktop\test.xml", 2

[Vincent.Zeno]

grazie a te per averlo verificato