Memorizzare preferenze ckBox

[Drocchia]

Ciao, devo memorizzare in un file le preferenze dei Check Box chi mi aiuta...in vb6!

Ciao

[Mabi]

Se lo devi fare in un file di testo potresti utilizzare una matrice di Check e con un ciclo, controllare il valore e scriverlo nel file:

Dim FileName As String
Dim Cont As Integer

FileName = "C:\Prova\Preferenze.txt"
Open FileName For Output As #1
  For Cont = 0 To 3
    If Chk(Cont).Value = 1 Then
      Print #1, "Check" & CStr(Cont) & "=Si"
    Else
      Print #1, "Check" & CStr(Cont) & "=No"
    End If
  Next Cont
Close #1

Puoi recuperare le preferenze con un altro ciclo:

Dim FileName As String

Dim Cont As Integer
Dim Riga As String
Dim Scelta As String

FileName = "C:\Prova\Preferenze.txt"
If Dir(FileName) <> "" Then
  Open FileName For Input As #1
    Do Until EOF(1)
      Line Input #1, Riga
      Scelta = Mid(Riga, InStr(1, Riga, "=") + 1)
      If Scelta = "Si" Then
        Chk(Cont).Value = 1
      ElseIf Scelta = "No" Then
        Chk(Cont).Value = 0
      End If
      Cont = Cont + 1
    Loop
  Close #1
End If