[VB6] Selezione cartella

[Cholo]

Ciao,
Dovrei fare in modo che il mio programma permetta di selezionare una cartella (all' interno di cui leggerò dei file) all' utente.

Cercavo di usare la "Common Dialog" ma non mi permette di selezionare una cartella, solo File.

C' è qualche proprietà che devo settare o qualche altro oggetto da utilizzare ?

[Cholo]

UP

[gaullo]

se cerchi c'è un mio 3d recente su questo

[gaullo]

http://www.vbsimple.net/index.htm?/howto/ht_009.htm

[Cholo]

Si, questo link l' avevo già incontrato stamattina cercando sul forum. Purtroppo non va il sito

[codo82]

in un modulo:

Option Explicit

Private Type BROWSEINFO
    hOwner As Long
    pidlRoot As Long
    pszDisplayName As String
    lpszTitle As String
    ulFlags As Long
    lpfn As Long
    lParam As Long
    iImage As Long
End Type

Private Const BIF_RETURNONLYFSDIRS As Long = &H1

Private Declare Function SHGetPathFromIDList Lib "Shell32.dll" Alias "SHGetPathFromIDListA" (ByVal pidl As Long, ByVal pszPath As String) As Long
Private Declare Function SHBrowseForFolder Lib "Shell32.dll" Alias "SHBrowseForFolderA" (lpBrowseInfo As BROWSEINFO) As Long
Public Function BrowseForFolder(ByVal hwnd As Long, ByVal szDialogTitle As String) As String
    Dim BI As BROWSEINFO
    Dim dwIList As Long, RetVal As Long
    Dim szPath As String
    BI.hOwner = hwnd
    BI.lpszTitle = szDialogTitle
    BI.ulFlags = BIF_RETURNONLYFSDIRS
    szPath = Space$(1024)
    dwIList = SHBrowseForFolder(BI)
    RetVal = SHGetPathFromIDList(ByVal dwIList, ByVal szPath)
    If RetVal Then
        BrowseForFolder = Left$(szPath, InStr(szPath, Chr(0)) - 1)
    Else
        BrowseForFolder = ""
    End If

End Function

E in una Form con un pulsante chiamato Command1 e un campo testo Text1:

Private Sub Command1_Click()
    Dim Temp As String
    Temp = BrowseForFolder(Me.hwnd, "Selezionare una cartella:")
    If Temp <> "" Then Text1.Text = Temp
    If Text1 <> "" And Right(Text1, 1) <> "\" Then Text1 = Text1 + "\"
End Sub

[gaullo]

bo, a me viene visualizzato il link, comunque c'è lo stesso codice che ti hanno postato, con le spiegazioni...

[Bisco]

Il codice mi funziona benissimo. Come faccio però a settare la directory iniziale da cui partire. (tipo "C:\WINDOWS\TEMP")

NB. La dir iniziale, non la pIDROOT (che indica la root iniziale dell'albero di ricerca)

Grazie

[xegallo]

cmq senza usare api la commondialog ha la proprietà flags per questi scopi che combinata con l'uso del tasto F1 evita inutili chiamate all'OS