[NET] Scrollbar e icona in traybar (era: 2 domande)

[gojitaa]

salve. avrei 2 domande........

1) come metto lo scrolbar in un mio progetto??.......
2) come metto il pulsantino che quando ci clicchi manda il progetto in basso a destra... insomma come quando uno si connette appare la icona di duecomputer in basso a destra.......
Grazie delle eventuali risposte ^_^

[gojitaa]

[gojitaa]

perche mi e stato modificato il nome del topic'? va bhe...... cmq aiutatemi vi prego

[sebamix]

Originariamente inviato da gojitaa
perche mi e stato modificato il nome del topic'? va bhe...... cmq aiutatemi vi prego

Hai letto il regolamento di questo forum?
Dovresti dare titoli attinenti al contenuto del topic per facilitare future ricerche.

[gojitaa]

ewhehhe ok....... colgo l'occasione per UP

[gojitaa]

[gojitaa]

up

[gojitaa]

Non ce nessuno che lo sa=??

[s|n3]

questo lo metti in un modulo

'INIZIO TRAY
'user defined type required by Shell_NotifyIcon API call
    Public Type NOTIFYICONDATA
     cbSize As Long
     hwnd As Long
     uId As Long
     uFlags As Long
     uCallBackMessage As Long
     hIcon As Long
     szTip As String * 64
    End Type

    'constants required by Shell_NotifyIcon API call:
    Public Const NIM_ADD = &H0
    Public Const NIM_MODIFY = &H1
    Public Const NIM_DELETE = &H2
    Public Const NIF_MESSAGE = &H1
    Public Const NIF_ICON = &H2
    Public Const NIF_TIP = &H4
    Public Const WM_MOUSEMOVE = &H200
    Public Const WM_LBUTTONDOWN = &H201     'Button down
    Public Const WM_LBUTTONUP = &H202       'Button up
    Public Const WM_LBUTTONDBLCLK = &H203   'Double-click
    Public Const WM_RBUTTONDOWN = &H204     'Button down
    Public Const WM_RBUTTONUP = &H205       'Button up
    Public Const WM_RBUTTONDBLCLK = &H206   'Double-click

    Public Declare Function SetForegroundWindow Lib "user32" _
    (ByVal hwnd As Long) As Long
    Public Declare Function Shell_NotifyIcon Lib "shell32" _
    Alias "Shell_NotifyIconA" _
    (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean

    Public nid As NOTIFYICONDATA
'FINE TRAY

questo nella form

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
    (ByVal lpClassName As String, _
    ByVal lpWindowName As String) As Long
Private Declare Function GetWindow Lib "user32" _
   (ByVal hwnd As Long, ByVal wCmd As Long) As Long
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" _
   (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
Private Declare Function IsWindowVisible Lib "user32" (ByVal hwnd As Long) As Long
Const GW_HWNDNEXT = 2
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As _
       Single, Y As Single)
    'this procedure receives the callbacks from the System Tray icon.
    Dim Result As Long
    Dim msg As Long
     'the value of X will vary depending upon the scalemode setting
     If Me.ScaleMode = vbPixels Then
      msg = X
     Else
      msg = X / Screen.TwipsPerPixelX
     End If
     Select Case msg
      Case WM_LBUTTONUP        '514 restore form window
       Me.WindowState = vbNormal
       Result = SetForegroundWindow(Me.hwnd)
       Me.Show
      Case WM_LBUTTONDBLCLK    '515 restore form window
       Me.WindowState = vbNormal
       Result = SetForegroundWindow(Me.hwnd)
       Me.Show
      Case WM_RBUTTONUP        '517 display popup menu
       Result = SetForegroundWindow(Me.hwnd)
       Me.PopupMenu mPopupSys
     End Select
    End Sub
    Private Sub Form_Resize()
     'this is necessary to assure that the minimized window is hidden
     If Me.WindowState = vbMinimized Then
       Me.Hide
             With nid
        .cbSize = Len(nid)
        .hwnd = Me.hwnd
        .uId = vbNull
        .uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
        .uCallBackMessage = WM_MOUSEMOVE
        .hIcon = Me.Icon
        .szTip = "Download Controller " & vbNullChar
       End With
       Shell_NotifyIcon NIM_ADD, nid
       Else
       Shell_NotifyIcon NIM_DELETE, nid
     End If
End Sub
Private Sub Form_Unload(Cancel As Integer)
'this removes the icon from the system tray
Shell_NotifyIcon NIM_DELETE, nid
End
End Sub
    Private Sub mPopExit_Click()
     'called when user clicks the popup menu Exit command
     Unload Me
    End Sub
    Private Sub mPopRestore_Click()
     'called when the user clicks the popup menu Restore command
     Me.WindowState = vbNormal
     Result = SetForegroundWindow(Me.hwnd)
     Me.Show
    End Sub
'FINE TRAY******************************************

be happy....